Проблемы с подключением и запросами в ADO - PullRequest
Новая
       21

Проблемы с подключением и запросами в ADO

0 голосов
/ 16 марта 2011

Я делаю файл .MDB, который включает базу данных ms access и форму, созданную с помощью vb 6. Я использую ms access 2000, и мне нужно подключиться как к моей локальной базе данных в MDB, так и к удаленному MS SQLБаза данных 2005 года.

В приведенном ниже коде я могу использовать msgbox для отображения значения, возвращаемого из набора результатов, но при попытке вывести его в textBox, например: txtStatus.Value = txtStatus.Value & rstRecordSet.Fields(1) & vbCrLf, он просто зависает.И метод, показанный в исходном примере из учебника, получил метод Debug.Print что-то, но оказалось, что не сделал ничего, что я вижу.Я имею в виду, что у VB нет консольной панели, куда пойдет оператор print?

Код с ошибкой: 

    Function Testing()
On Error GoTo Error_Handling
   Dim conConnection As New ADODB.Connection
   Dim cmdCommand As New ADODB.Command
   Dim rstRecordSet As New ADODB.Recordset

   conConnection.ConnectionString = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & _
   App.Path & "\" & CurrentDb.Name & ";"
   conConnection.CursorLocation = adUseClient

   With cmdCommand
    .ActiveConnection = conConnection
    .CommandText = "SELECT * FROM Opt_In_Customer_Record;"
    .CommandType = adCmdText
   End With

   With rstRecordSet
    .CursorType = adOpenStatic
    .CursorLocation = adUseClient
    .LockType = adLockOptimistic
    .Open cmdCommand
   End With

   If rstRecordSet.EOF = False Then
        rstRecordSet.MoveFirst
        Do
            MsgBox "Record " & rstRecordSet.AbsolutePosition & " " & _
          rstRecordSet.Fields(0).Name & "=" & rstRecordSet.Fields(0) & " " & _
          rstRecordSet.Fields(1).Name & "=" & rstRecordSet.Fields(1)
          rstRecordSet.MoveNext
        Loop Until rstRecordSet.EOF = True
   End If

   conConnection.Close
   Set conConnection = Nothing
   Set cmdCommand = Nothing
   Set rstRecordSet = Nothing

   Exit Function

Error_Handling:
MsgBox "Error during function Testing!"
Exit Function

End Function

1 Ответ

1 голос
/ 16 марта 2011

Сначала я думал, что это шутка ;-) В любом случае, я полагаю, вы говорите об ADO, как в вашем названии.

Здесь Вы можете найти вещи. Этот сайт поможет вам со строками подключения для другой базы данных.
Разница между доступом и сервером sql, использующим ADO, заключается именно в строке подключения. Я бы посоветовал вам избегать удаленного управления данными, потому что вначале вы упростите свою жизнь, но тогда вам придется бороться с ними, потому что они работают неправильно.

Это пример подключения и выборки данных: 

Dim cnn As New ADODB.Connection
Dim cmd As New ADODB.Command
Dim strSql As String

cnn.ConnectionString = _
    "Provider=Microsoft.Jet.OLEDB.4.0;" & _
    "Data Source=m:\testdbSource\testSource.mdb;" & _
    "User Id=admin;Password=;"
cnn.Open

cmd.ActiveConnection = cnn
cmd.CommandType = adCmdText
cmd.CommandText = "select * from tblSource"
cmd.Execute

Set cmd = Nothing
cnn.Close
Set cnn = Nothing

Этот образец работает для меня: 

Function Testing()

    On Error GoTo Error_Handling

    Dim MyDb As String
    Dim conConnection As New ADODB.Connection
    Dim cmdCommand As New ADODB.Command
    Dim rstRecordSet As New ADODB.Recordset

    MyDb = "db1.mdb"

    With conConnection
        .Provider = "Microsoft.Jet.OLEDB.4.0"
        .ConnectionString = App.Path & "\" & MyDb
        .Open
    End With


    With cmdCommand
        .ActiveConnection = conConnection
        .CommandText = "SELECT * FROM Opt_In_Customer_Record;"
        .CommandType = adCmdText
    End With

   With rstRecordSet
    .CursorType = adOpenStatic
    .CursorLocation = adUseClient
    .LockType = adLockOptimistic
    .Open cmdCommand
   End With

   Do While Not rstRecordSet.EOF
        MsgBox "Record " & rstRecordSet.AbsolutePosition & " " & _
          rstRecordSet.Fields(0).Name & "=" & rstRecordSet.Fields(0) & " " & _
          rstRecordSet.Fields(1).Name & "=" & rstRecordSet.Fields(1)
          rstRecordSet.MoveNext
   Loop

   conConnection.Close
   Set conConnection = Nothing
   Set cmdCommand = Nothing
   Set rstRecordSet = Nothing

   Exit Function

Error_Handling:
    MsgBox "Error during function Testing!"
    MsgBox Err.Description

End Function
...