перемещение набора элементов в другой блок

Question

Ниже приведен xml, куда мне нужно переместить <employeeAddress> блок внутри <employeePersonalDeatails>

XML-файл:

<?xml version="1.0" encoding="UTF-8"?>
<employeeInfo xmlns="http://myweb.com">
    <employeePersonalDetails>
        <name>ABC</name>
        <Age>29</Age>
        <Sex>Male</Sex>
    </employeePersonalDetails>
    <employeeAddress>
        <Address>345, 4th main</Address>
        <country>LA</country>
        <pincode>560037</pincode>
    </employeeAddress>
</employeeInfo>

Ниже приведен xslt для перемещения <employeeAddress>

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:ns="http://myweb.com"
    version="1.0">
    <xsl:template match="*">
        <xsl:element name="{local-name()}">
            <xsl:apply-templates select="@*|node()"/>
        </xsl:element>
    </xsl:template>
    <xsl:template match="@*">
        <xsl:attribute name="{local-name()}">
            <xsl:value-of select="."/>
        </xsl:attribute>
    </xsl:template>

    <xsl:template match="/">
        <xsl:copy>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="//ns:employeePersonalDetails">
        <xsl:element name="{local-name()}"> 
            <xsl:apply-templates select="@*|node()"/>                 
        </xsl:element>
        <xsl:apply-templates select="//ns:employeeAddress"/>   
    </xsl:template>

</xsl:stylesheet>

Вывод вышеупомянутого xslt перемещает <employeeAddress> блок внутрь <employeePersonalDeatails>.Но это операция копирования и вставки.<employeeAddress> блок остается в том же положении.

вывод:

<?xml version="1.0" encoding="utf-8"?>
<employeeInfo>
    <employeePersonalDetails>
        <name>ABC</name>
        <Age>29</Age>
        <Sex>Male</Sex>
    </employeePersonalDetails><employeeAddress>
        <Address>345, 4th main</Address>
        <country>LA</country>
        <pincode>560037</pincode>
    </employeeAddress>
    <employeeAddress>
        <Address>345, 4th main</Address>
        <country>LA</country>
        <pincode>560037</pincode>
    </employeeAddress>
</employeeInfo>

В приведенном выше выводе мы видим, что <employeeAddress> дублируется.Нужно ли мне написать еще один xslt для удаления <employeeAddress>?или это можно сделать так же xslt.

Answer 1

Это преобразование :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ns="http://myweb.com">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

    <xsl:template match="*">
        <xsl:element name="{local-name()}">
            <xsl:apply-templates select="@*|node()"/>
        </xsl:element>
    </xsl:template>
    <xsl:template match="@*">
        <xsl:attribute name="{local-name()}">
            <xsl:value-of select="."/>
        </xsl:attribute>
    </xsl:template>

    <xsl:template match="/">
        <xsl:copy>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="//ns:employeePersonalDetails">
        <xsl:element name="{local-name()}">
            <xsl:apply-templates select="@*|node()"/>
            <xsl:apply-templates select="../ns:employeeAddress" mode="copy"/>
        </xsl:element>
    </xsl:template>

    <xsl:template mode="copy" match="*">
        <xsl:element name="{local-name()}">
            <xsl:apply-templates select="@*|node()"/>
        </xsl:element>
    </xsl:template>

    <xsl:template match="ns:employeeAddress"/>
</xsl:stylesheet>

при применении к предоставленному XML-документу :

<employeeInfo xmlns="http://myweb.com">
    <employeePersonalDetails>
        <name>ABC</name>
        <Age>29</Age>
        <Sex>Male</Sex>
    </employeePersonalDetails>
    <employeeAddress>
        <Address>345, 4th main</Address>
        <country>LA</country>
        <pincode>560037</pincode>
    </employeeAddress>
</employeeInfo>

создает искомое, правильный результат :

<employeeInfo>
   <employeePersonalDetails>
      <name>ABC</name>
      <Age>29</Age>
      <Sex>Male</Sex>
      <employeeAddress>
         <Address>345, 4th main</Address>
         <country>LA</country>
         <pincode>560037</pincode>
      </employeeAddress>
   </employeePersonalDetails>
</employeeInfo>

Пояснение : «Удаление» employeeAddress в анонимном режиме, обработка его в именованном режиме.