Перетаскивание Flex между AdvancedDataGrid и пользовательским itemRenderer - PullRequest
Новая
       36

Перетаскивание Flex между AdvancedDataGrid и пользовательским itemRenderer

0 голосов
/ 26 февраля 2011

Я реализовал перетаскивание между 2 AdvancedDataGrid, но поведение Flex по умолчанию отображает данные строк во время перетаскивания с использованием средства визуализации элементов сетки, показывая все 5 столбцов.

Вместо этого я хотел бы отображать значок / изображение или мой собственный инструмент визуализации элементов при перетаскивании и брось. Что было бы проще всего?

Какой-нибудь пример?

Спасибо!

Ответы [ 2 ]

1 голос
/ 26 февраля 2011

Подкласс AdvancedDataGrid и переопределить одно свойство: 

public class MyAdvancedDataGrid extends AdvancedDataGrid
{

    public function MyAdvancedDataGrid()
    {
        super();
    }

    [Embed("script.png")]
    private var scriptClass:Class;

    override protected function get dragImage():IUIComponent
    {
        var image:Image = new Image();
        image.source = scriptClass;
        image.owner = this;
        image.moduleFactory = moduleFactory;
        return image; 
    }
}
0 голосов
/ 28 февраля 2011

Вы можете использовать свойство перетаскивания для указания изображения.Из онлайн-примеров Adobe : 

<?xml version="1.0"?>
<!-- dragdrop\DandDImageProxy.mxml -->
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml">

    <mx:Script>
        <![CDATA[
            //Import classes so you don't have to use full names.
            import mx.managers.DragManager;
            import mx.core.DragSource;
            import mx.events.DragEvent;
            import flash.events.MouseEvent;

            // Embed icon image.
            [Embed(source='assets/globe.jpg')]
            public var globeImage:Class;

            // The mouseMove event handler for the Image control
            // initiates the drag-and-drop operation.
            private function mouseOverHandler(event:MouseEvent):void 
            {                
                var dragInitiator:Image=Image(event.currentTarget);
                var ds:DragSource = new DragSource();
                ds.addData(dragInitiator, "img");               

                // The drag manager uses the Image control 
                // as the drag proxy and sets the alpha to 1.0 (opaque),
                // so it appears to be dragged across the Canvas.
                var imageProxy:Image = new Image();
                imageProxy.source = globeImage;
                imageProxy.height=15;
                imageProxy.width=15;                
                DragManager.doDrag(dragInitiator, ds, event, 
                    imageProxy, -15, -15, 1.00);
            }

            // The dragEnter event handler for the Canvas container
            // enables dropping.
            private function dragEnterHandler(event:DragEvent):void {
                if (event.dragSource.hasFormat("img"))
                {
                    DragManager.acceptDragDrop(Canvas(event.currentTarget));
                }
            }

            // The dragDrop event handler for the Canvas container
            // sets the Image control's position by 
            // "dropping" it in its new location.
            private function dragDropHandler(event:DragEvent):void {
                Image(event.dragInitiator).x = 
                    Canvas(event.currentTarget).mouseX;
                Image(event.dragInitiator).y = 
                    Canvas(event.currentTarget).mouseY;
            }
        ]]>
    </mx:Script>

    <!-- The Canvas is the drag target --> 
    <mx:Canvas id="v1" 
        width="500" height="500"  
        borderStyle="solid" 
        backgroundColor="#DDDDDD"
        dragEnter="dragEnterHandler(event);" 
        dragDrop="dragDropHandler(event);">

        <!-- The image is the drag initiator. -->
        <mx:Image id="myimg" 
            source="@Embed(source='assets/globe.jpg')" 
            mouseMove="mouseOverHandler(event);"/> 
    </mx:Canvas>
</mx:Application>
...