Как мне обрабатывать вызовы удаленных методов через AsyncToken? - PullRequest
Новая
       22

Как мне обрабатывать вызовы удаленных методов через AsyncToken?

0 голосов
/ 25 мая 2011

Итак, вот mxml, который я хотел бы получить: 

<?xml version="1.0" encoding="utf-8"?>
<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009" 
               xmlns:s="library://ns.adobe.com/flex/spark" 
               xmlns:mx="library://ns.adobe.com/flex/mx" minWidth="955" minHeight="600">

    <fx:Script>
        <![CDATA[
            import argoseye.main.Golem;

            import mx.collections.ArrayCollection;
            import mx.rpc.AsyncResponder;
            import mx.rpc.AsyncToken;
            import mx.rpc.Responder;
            import mx.rpc.events.FaultEvent;
            import mx.rpc.events.InvokeEvent;
            import mx.rpc.events.ResultEvent;
            import mx.rpc.remoting.RemoteObject;
            protected function button1_clickHandler(event:MouseEvent):void
            {
                var ro:RemoteObject = new RemoteObject("destination");
                ro.endpoint = "http://Jesus/blazeds/messagebroker/amf";
                ro.addEventListener(InvokeEvent.INVOKE,onInvoke);

                var token:AsyncToken = new AsyncToken();
                token.addResponder(new AsyncResponder(onResult,onFault));

                token = ro.getCells();
                textfeld.text = textfeld.text + "Clickhandler called .... \n";

            }

            public function onResult(event:ResultEvent,token:Object):void {
                textfeld.text = textfeld.text + "Resulthandler called .... \n";
                var cellList:ArrayCollection = event.result as ArrayCollection;

            }

            public function onFault(event:FaultEvent,token:Object):void
            {
                textfeld.text = textfeld.text + "Faulthandler called .... \n";
            }

            public function onInvoke(event:InvokeEvent):void {
                textfeld.text = textfeld.text + "Invokehandler called .... \n";
            }
        ]]>
    </fx:Script>

    <fx:Declarations>
        <!-- Place non-visual elements (e.g., services, value objects) here -->
    </fx:Declarations>
    <s:Button x="1093" y="575" label="Button" click="button1_clickHandler(event)"/>
    <s:TextArea x="1022" y="183" id="textfeld"/>
</s:Application>

Вывод

Вызван Invokehandler ....

Вызван Clickhandler....

Resulthandler не вызывается, несмотря на то, что консоль BlazeDS регистрирует успешное Resultevent.Что я делаю не так?

Редактировать: я пытался экспортировать процедуру в класс, который должен управлять этими вещами.

package argoseye.main

{import flash.events.Event; 

import mx.collections.ArrayCollection;
import mx.messaging.ChannelSet;
import mx.messaging.channels.AMFChannel;
import mx.rpc.AsyncResponder;
import mx.rpc.AsyncToken;
import mx.rpc.events.FaultEvent;
import mx.rpc.events.ResultEvent;
import mx.rpc.remoting.RemoteObject;

public class Schem
{
    public var info:String="";


    public function Schem()
    {       
    }

    public function loadCurrentSchem():void
    {
        var ro:RemoteObject = new RemoteObject("Hibernatetest");
        ro.endpoint = "http://jesus/blazeds/messagebroker/amf";

        var token:AsyncToken = ro.getCells();
        token.addResponder(new AsyncResponder(onResult,onFault));

        info = info + "Loader Called ...";


    }

    public function onResult(event:ResultEvent,token:Object):void {
        var cellList:ArrayCollection = event.result as ArrayCollection;
        info = info + "Resulthandler Called";

    }

    public function onFault(event:FaultEvent,token:Object):void
    {

    }
    //Eventhandlers


    //Getters, Setters


}

}

Если я его вызываю, он не достигает обработчика событий.Где моя ошибка?

Ответы [ 2 ]

5 голосов
/ 25 мая 2011

Ваша ошибка заключается в следующих строках: 

var token:AsyncToken = new AsyncToken();
token.addResponder(new AsyncResponder(onResult,onFault));
token = ro.getCells();

Вы создаете новый токен в строке 1. Вы назначаете респондента в строке 2. А затем вы переназначаете токен в строке 3.

То, что вы делаете в строке 3, эффективно создает новый токен, поэтому к нему не присоединен респондент, потому что это новый экземпляр.

Так и должно быть: 

var token:AsyncToken = ro.getCells(); 
//ro.getCells() will return a new instance of AsyncToken
token.addResponder(new AsyncResponder(onResult,onFault));
2 голосов
/ 25 мая 2011

Используйте следующий код: 

<fx:Script>
    <![CDATA[
        import argoseye.main.Golem;

        import mx.collections.ArrayCollection;
        import mx.rpc.AsyncResponder;
        import mx.rpc.AsyncToken;
        import mx.rpc.Responder;
        import mx.rpc.events.FaultEvent;
        import mx.rpc.events.InvokeEvent;
        import mx.rpc.events.ResultEvent;
        import mx.rpc.remoting.RemoteObject;
        protected function button1_clickHandler(event:MouseEvent):void
        {
            var ro:RemoteObject = new RemoteObject("destination");
            ro.endpoint = "http://Jesus/blazeds/messagebroker/amf";
            ro.addEventListener(InvokeEvent.INVOKE,onInvoke);

            var token:AsyncToken = ro.getCells();
            token.addResponder(new AsyncResponder(onResult,onFault));
            textfeld.text = textfeld.text + "Clickhandler called .... \n";

        }

        public function onResult(event:ResultEvent,token:Object):void {
            textfeld.text = textfeld.text + "Resulthandler called .... \n";
            var cellList:ArrayCollection = event.result as ArrayCollection;

        }

        public function onFault(event:FaultEvent,token:Object):void
        {
            textfeld.text = textfeld.text + "Faulthandler called .... \n";
        }

        public function onInvoke(event:InvokeEvent):void {
            textfeld.text = textfeld.text + "Invokehandler called .... \n";
        }
    ]]>
</fx:Script>

<fx:Declarations>
    <!-- Place non-visual elements (e.g., services, value objects) here -->
</fx:Declarations>
<s:Button x="1093" y="575" label="Button" click="button1_clickHandler(event)"/>
<s:TextArea x="1022" y="183" id="textfeld"/>

...