Как вызвать Windows gethostbyaddr API с помощью BATCH-скрипта - PullRequest
Новая
       44

Как вызвать Windows gethostbyaddr API с помощью BATCH-скрипта

1 голос
/ 12 июня 2011

У меня уже есть небольшой скрипт на Perl для обратного просмотра, но он не переносим, ​​если на другой машине также не установлен Perl.Мне нужен скрипт, который может без проблем запускаться на компьютерах коллег, а также может быть преобразован в пользовательскую команду (путем обновления переменных среды PATH и PATHEXT).Файл сценария должен быть переносимым и доступным для пользователей без прав администратора.

Пакетный сценарий, кажется, подходит для этой цели, но я не могу понять, как вызвать API gethostbyaddr.Я полагаю, VBScript также является опцией и открыт для этого.

gethostbyaddr API

1 Ответ

0 голосов
/ 28 августа 2012

Вот два пакетных сценария. Надеюсь, по крайней мере, один может помочь. 

@ECHO OFF
::Lookup.bat
::http://www.computing.net/answers/programming/ip-by-hostname/25313.html
::Takes input file of hostnames and creates csv file with hostnames and IP addresses.
::Gets IP's using nslookup
:: Output in file hostnames.csv in current folder

if "%1"=="" goto :Syntax

SET SCRIPTPATH=%~p0
CD %SCRIPTPATH%

del hostnames.csv

for /f %%e in (%1) do call :LOOKUP %%e
echo Done!!!
goto :EOF

:LOOKUP
SET HOST1=%1
FOR /F "skip=4 tokens=2 delims=:" %%A IN ('2^>NUL nslookup %1') DO ( ECHO %1,%%A>>%SCRIPTPATH%hostnames.csv )
GOTO :EOF

:Syntax
echo.
echo Syntax:
echo.
echo %0 ^<FileName^>
echo.
echo   where ^<FileName^> is a file containing a list of hostnames.
echo.
echo   The batch file will return the results to file hostnames.csv in current folder
goto :EOF

@echo off
::gethostname.bat
::Takes input file of IP addresses and creates csv file with IP address and hostnames.
::Gets hostnames using netBIOS, which is usually accurate. If no info avail from
::netBIOS, then use nslookup. Plenty of debug statements in screen output. :)
:: Output in file C:\TEMP\ip-resolved.csv

if "%1"=="" goto :Syntax

SET SCRIPTPATH=%~p0
CD %SCRIPTPATH%

echo ip,hostname,power>C:\TEMP\ip-resolved.csv
for /f %%e in (%1) do call :PING-NBT %%e
echo Done!!!
goto :EOF

:PING-NBT
set ipaddress=%1
set host1=
echo.
echo ***Pinging %ipaddress%
SET ON=0
PING -n 1 %1 | find /i "Reply from" >nul && SET ON=1
echo Just parsed ping reply... host is %ON%
REM Next line skips netBIOS check if host is offline
IF "%ON%"=="0" GOTO :LOOKUP %ipaddress% %ON%
echo Proceeding to nbtstat with host %on%

REM The next lines check netBIOS name.
echo nbt1-start
for /f %%i in ('nbtstat -a %1^|find "<20>"') do @set host1=%%i
echo nbt=%host1% power=%ON%
REM If there isn't a NetBIOS name, then skips to nslookup section.
REM echo %2
if "%host1%"=="" goto :LOOKUP %1 %ON%
ECHO %ipaddress%,%host1%,%ON% >> C:\TEMP\ip-resolved.csv
echo nbt2-end
goto :EOF

:LOOKUP
echo nslookup1-start
for /f "tokens=2" %%i in ('nslookup %1^|find "Name:"') do @set host1=%%i
echo nslookup=%host1% power=%2
REM Next line=if host var 
rem if not "%host1%"=="%1" goto :EOF
ECHO %ipaddress%,%host1%,%2 >>C:\TEMP\ip-resolved.csv
set host1=
echo nslookup2-end
goto :EOF

:Syntax
echo.
echo Syntax:
echo.
echo %0 ^<FileName^>
echo.
echo   where ^<FileName^> is a file containing a list of IP addresses to
echo         which we need the hostname.
echo.
echo   The batch file will return the results via a file
echo   C:\TEMP\ip-resolved.csv
goto :EOF
...