Вот мое первое решение:
РЕШЕНИЕ 1
@echo off
set test_script=.pyexe.py
rem Let's create temporary Python script which prints info we need
echo from __future__ import print_function; import sys; print(sys.executable); print(sys.version) > %test_script%
echo Python accessible through system PATH:
python %test_script%
echo ---
echo Python set as handler for Python files:
%test_script%
del %test_script%
set test_script=
Однако я столкнулся с проблемой.Когда нет действительного интерпретатора Python, связанного с файлами Python, при попытке открыть файл Python с помощью some_script.py появляется системное диалоговое окно Open With .Решение этой проблемы требует очень хороших знаний о пакетных файлах.Поэтому, пытаясь найти решение, я задал следующие вопросы:
Улучшенная версия исходного пакетного файла теперь выглядит следующим образом:
РЕШЕНИЕ 1b
@echo off
setlocal
set test_script=.pyexe.py
rem Let's create temporary Python script which prints info we need
echo from __future__ import print_function; import sys; print(sys.executable); print(sys.version) > %test_script%
echo Python accessible through the system PATH:
python %test_script%
echo ---
echo Python set as a handler for Python files:
rem We need to check if a handler set in the registry exists to prevent "Open With"
rem dialog box in case it doesn't exist
rem ftype Python.File hypothetical return value:
rem Python.File="%PYTHON_HOME%\python.exe" "%1" %*
for /f "tokens=2 delims==" %%i in ('ftype Python.File') do set reg_entry=%%i
rem ...now in 'reg_entry' variable we have everything after equal sign:
rem "%PYTHON_HOME%\python.exe" "%1" %*
set "handler="
setlocal enableDelayedExpansion
for %%A in (!reg_entry!) do if not defined handler endlocal & set handler=%%A
rem ...now in 'handler' variable we have the first token:
rem "%PYTHON_HOME%\python.exe"
rem Now we expand any environment variables that might be present
rem in the handler's path
for /f "delims=" %%i in ('echo %handler%') do set expanded_handler=%%i
if exist "!expanded_handler!" (
"%test_script%"
) else (
if not "!handler!" == "!expanded_handler!" (
set "handler=!expanded_handler! ^(!handler!^)"
)
echo Handler is set to !handler! which does not exist
)
del %test_script%
Это еще одно решение, позволяющее избежать проблем, указанных выше:
РЕШЕНИЕ 2
@echo off
setlocal
echo Python accessible through the system PATH:
where python
echo ---
echo Python set as a handler for Python source files (.py):
for /f "skip=2 tokens=1,2*" %%i in ('reg query HKCR\.py /ve') do set "file_type=%%k"
for /f "skip=2 tokens=1,2*" %%i in ('reg query HKCR\%file_type%\shell\open\command /ve') do echo %%k
... и улучшеноверсия:
РЕШЕНИЕ 2b
@echo off
setlocal EnableDelayedExpansion
echo Python interpreter accessible through the system PATH:
where python
if not errorlevel 1 (
python -c "from __future__ import print_function; import sys; print(sys.version)"
)
echo ---
echo Python interpreter registered as a handler for Python source files (.py):
reg query HKCR\.py /ve >nul 2>&1
if errorlevel 1 (
echo No "HKEY_CLASSES_ROOT\.py" registry key found
) else (
for /f "skip=2 tokens=1,2*" %%i in ('reg query HKCR\.py /ve 2^>nul') do set "file_type=%%k"
if "!file_type!"=="(value not set)" (
echo "No file type set for .py extension"
) else (
reg query HKCR\!file_type!\shell\open\command /ve >nul 2>&1
if errorlevel 1 (
echo No "HKEY_CLASSES_ROOT\!file_type!\shell\open\command" registry key found
) else (
for /f "skip=2 tokens=1,2*" %%i in ('reg query HKCR\!file_type!\shell\open\command /ve 2^>nul') do set "handler=%%k"
if "!handler!"=="(value not set)" (
echo No command set for !file_type!
) else (
echo !handler!
)
)
)
)