Как динамически добавлять компоненты в TScrollBox один под другим при нажатии кнопки? - PullRequest
Новая
       55

Как динамически добавлять компоненты в TScrollBox один под другим при нажатии кнопки?

8 голосов
/ 08 июля 2011

Я создал один TScrollBox. Я добавил ярлык и поле редактирования динамически при нажатии кнопки. Для установки местоположения компонента я использовал свойство height, width, left, top компонентов. Но когда полоса прокрутки появляется на экране после добавления 5 компонентов, расположение следующих компонентов нарушается. и следующий компонент не размещается синхронно в ScrollBox.

1 Ответ

12 голосов
/ 08 июля 2011

Координата Top для элементов управления, помещенных в ScrollBox, должна учитывать количество «прокрутки», которая уже имела место. Если вы добавляете элементы управления одновременно, это не проблема, потому что ScrollBox не имеет возможности «прокручивать».

Если вы добавляете элементы управления в ScrollBox после , он получает возможность «прокручиваться», вам необходимо учитывать количество вертикальной «прокрутки», которая имела место. Вот пример кода, который добавит метки к ScrollBox1 с учетом вертикальной прокрутки, чтобы элементы управления не перекрывали друг друга. Здесь я использую свойство «Tag» формы для хранения Top для следующего добавленного элемента управления, а также использую Tag для генерации уникальных имен для меток (чтобы вы могли видеть, что они входят в ScrollBox с правильными координатами). 

procedure TForm31.Button1Click(Sender: TObject);
var L: TLabel;
begin
  L := TLabel.Create(Self);
  L.Caption := 'Test: ' + IntToStr(Tag);
  L.Parent := ScrollBox1;
  L.Top := Tag + ScrollBox1.VertScrollBar.Size - ScrollBox1.VertScrollBar.Position;
  Tag := Tag + L.Height;
end;

Другой подход, который я иногда использовал, - отслеживать последний добавленный элемент управления и основывать координаты нового элемента управления на координатах этого последнего добавленного элемента управления: 

var LastControl: TControl;

procedure TForm31.Button1Click(Sender: TObject);
var L: TLabel;
begin
  L := TLabel.Create(Self);
  L.Caption := 'Test: ' + IntToStr(Tag);
  L.Parent := ScrollBox1;
  if Assigned(LastControl) then
    L.Top := LastControl.Top + LastControl.Height
  else
    L.Top := 0;
  Tag := Tag + L.Height;

  LastControl := L;
end;

И еще один подход - найти самый низкий элемент управления и добавить свой элемент управления на основе его координат: 

procedure TForm31.Button1Click(Sender: TObject);
var L: TLabel;
    Bottom, TestBottom: Integer;
    i: Integer;
begin
  // Find "Bottom"
  Bottom := 0;
  for i:=0 to ScrollBox1.ControlCount-1 do
    with ScrollBox1.Controls[i] do
    begin
      TestBottom := Top + Height;
      if TestBottom > Bottom then
        Bottom := TestBottom;
    end;
  L := TLabel.Create(Self);
  L.Caption := 'Test: ' + IntToStr(Tag);
  L.Parent := ScrollBox1;
  L.Top := Bottom;
  Tag := Tag + L.Height;
end;
...