Как избавиться от атрибута xmlns = "" (no-namespace) в выводе XSLT - PullRequest
Новая
       0

Как избавиться от атрибута xmlns = "" (no-namespace) в выводе XSLT

7 голосов
/ 20 апреля 2011

Вот мой (упрощенный для этого случая сценарий) XML: 

<?xml version="1.0" encoding="UTF-8"?>
<?xml-stylesheet href="test_1.xsl" type="text/xsl"?>

<doc xmlns="http://www.foo.org">
  <div>
    <title>Mr. Title</title>
    <paragraph>This is one paragraph.
    </paragraph>
    <paragraph>Another paragraph.
    </paragraph>
  </div>
</doc>

А вот мой XSLT: 

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:foo="http://www.foo.org">

<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="foo:doc">
  <xsl:element name="newdoc" namespace="http://www/w3.org/1999/xhtml">
   <xsl:apply-templates/>
  </xsl:element>
 </xsl:template>

 <xsl:template match="foo:div">
  <segment title="{foo:title}">
   <xsl:apply-templates/>
  </segment>
 </xsl:template>

 <xsl:template match="foo:title">
  <xsl:element name="h2">
   <xsl:apply-templates/>
  </xsl:element>
 </xsl:template>

 <xsl:template match="foo:paragraph">
  <xsl:element name="p">
   <xsl:apply-templates/>
  </xsl:element>
 </xsl:template>

</xsl:stylesheet>

Выход выдает это: 

<newdoc xmlns="http://www/w3.org/1999/xhtml">
  <segment xmlns="" title="Mr. Title">
    <h2>Mr. Title</h2>
    <p>This is one paragraph.
    </p>
    <p>Another paragraph.
    </p>
  </segment>
</newdoc>

, что замечательно, за исключением xmlns = "" в элементе сегмента, который, похоже, не определяет пространства имен для себя и всех своих дочерних элементов. Как сделать так, чтобы это не добавлялось?

Sidenote: я также пытался преобразовать первый узел с помощью 

<xsl:template match="mydoc:doc">
  <html xmlns="http://www/w3.org/1999/xhtml">
   <xsl:apply-templates/>
  </html>
 </xsl:template>

вместо этого, но он производит тот же эффект.

Спасибо, полезные люди!

Ответы [ 2 ]

11 голосов
/ 20 апреля 2011

Кажется, что вы хотите поместить все элементы в выходном документе в пространство имен "http://www/w3.org/1999/xhtml"". В настоящее время вы указываете только пространство имен для элемента "newdoc", все остальные элементы находятся в пространстве имен по умолчанию, так как пространство имен отсутствуетобъявление в вашей таблице стилей. Вложенность внутри таблицы стилей определяет, к какому пространству имен относятся элементы, а не вложение после преобразования.

Вы можете объявить пространство имен по умолчанию в вашей таблице стилей, чтобы повлиять на все остальные неквалифицированные элементы: 

<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:foo="http://www.foo.org"
    xmlns="http://www.w3.org/1999/xhtml">

Теперь вам больше не нужен тег xsl:element, и вы можете напрямую использовать newdoc для создания элемента в правильном пространстве имен.

4 голосов
/ 20 апреля 2011

В шаблоне foo:div вы создаете элемент segment с пустым пространством имен. Поскольку родительский элемент имеет другое пространство имен, процессор должен добавить это объявление пространства имен.

Если вы хотите получить segment с тем же пространством имен, что и у родительского, тогда используйте xsl:element вместо: 

<xsl:template match="foo:div">
    <xsl:element name="segment">
        <xsl:attribute name="title">
            <xsl:value-of select="foo:title"/>
        </xsl:attribute>
        <xsl:apply-templates/>
    </xsl:element>
</xsl:template>
Добро пожаловать на сайт PullRequest, где вы можете задавать вопросы и получать ответы от других членов сообщества.

Нет похожих вопросов

...