Группировка при использовании 2 разных файлов XML в качестве источников? - PullRequest
Новая
       13

Группировка при использовании 2 разных файлов XML в качестве источников?

1 голос
/ 30 ноября 2011

я хочу сделать типичную группировку, которую обычно можно выполнить с помощью xsl: key, но она становится более сложной, поскольку данные для групп находятся в двух разных файлах.Как процесс?Вот пример того, что я хочу сделать, могу ли я попросить вашей помощи?должен быть совместим с xslt-1.0.

bookreference.xml: 

<t>  
    <book isbn="1">  
        <category>SF</category>  
    </book>  
    <book isbn="2">  
        <category>SF</category>  
    </book>  
    <book isbn="3">  
        <category>SF</category>  
    </book>  
    <book isbn="4">  
        <category>Comedy</category>  
    </book>  
    <book isbn="5">  
        <category>Comedy</category>  
    </book>
</t>

mylibrary.xml: 

<t>  
   <book isbn="1">
       <price>10</price>
   </book>
   <book isbn="2">
      <price>10</price>
   </book>       
   <book isbn="3">
      <price>20</price>
   </book>
   <book isbn="4">
      <price>5</price>
   </book>
</t>

желаемый вывод: 

SF : 3 book(s) - Total : 40$
Comedy : 2 book(s) - Total : 5$

Ответы [ 2 ]

0 голосов
/ 30 ноября 2011

Хороший вопрос, + 1.

Существует нет необходимости в сложной (более чем необходимой) группировке или для любых функций расширения : 

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kBookByCat" match="book"
      use="category"/>

 <xsl:key name="kPriceByIsbn" match="price"
      use="../@isbn"/>

 <xsl:variable name="vMyLib" select=
 "document('file:///c:/temp/delete/mylibrary.xml')"/>

 <xsl:template match=
  "book[generate-id()
       =
        generate-id(key('kBookByCat', category)[1])
        ]
  ">
     <xsl:variable name="vBooksinCat" select=
          "key('kBookByCat', category)"/>

     <xsl:value-of select="category"/> : <xsl:text/>
     <xsl:value-of select="count($vBooksinCat)"/>
     <xsl:text> book(s) - Total : $</xsl:text>

     <xsl:for-each select="$vMyLib">
      <xsl:value-of select="sum(key('kPriceByIsbn', $vBooksinCat/@isbn))"/>
      <xsl:text>&#xA;</xsl:text>
     </xsl:for-each>
 </xsl:template>
 <xsl:template match="text()"/>
</xsl:stylesheet>

Когда это преобразование применяется к первому из двух предоставленных фрагментов данных (исправлено в правильно сформированном документе XML): 

<t>
    <book isbn="1">
        <category>SF</category>
    </book>
    <book isbn="2">
        <category>SF</category>
    </book>
    <book isbn="3">
        <category>SF</category>
    </book>
    <book isbn="4">
        <category>Comedy</category>
    </book>
    <book isbn="5">
        <category>Comedy</category>
    </book>
</t>

и второй фрагмент данных (исправленный в правильно сформированный XML-документ) сохраненный как C:\Temp\Delete\mylibrary.xml,

Требуется правильный результат : 

SF : 3 book(s) - Total : $40
Comedy : 2 book(s) - Total : $5
0 голосов
/ 30 ноября 2011

Как уже предлагалось в моем комментарии, вы можете сначала объединить два документа в фрагмент дерева результатов, а затем использовать exsl: node-set, чтобы получить набор узлов, к которому затем можно применить группировку Мюнхена: 

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:exsl="http://exslt.org/common"
  exclude-result-prefixes="exsl"
  version="1.0">

  <xsl:param name="price-url" select="'test2011113002.xml'"/>
  <xsl:variable name="doc2" select="document($price-url)"/>

  <xsl:output method="text"/>

  <xsl:variable name="rtf">
    <xsl:apply-templates select="//book" mode="merge"/>
  </xsl:variable>

  <xsl:template match="book" mode="merge">
    <xsl:copy>
      <xsl:variable name="isbn" select="@isbn"/>
      <xsl:copy-of select="@* | node()"/>
      <xsl:for-each select="$doc2">
        <xsl:copy-of select="key('k1', $isbn)/price"/>
      </xsl:for-each>
    </xsl:copy>
  </xsl:template>

  <xsl:key name="k1" match="book" use="@isbn"/>
  <xsl:key name="k2" match="book" use="category"/>

  <xsl:template match="/">
    <xsl:apply-templates select="exsl:node-set($rtf)/book[generate-id() = generate-id(key('k2', category)[1])]"/>
  </xsl:template>

  <xsl:template match="book">
    <xsl:variable name="current-group" select="key('k2', category)"/>
    <xsl:value-of select="concat($current-group/category, ': ', count($current-group), ' - Total : ', sum($current-group/price), '&#10;')"/>
  </xsl:template>

</xsl:stylesheet>
...