Несколько файлов XSLT в один файл XSLT для 2 разных файлов XML - PullRequest
Новая
       4

Несколько файлов XSLT в один файл XSLT для 2 разных файлов XML

3 голосов
/ 17 июля 2011

Это мой xml файл: 

<?xml version="1.0" encoding="windows-1250"?>
<CONTACTS>
    <CONTACT>
        <FirstName>Ford</FirstName>
        <LastName>Pasteur</LastName>
        <EMail>pasteur.ford@yahoo.com</EMail>
    </CONTACT>
    <CONTACT>
        <FirstName>Jack</FirstName>
        <LastName>Sully</LastName>
        <URL>http://www.facebook.com/profile.php?id=1000474277</URL>
    </CONTACT>
    <CONTACT>
        <FirstName>Colombo</FirstName>
        <LastName>Chao</LastName>
        <EMail>chao.colombo@liberto.it</EMail>
    </CONTACT>
</CONTACTS>

Я использовал приведенный ниже XSLT-файл для первой версии вывода XML. 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="CONTACT">
        <xsl:copy>
               <Customer-ID>
               <xsl:value-of select="generate-id(.)"/> 
               </Customer-ID>
              <xsl:copy-of select="FirstName|LastName|URL"/>
              <Facebook-ID>
            <xsl:choose>
                <xsl:when test="URL">
                    <xsl:value-of select="substring-after(URL,'?id=')"/>
                </xsl:when>
                <xsl:otherwise>

                </xsl:otherwise>
            </xsl:choose>
        </Facebook-ID>
            <EMAILS>
                <xsl:apply-templates select="EMail"/>
            </EMAILS>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="EMail">
        <EMail> 
            <Type><xsl:value-of select="substring-before(
                    substring-after(.,'@'),
                    '.')"/>
            </Type>
            <Value><xsl:value-of select="."/></Value>
        </EMail>
    </xsl:template>

</xsl:stylesheet>

Моя первая версия вывода xml из вышеуказанного XSLT-файла: 

<?xml version="1.0" encoding="windows-1250"?>
<CONTACTS>
    <CONTACT>
    <Customer-ID>N65539</Customer-ID>
    <FirstName>Ford</FirstName>
    <LastName>Pasteur</LastName>
    <EMAILS>
    <EMail>
    <Type>yahoo</Type>
    <Value>pasteur.ford@yahoo.com</Value>
    </EMail>
    </EMAILS>
    </CONTACT>
    <CONTACT>
    <Customer-ID>N65546</Customer-ID>
     <FirstName>Jack</FirstName>
     <LastName>Sully</LastName>
     <URL>http://www.facebook.com/profile.php?id=1000474277</URL>
    <Facebook-ID>1000474277</Facebook-ID>
    <EMAILS/>
    </CONTACT>
    <CONTACT>
    <Customer-ID>N65553</Customer-ID>
    <FirstName>Colombo</FirstName>
    <LastName>Chao</LastName>
    <EMAILS>
    <EMail>
    <Type>liberto</Type>
    <Value>chao.colombo@liberto.it</Value>
    </EMail>
    </EMAILS>
    </CONTACT>
</CONTACTS>

Это мой второй XSLT-файл: 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:template match="node()|@*">
    <xsl:copy>
        <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="CONTACT">
<xsl:copy>
    <Customer-ID>
        <xsl:value-of select="Customer-ID"/>
    </Customer-ID>

    <FirstName>
        <xsl:value-of select="FirstName"/>
    </FirstName>

    <LastName>
        <xsl:value-of select="LastName"/>
    </LastName>

    <gmail>
            <xsl:value-of select="EMAILS/EMail[Type='gmail']/Value"/>
    </gmail>

    <yahoo>
            <xsl:value-of select="EMAILS/EMail[Type='yahoo']/Value"/>
    </yahoo>

    <liberto>
            <xsl:value-of select="EMAILS/EMail[Type='liberto']/Value"/>
    </liberto>

    <URL>
            <xsl:value-of select="URL"/>
    </URL>

    <Facebook-ID>
             <xsl:value-of select="Facebook-ID"/>
    </Facebook-ID>

      </xsl:copy>
