Заменить текст XML-узла с помощью XSLT и Java?

Question

XML-файл -

<Remarks>
 <Remark>
 <Cid>2009-1</Cid>
 <Date>3-11-2011 2:55:0</Date>
 <Title>Book</Title>
 <Comment>XXX</Comment>
 </Remark>
 <Remark>
 <Cid>2009-2</Cid>
 <Date>3-12-2011 2:55:0</Date>
 <Title>Song</Title>
 <Comment>XXX</Comment>
 </Remark>
</Remarks>

Я хочу заменить текст <Comment> на конкретный <Cid>.Например;для Cid 2009-1 я хочу обновить / изменить соответствующий комментарий XXX на YYY.Оба эти значения основаны на параметрах, которые мой код Java будет передавать.Ниже приведен XSLT-файл -

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:strip-space elements="*"/>
    <xsl:param name="ciName" select=""/>
    <xsl:param name="coName" select=""/>

    <xsl:template match="node()|@*">
      <xsl:copy>
         <xsl:apply-templates select="node()|@*"/>
      </xsl:copy>
    </xsl:template>

    <xsl:template match="//Remarks/Remark/Comment[preceding-sibling::Cid='$ciName']">
      <xsl:copy>
         <xsl:value-of select="$coName"/>
      </xsl:copy>
    </xsl:template>

 </xsl:stylesheet>

И это part Java-код -

    String cid = "2009-1";
    String comm = "YYY";

    TransformerFactory factory = TransformerFactory.newInstance();
    Source xslt = new StreamSource(new File("loc1.xslt"));
    Transformer transformer = factory.newTransformer(xslt);
    transformer.setParameter("ciName",cid);
    transformer.setParameter("coName",comm);

    Source text = new StreamSource(new File("Comments.xml"));
    transformer.transform(text, new StreamResult(new File( "Comments1.xml")));

Ошибка -

ERROR:  'Premature end of file.'
ERROR:  'com.sun.org.apache.xml.internal.utils.WrappedRuntimeException: Premature end of file.'
Excep......

ТакжеЯ НЕ могу редактировать / заменять / изменять соответствующий комментарий ... Любая помощь ....?Заранее спасибо.

Answer 1

С процессором XSLT 2.0, таким как Saxon 9, вы можете использовать

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">


    <xsl:param name="ciName" select="'2009-1'"/>
    <xsl:param name="coName" select="'YYY'"/>

    <xsl:template match="node()|@*">
      <xsl:copy>
         <xsl:apply-templates select="node()|@*"/>
      </xsl:copy>
    </xsl:template>

    <xsl:template match="Remark[Cid = $ciName]/Comment">
      <xsl:copy>
         <xsl:value-of select="$coName"/>
      </xsl:copy>
    </xsl:template>

 </xsl:stylesheet>

С XSLT 1.0 вам не разрешено использовать переменную или ссылку на параметр в шаблоне совпадения, поэтому вам нужно использовать

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">


    <xsl:param name="ciName" select="'2009-1'"/>
    <xsl:param name="coName" select="'YYY'"/>

    <xsl:template match="node()|@*">
      <xsl:copy>
         <xsl:apply-templates select="node()|@*"/>
      </xsl:copy>
    </xsl:template>

    <xsl:template match="Remark/Comment">
      <xsl:copy>
         <xsl:choose>
           <xsl:when test="../Cid = $ciName">
             <xsl:value-of select="$coName"/>
           </xsl:when>
           <xsl:otherwise>
             <xsl:apply-templates/>
           </xsl:otherwise>
         </xsl:choose>
      </xsl:copy>
    </xsl:template>

 </xsl:stylesheet>