Perl массив против списка

Question

У меня есть две структуры данных в Perl:

Массив:

my @array2 = ( "1", "2", "3");

for $elem (@array2) {
    print $elem."\n";
}

Дает мне следующий вывод:

1
2
3

И список:

my @array = [ "1", "2", "3"];                                            

for $elem (@array) {
    print $elem."\n";
}

Дает следующий вывод:

ARRAY(0x9c90818)

Очевидно, я хотел бы перебрать элементы в обоих случаях, но почему второе решение дает мне только ссылку на этот массив?

Answer 1

Списки в Perl не являются структурами данных, это позиции в исходном коде, определяемые контекстом вокруг них. Списки - это в основном временные структуры, которые Perl использует для перемещения данных. Вы взаимодействуете с ними со всем синтаксисом Perl, но не можете работать с ними как с типом данных. Наиболее близким к списку типом данных является массив.

my @var    =    (1, 2, 3);  # parens needed for precedence, they do not create a list
   ^ an array    ^ a list

say 1, 2, 3;
    ^ a list

say @var;
    ^ a list (of one array, which will expand into 3 values before `say` is called)

Когда вы пишете [1, 2, 3], вы создаете ссылку на скалярный массив. Эта ссылка на массив инициализируется списком 1, 2, 3, и это то же самое, что создание именованного массива и получение ссылки на него:

[1, 2, 3]   ~~   do {my @x = (1, 2, 3); \@x}

Поскольку конструкция [...] создает скаляр, вы должны держать его в скаляре:

my $array = [1, 2, 3];                                            

for my $elem (@$array) {   # lexical loop variable
    print $elem."\n";
}

Поскольку вы хотите работать со всем массивом, а не только со ссылкой, вы помещаете @ перед $array, который разыменовывает ссылку на сохраненный массив.

Answer 2

Квадратные скобки используются для создания анонимного массива.При оценке он возвращает ссылку на этот массив, а не фактические значения массива.

Скобки не имеют такого скрытого свойства, а просто переопределяют приоритет внутри выражений, как в математике.Например:

my @array = 1,2,3;

Фактически оценивается так:

my @array = 1;
2,3; # causes the warning "Useless use of constant in void context"

, поскольку оператор = имеет более высокий приоритет, чем запятые.Таким образом, чтобы обойти это, мы используем круглые скобки при назначении массивов, например так:

my @array = (1,2,3);

Ваш пример:

my @array = [1,2,3];

выглядит примерно так:

my @tmp = (1,2,3);
my @array = \@tmp;

Где \ используется для создания ссылки на массив @tmp.

Answer 3

Квадратные скобки создают анонимный массив, заполняют массив содержимым скобок и возвращают ссылку на этот массив.Другими словами,

[ "1", "2", "3" ]

в основном совпадает с

do { my @anon = ("1", "2", "3"); \@anon }

, поэтому код должен выглядеть так:

my $array_ref = [ "1", "2", "3" ];

for (@$array_ref) {  # Short for @{ $array_ref }
    print "$_\n";
}

или

my @array_of_refs = ([ "1", "2", "3" ]);

for my $array_ref (@array_of_refs) {
    for (@$array_ref) {
        print "$_\n";
    }
}

Answer 4

Если вам нужны дополнительные разъяснения, см. соответствующую документацию .

Вы можете попробовать сделать некоторые вещи для иллюстрации:

#!perl -lw # -l appends a \n to each print, -w enables warnings
use strict;
my $aryref = [1 .. 5];
print for $aryref;    # Prints the stringified reference - not what you want
print for @$aryref;   # Dereferencing it lets you access the array
my @ary = $aryref;    # Probably not what you want
print for @ary;       # Stringified reference again
print for @{$ary[0]}; # Dereference the first array element (which holds the ref)

Answer 5

@ array = ("1", "2", "3"); Здесь 1,2,3 - элемент переменной @array.Например$ array [0] равно 1, $ array [1] равно 2, а $ array [2] равно 3.

@ array = ["1", "2", "3"]; Perl использует анонимные ссылки на массивы, используя [], поэтому здесь в основном только один элемент, который вы храните, и это ссылка массива ["1", "2", "3"] на переменную @array.для ex $ array [0] это "ARRAY (0x9c90818)"
Следовательно, при печати он показывает вам ссылки.

Answer 6

В Perl массивы и списки - одно и то же, но ваш второй пример не использует ни того, ни другого. Квадратные скобки окружают массив ссылка (скалярное значение), а "присвоение" скаляра массиву с чем-то вроде my @array = $scalar эквивалентно my @array = ($scalar). Таким образом, единственный элемент @array во втором примере - это ссылка на массив.