Слияние записей для Mnesia

Question

Я пытаюсь провести рефакторинг некоторого кода, который у меня есть, для программного обеспечения, которое собирает текущее состояние операторов в очереди вызовов. В настоящее время для каждого из 6 или около того событий, которые я слушаю, я проверяю в таблице Mnesia, существует ли агент, и изменяю некоторые значения в строке в зависимости от события или добавляю его как новый, если агент не существует. В настоящее время у меня есть транзакция Mnesia в каждом событии, и, конечно, это набор повторяющихся кодов для проверки существования агентов и так далее.

Я пытаюсь изменить это так, чтобы была одна функция типа change_agent / 2 , которую я вызываю из событий, которые обрабатывают это для меня.

Мои проблемы, конечно, записи .... Я не нахожу способа их динамического создания или объединения двух из них вместе или чего-то еще. Предпочтительно, чтобы была функция, которую я мог бы вызвать как:

change_agent("001", #agent(id = "001", name = "Steve")).
change_agent("001", #agent(id = "001", paused = 0, talking_to = "None")).

Answer 1

Трудно написать общие функции доступа к записям. Одним из способов решения этой проблемы является библиотека 'exprecs' , которая сгенерирует код для низкоуровневых функций доступа к записи.

Вам нужно добавить следующие строки в модуль:

-compile({parse_transform, exprecs}).
-export_records([...]).  % name the records that you want to 'export'

Соглашение об именах для функций доступа может показаться странным, но оно было вдохновлено предложением Ричарда О'Киф. Это, по крайней мере, непротиворечиво и вряд ли конфликтует с существующими функциями. (

Answer 2

Некоторое время назад я написал некоторый код, который объединяет две записи. Не совсем динамический, но с макросами вы можете легко использовать его для нескольких записей.

Это работает так: функция merge / 2 берет две записи и преобразует их в списки вместе с пустой записью для справки (тип записи определяется во время компиляции и должен быть. Это «нединамическая» часть) , Затем они запускаются через универсальную функцию merge / 4, которая работает со списками и берет элементы из A, если они определены, в противном случае из B, если они определены, или, наконец, из Default (которая всегда определяется).

Вот код (прошу прощения за плохую подсветку синтаксиса Erlang в StackOverflow):

%%%----------------------------------------------------------------------------
%%% @spec merge(RecordA, RecordB) -> #my_record{}
%%%     RecordA = #my_record{}
%%%     RecordB = #my_record{}
%%%
%%% @doc Merges two #my_record{} instances. The first takes precedence.
%%% @end
%%%----------------------------------------------------------------------------
merge(RecordA, RecordB) when is_record(RecordA, my_record),
                             is_record(RecordB, my_record) ->
    list_to_tuple(
        lists:append([my_record],
                     merge(tl(tuple_to_list(RecordA)),
                           tl(tuple_to_list(RecordB)),
                           tl(tuple_to_list(#my_record{})),
                           []))).

%%%----------------------------------------------------------------------------
%%% @spec merge(A, B, Default, []) -> [term()]
%%%     A = [term()]
%%%     B = [term()]
%%%     Default = [term()]
%%%
%%% @doc Merges the lists `A' and `B' into to a new list taking
%%% default values from `Default'.
%%%
%%% Each element of `A' and `B' are compared against the elements in
%%% `Default'. If they match the default, the default is used. If one
%%% of them differs from the other and the default value, that element is
%%% chosen. If both differs, the element from `A' is chosen.
%%% @end
%%%----------------------------------------------------------------------------
merge([D|ATail], [D|BTail], [D|DTail], To) ->
    merge(ATail, BTail, DTail, [D|To]); % If default, take from D
merge([D|ATail], [B|BTail], [D|DTail], To) ->
    merge(ATail, BTail, DTail, [B|To]); % If only A default, take from B
merge([A|ATail], [_|BTail], [_|DTail], To) ->
    merge(ATail, BTail, DTail, [A|To]); % Otherwise take from A
merge([],        [],        [],        To) ->
    lists:reverse(To).

Не стесняйтесь использовать его любым удобным для вас способом.