Это на самом деле возможно, хотя и сложно.Я репостирую этот кусок магии от Кевина Джонса, также известного как Zorvek , когда он находится за EE Paywall (ссылка прикреплена, если у кого-то есть доступ)
Хотя ExcelСтрого запрещается UDF изменять любые свойства ячейки, листа или рабочей книги, есть способ осуществить такие изменения, когда UDF вызывается с использованием таймера Windows и таймера Application.OnTime по очереди.Таймер Windows должен использоваться в UDF, потому что Excel игнорирует любые вызовы Application.OnTime внутри UDF.Но, поскольку у таймера Windows есть ограничения (Excel будет мгновенно завершать работу, если таймер Windows пытается запустить код VBA, если ячейка редактируется или открывается диалоговое окно), он используется только для планирования таймера Application.OnTime, безопасного таймера.какой Excel разрешает запуск только в том случае, если ячейка не редактируется и диалоговые окна не открыты.
В приведенном ниже примере кода показано, как запустить таймер Windows из UDF, как использовать эту процедуру таймера для запускатаймер Application.OnTime и способ передачи информации, известной только UDF, в последующие подпрограммы, выполняемые таймером.Код ниже должен быть помещен в обычный модуль.
Private Declare Function SetTimer Lib "user32" ( _
ByVal HWnd As Long, _
ByVal nIDEvent As Long, _
ByVal uElapse As Long, _
ByVal lpTimerFunc As Long _
) As Long
Private Declare Function KillTimer Lib "user32" ( _
ByVal HWnd As Long, _
ByVal nIDEvent As Long _
) As Long
Private mCalculatedCells As Collection
Private mWindowsTimerID As Long
Private mApplicationTimerTime As Date
Public Function AddTwoNumbers( _
ByVal Value1 As Double, _
ByVal Value2 As Double _
) As Double
' This is a UDF that returns the sum of two numbers and starts a windows timer
' that starts a second Appliction.OnTime timer that performs activities not
' allowed in a UDF. Do not make this UDF volatile, pass any volatile functions
' to it, or pass any cells containing volatile formulas/functions or
' uncontrolled looping will start.
AddTwoNumbers = Value1 + Value2
' Cache the caller's reference so it can be dealt with in a non-UDF routine
If mCalculatedCells Is Nothing Then Set mCalculatedCells = New Collection
On Error Resume Next
mCalculatedCells.Add Application.Caller, Application.Caller.Address
On Error GoTo 0
' Setting/resetting the timer should be the last action taken in the UDF
If mWindowsTimerID <> 0 Then KillTimer 0&, mWindowsTimerID
mWindowsTimerID = SetTimer(0&, 0&, 1, AddressOf AfterUDFRoutine1)
End Function
Public Sub AfterUDFRoutine1()
' This is the first of two timer routines. This one is called by the Windows
' timer. Since a Windows timer cannot run code if a cell is being edited or a
' dialog is open this routine schedules a second safe timer using
' Application.OnTime which is ignored in a UDF.
' Stop the Windows timer
On Error Resume Next
KillTimer 0&, mWindowsTimerID
On Error GoTo 0
mWindowsTimerID = 0
' Cancel any previous OnTime timers
If mApplicationTimerTime <> 0 Then
On Error Resume Next
Application.OnTime mApplicationTimerTime, "AfterUDFRoutine2", , False
On Error GoTo 0
End If
' Schedule timer
mApplicationTimerTime = Now
Application.OnTime mApplicationTimerTime, "AfterUDFRoutine2"
End Sub
Public Sub AfterUDFRoutine2()
' This is the second of two timer routines. Because this timer routine is
' triggered by Application.OnTime it is safe, i.e., Excel will not allow the
' timer to fire unless the environment is safe (no open model dialogs or cell
' being edited).
Dim Cell As Range
' Do tasks not allowed in a UDF...
Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual
Do While mCalculatedCells.Count > 0
Set Cell = mCalculatedCells(1)
mCalculatedCells.Remove 1
Cell.Offset(0, 1).Value = Cell.Value
Loop
Application.Calculation = xlCalculationAutomatic
Application.ScreenUpdating = True
End Sub