</xsl:template>

Это мой последний вывод xml из 2-го XSLT-файла: 

<?xml version="1.0" encoding="windows-1250"?>
<CONTACTS>

    <CONTACT>
    <Customer-ID>N65539</Customer-ID>
    <FirstName>Ford</FirstName>
    <LastName>Pasteur</LastName>
    <gmail/>
    <yahoo>pasteur.ford@yahoo.com</yahoo>
    <liberto/>
    <URL/>
    <Facebook-ID/>
    </CONTACT>

    <CONTACT>
    <Customer-ID>N65546</Customer-ID>
    <FirstName>Jack</FirstName>
    <LastName>Sully</LastName>
    <gmail/>
    <yahoo/>
    <liberto/>
    <URL>http://www.facebook.com/profile.php?id=1000474277</URL>
    <Facebook-ID>1000474277</Facebook-ID>
    </CONTACT>

    <CONTACT>
    <Customer-ID>N65553</Customer-ID>
    <FirstName>Colombo</FirstName>
    <LastName>Chao</LastName>
    <gmail/>
    <yahoo/>
    <liberto>chao.colombo@liberto.it</liberto>
    <URL/>
    <Facebook-ID/>
    </CONTACT>
</CONTACTS>

Как объединить эти два XSLT-файла в один XSLT-файл, чтобы получить окончательный вывод XML.

как мне поступить с этим? потому что есть два разных XML-файла схожего типа.

Я использую Eclipse Hellios run as -> XSL преобразование, чтобы увидеть вывод.

Ответы [ 2 ]

4 голосов
/ 17 июля 2011

Выполнение цепочки преобразований довольно часто используется в приложениях XSLT , хотя выполнение этого полностью в XSLT 1.0 требует использования специфичной для поставщика функции xxx:node-set().В XSLT 2.0 такого расширения не требуется, поскольку там исключен печально известный тип данных RTF.

Вот пример (слишком просто, чтобы иметь смысл, но полностью иллюстрирующий, как это делается):

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/">
   <xsl:variable name="vrtfPass1">
    <xsl:apply-templates select="/*/*"/>
   </xsl:variable>

   <xsl:variable name="vPass1"
        select="ext:node-set($vrtfPass1)"/>

   <xsl:apply-templates mode="pass2"
        select="$vPass1/*"/>
 </xsl:template>

 <xsl:template match="num[. mod 2 = 1]">
  <xsl:copy-of select="."/>
 </xsl:template>

 <xsl:template match="num" mode="pass2">
  <xsl:copy>
    <xsl:value-of select=". *2"/>
  </xsl:copy>
 </xsl:template>
</xsl:stylesheet>

, когда это преобразование применяется к следующему документу XML : 

<nums>
  <num>01</num>
  <num>02</num>
  <num>03</num>
  <num>04</num>
  <num>05</num>
  <num>06</num>
  <num>07</num>
  <num>08</num>
  <num>09</num>
  <num>10</num>
</nums>

желаемый, правильный результат : 

<num>2</num>
<num>6</num>
<num>10</num>
<num>14</num>
<num>18</num>

Объяснение :

  1. На первом шаге документ XML преобразуется , а результат определяется какзначение переменной $vrtfPass1.При этом копируются только элементы num, имеющие нечетное значение (не четное).

  2. Переменная $vrtfPass1, имеющая тип RTF, не может напрямую использоваться для выражений XPath, поэтому мы преобразуем его в обычное дерево, используя функцию EXSLT (реализуемую большинством процессоров XSLT 1.0) ext:node-set и определяя другую переменную - $vPass1, значением которой является это дерево.

  3. Теперь мы выполняем второе преобразование в нашей цепочке преобразований - для результата первого преобразования, которое сохраняется как значение переменной $vPass1.Чтобы не связываться с шаблоном первого прохода, мы указываем, что новая обработка должна быть в именованном режиме, называемом «pass2».В этом режиме значение любого элемента num умножается на два.

