XSLT: как проверить множество узлов на определенное значение, примененное ко всем из них

Question

У меня есть следующий упрощенный источник XML:

<?xml version="1.0" encoding="UTF-8"?>
<MVKE>
<item>
    <MANDT>025</MANDT>
    <MATNR>000000000000000551</MATNR>
    <VMSTA>2</VMSTA>
</item>
<item>
    <MANDT>025</MANDT>
    <MATNR>000000000000000551</MATNR>
    <VMSTA>2</VMSTA>
</item>
<item>
    <MANDT>025</MANDT>
    <MATNR>000000000000000551</MATNR>   
    <VMSTA>2</VMSTA>
</item>
</MVKE>

и мне нужно сравнить значения <VMSTA>. Если все они равны «2», тогда мое значение флага в целевом XML должно сказать «true», иначе «false».

Я придумал этот XSLT:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output indent="yes" method="xml" encoding="UTF-8"/>

<xsl:template match="/">
    <list>
        <xsl:apply-templates select="MVKE"/>
    </list>
</xsl:template>

<xsl:template match="MVKE">
    <flag>
        <xsl:for-each select="item">
            <xsl:choose>
                <xsl:when
                    test="(preceding-sibling::*[1]/VMSTA or self::*/VMSTA = current()/VMSTA) and (current()/VMSTA='2')">
                    <xsl:value-of select="'true'"/>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="'false'"/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:for-each>
    </flag>
</xsl:template>

</xsl:stylesheet>

но вывод всегда

<?xml version="1.0" encoding="UTF-8"?>
<list>
<flag>truetruetrue</flag>
</list>

из-за <xsl:for-each>. Я также попробовал это с ключами на <VMSTA>, но это также дало мне 3 значения в <flag>. Как правильно сравнить 3 и получить только одно значение в <flag>? Я просто думаю о сложном?

Answer 1

Вам не нужно for-each. Предполагая, что узел контекста является элементом MVKE (как в вашем примере), следующее выражение возвращает true, когда все элементы VMSTA имеют строковое значение, равное 2 (и false, когда присутствует любое другое значение ):

not(item/VMSTA[not(.='2')])

Это работает из-за неявного преобразования item/VMSTA[not(.='2')] в логическое значение. Логическое значение набора узлов равно true тогда и только тогда, когда оно не пустое. Следовательно, item/VMSTA[not(.='2')] равен true всякий раз, когда он выбирает хотя бы один узел, то есть, когда существует элемент VMSTA, строковое значение которого не равно 2. Заключение выражения в not() приводит к его отрицанию, что является желаемым результатом.

Полный пример:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output indent="yes" method="xml" encoding="UTF-8"/>
    <xsl:template match="/">
        <list><xsl:apply-templates select="MVKE"/></list>
    </xsl:template>
    <xsl:template match="MVKE">
        <flag><xsl:value-of select="not(item/VMSTA[not(.='2')])"/></flag>
    </xsl:template>
</xsl:stylesheet>

Answer 2

Просто используйте :

not(/*/*/VMSTA[not(. = '2')])

Это выражение XPath оценивается как false(), если существует элемент /*/*/VMSTA, строковое значение которого отличается от строки "2".

В противном случае true().

Это можно назвать" законом двойного отрицания `

Answer 3

Я рекомендую использовать ключ, чтобы получить группу узлов с различными значениями для <VMSTA/>.Если в группе только один узел, то все значения идентичны:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output method="xml" indent="yes"/>
  <xsl:strip-space elements="*" />
  <xsl:key name="dupes" match="VMSTA" use="."/>

  <xsl:template match="/">
      <xsl:variable name="vmsta-count"
                    select="count(//VMSTA[generate-id() =
                                   generate-id(key('dupes', .))])"/>
      <list>
        <flag>
          <xsl:choose>
            <xsl:when test="$vmsta-count = 1">
              <xsl:text>true</xsl:text>
            </xsl:when>
            <xsl:otherwise>
              <xsl:text>false</xsl:text>
            </xsl:otherwise>
          </xsl:choose>
        </flag>
      </list>
  </xsl:template>
</xsl:stylesheet>

При запуске с предоставленным вами источником получается:

<?xml version="1.0"?>
<list>
  <flag>true</flag>
</list>

Но это общий случайрешение, и не заботится о фактической стоимости, только различия в стоимости.

Я надеюсь, что это помогает.