Несколько фоновых субрегионов в сетке Mathematica - PullRequest
Новая
       38

Несколько фоновых субрегионов в сетке Mathematica

5 голосов
/ 25 мая 2011

Я не могу понять, как определить несколько субрегионов с различным цветом фона, как показано ниже.

Любая идея?

Большое спасибо,

LA 

Grid[Table["g", {4}, {7}],
Background -> {None, None, {{{1, 3}, {1, 3}} -> LightRed}}]

Ответы [ 2 ]

7 голосов
/ 25 мая 2011

Как примечание, обычным требованием является указание цветов фона в зависимости от значений.

Для этого вы можете сделать: 

k = Table[RandomInteger[{1, 2}], {4}, {7}];
Grid[k,
 Background ->
  {None, None,
   Join[
    Position[k, 1] /. {x_, y_} -> ({x, y} -> LightRed), 
    Position[k, 2] /. {x_, y_} -> ({x, y} -> LightBlue)]
   }]

enter image description here

Редактировать

Если вы не знаете априори диапазон значений, вы можете попробовать что-то вроде: 

k = Table[RandomInteger[{1, 20}], {4}, {7}];
Grid[k,
 Frame -> All,
 ItemStyle -> Directive[FontSize -> 16], 
 Background ->
  {None, None, 
   Flatten@Array[List[##] ->
                   ColorData["Rainbow"][(k[[##]] - Min@k) / Max@k] &, 
           Dimensions@k]
  }  
]

enter image description here

6 голосов
/ 25 мая 2011

Просто перечислите регионы и цвета, как у вас уже есть первый: 

Grid[Table["g", {4}, {7}], 
 Background -> {None, None, {
    {{1, 3}, {1, 3}} -> LightRed,
    {{3, 4}, {4, 7}} -> LightBlue
  } } ]

enter image description here

...