Подсчет 5 самых популярных сообщений в блоге SharePoint с использованием XSL - PullRequest
Новая
       20

Подсчет 5 самых популярных сообщений в блоге SharePoint с использованием XSL

0 голосов
/ 23 декабря 2011

Я в основном редактирую ItemStyle.xsl, чтобы он мог получить то, что мне нужно, и отобразить через CQWP (веб-часть запроса контента).Мне нужно, чтобы отображались только топ-5 постов с наибольшим количеством комментариев.Комментарии можно получить через @NumComments.Я не достаточно знаком с XSL, чтобы знать, как это сделать, я полагаю, с помощью счетчика?Какие-нибудь советы?

Вот текущий код XSL для этого шаблона, который просто отображает все сообщения.

<xsl:template name="MostCommented" match="Row[@Style='MostCommented']" mode="itemstyle">
    <xsl:variable name="SafeLinkUrl">
        <xsl:call-template name="OuterTemplate.GetSafeLink">
            <xsl:with-param name="UrlColumnName" select="'LinkUrl'"/>
        </xsl:call-template>
    </xsl:variable>
    <xsl:variable name="DisplayTitle">
        <xsl:call-template name="OuterTemplate.GetTitle">
            <xsl:with-param name="Title" select="@Title"/>
            <xsl:with-param name="UrlColumnName" select="'LinkUrl'"/>
        </xsl:call-template>
    </xsl:variable>
    <div>
        <a href="{$SafeLinkUrl}" target="{$LinkTarget}" title="{@LinkToolTip}">
            <xsl:value-of select="$DisplayTitle"/>
        </a>
    </div>
</xsl:template>

Ответы [ 2 ]

1 голос
/ 23 декабря 2011

Вам необходимо добавить этот код - в шаблоне, который соответствует родительскому элементу Row

<xsl:apply-templates select="Row[@Style='MostCommented']" mode="itemstyle">
 <xsl:sort select="@NumComments" data-type="number" order="descending"/>
</xsl:apply-templates>

Кроме того, внутри вашего шаблона (тот, который будет выбран для выполнения в результате выполнения xsl:apply-templates выше) оборачивает весь существующий код в условное выражение, как показано ниже : 

<xsl:template name="MostCommented" match="Row[@Style='MostCommented']" mode="itemstyle">
 <xsl:if test="not(position() > 5)">
  <!-- Put all already-existing code here -->
 </xsl:if>
</xsl:template>

Вот полный пример, иллюстрирующий эту технику : 

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/*">
     <t>
       <xsl:apply-templates select="*">
        <xsl:sort select="@valued"
            data-type="number" order="descending"/>
       </xsl:apply-templates>
     </t>
 </xsl:template>

 <xsl:template match="post">
  <xsl:if test="not(position() >5)">
   <xsl:copy-of select="."/>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

Когда это преобразование применяется к следующему документу XML (так как вы забыли его указать !!!): 

<t>
 <post valued="5"/>
 <post valued="2"/>
 <post valued="9"/>
 <post valued="8"/>
 <post valued="6"/>
 <post valued="3"/>
 <post valued="4"/>
 <post valued="10"/>
 <post valued="2"/>
 <post valued="7"/>
</t>

желаемый, правильный результат выдается : 

<t>
   <post valued="10"/>
   <post valued="9"/>
   <post valued="8"/>
   <post valued="7"/>
   <post valued="6"/>
</t>
0 голосов
/ 04 января 2012

Мне удалось сделать это непосредственно в веб-части CQWP вместо ItemStyle.xsl

Замена 

<property name="QueryOverride" type="string" />

на 

<property name="QueryOverride" type="string"><![CDATA[<OrderBy><FieldRef Name="NumComments" Nullable="True" Type="Lookup" Ascending="False"/></OrderBy>]]></property>
...