Решение XSLT 2.0 (без RTF): 

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/">
  <xsl:variable name="vPass1" >
   <xsl:apply-templates select="/*/*"/>
  </xsl:variable>
   <xsl:apply-templates mode="pass2"
        select="$vPass1/*"/>
 </xsl:template>

 <xsl:template match="num[. mod 2 = 1]">
  <xsl:copy-of select="."/>
 </xsl:template>

 <xsl:template match="num" mode="pass2">
  <xsl:copy>
    <xsl:value-of select=". *2"/>
  </xsl:copy>
 </xsl:template>
</xsl:stylesheet>
3 голосов
/ 17 июля 2011

Вы можете использовать xsl:import для повторного использования файлов XSLT, а затем использовать методику, описанную в ответе @ Dimitre следующим образом: 

<xsl:stylesheet version="1.0" 
    xmlns:exslt="http://exslt.org/common"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    exclude-result-prefixes="exslt">

    <xsl:import href="phase1.xsl"/>
    <xsl:import href="phase2.xsl"/>

    <xsl:output method="xml" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="/">
        <xsl:variable name="intermediate">
            <xsl:apply-templates select="/CONTACTS/CONTACT" mode="phase1"/>
        </xsl:variable>
           <CONTACTS>
        <xsl:apply-templates select="exslt:node-set($intermediate)" 
         mode="phase2"/>
           </CONTACTS>
    </xsl:template>

</xsl:stylesheet>

Где:

  • phase1.xsl и phase2.xsl - ваши два преобразования xslt

  • преобразования слегка изменены, добавляя mode к каждому шаблону.Например, преобразование phase1.xsl: 

    <xsl:template match="node()|@*">
    <xsl:copy>
        <xsl:apply-templates select="node()|@*" mode="phase1"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="CONTACT" mode="phase1">
    <xsl:copy>
        <Customer-ID>
            <xsl:value-of select="generate-id(.)"/> 
        </Customer-ID>
        <xsl:copy-of select="FirstName|LastName|URL"/>
        <Facebook-ID>
            <xsl:choose>
                <xsl:when test="URL">
                    <xsl:value-of select="substring-after(URL,'?id=')"/>
                </xsl:when>
                <xsl:otherwise>

                </xsl:otherwise>
            </xsl:choose>
        </Facebook-ID>
        <EMAILS>
            <xsl:apply-templates select="EMail" mode="phase1"/>
        </EMAILS>
    </xsl:copy>
</xsl:template>

<xsl:template match="EMail" mode="phase1">
    <EMail> 
        <Type><xsl:value-of select="substring-before(
                substring-after(.,'@'),
                '.')"/>
        </Type>
        <Value><xsl:value-of select="."/></Value>
    </EMail>
</xsl:template>

Для phase2.xsl вы, очевидно, будете использовать `mode =" phase2 ".

Когда вышеуказанные условия выполнены и преобразование слиянием применяется к первому входному XML, получается следующий вывод: 

<CONTACTS>
   <CONTACT>
      <Customer-ID>d0e2</Customer-ID>
      <FirstName>Ford</FirstName>
      <LastName>Pasteur</LastName>
      <gmail/>
      <yahoo>pasteur.ford@yahoo.com</yahoo>
      <liberto/>
      <URL/>
      <Facebook-ID/>
   </CONTACT>
   <CONTACT>
      <Customer-ID>d0e9</Customer-ID>
      <FirstName>Jack</FirstName>
      <LastName>Sully</LastName>
      <gmail/>
      <yahoo/>
      <liberto/>
      <URL>http://www.facebook.com/profile.php?id=1000474277</URL>
      <Facebook-ID>1000474277</Facebook-ID>
   </CONTACT>
   <CONTACT>
      <Customer-ID>d0e16</Customer-ID>
      <FirstName>Colombo</FirstName>
      <LastName>Chao</LastName>
      <gmail/>
      <yahoo/>
      <liberto>chao.colombo@liberto.it</liberto>
      <URL/>
      <Facebook-ID/>
   </CONTACT>
</CONTACTS>
Добро пожаловать на сайт PullRequest, где вы можете задавать вопросы и получать ответы от других членов сообщества.

Нет похожих вопросов

...