XSLT: перенести текст элемента в родительский элемент и удалить элемент

Question

Это мой XML:

<?xml version="1.0" encoding="UTF-8"?>
<?xml-stylesheet href="test_2.xsl" type="text/xsl"?>

<doc xmlns="http://www.foo.org">
  <div>
    <title>Mr. Title</title>
    <paragraph>This is one paragraph.
    </paragraph>
    <paragraph>Another paragraph.
    </paragraph>
    <list>
      <orderedlist>
        <item>
          <paragraph>An item paragraph.</paragraph>
        </item>
        <item>
          <paragraph>Another item paragraph</paragraph>
        </item>
      </orderedlist>
    </list>
  </div>    
</doc>

Мой XML избавляется от списка, меняет упорядоченный список на ol, меняет элемент на li.Теперь я хотел бы избавиться от узлов абзаца, которые являются потомками элемента, при переносе текста в новый li.Обратите внимание, что я не хочу избавляться от узлов абзаца, которые НЕ являются потомками элемента.

Пока это мой XSLT:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:foo="http://www.foo.org">

<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="foo:doc">
  <xsl:element name="newdoc" namespace="http://www/w3.org/1999/xhtml">
   <xsl:apply-templates/>
  </xsl:element>
 </xsl:template>

 <xsl:template match="foo:div">
  <segment title="{foo:title}">
   <xsl:apply-templates/>
  </segment>
 </xsl:template>

 <xsl:template match="foo:title">
  <xsl:element name="h2">
   <xsl:apply-templates/>
  </xsl:element>
 </xsl:template>

 <xsl:template match="foo:paragraph">
  <xsl:element name="p">
   <xsl:apply-templates/>
  </xsl:element>
 </xsl:template>

 <xsl:template match="foo:list">
  <xsl:apply-templates/>
 </xsl:template>

 <xsl:template match="foo:orderedlist">
  <xsl:element name="ol">
   <xsl:apply-templates/>
  </xsl:element>
 </xsl:template>

 <xsl:template match="foo:item">
  <xsl:element name="li">
   <xsl:apply-templates/>
  </xsl:element>
 </xsl:template>

</xsl:stylesheet>

Вывод такой:

<newdoc xmlns="http://www/w3.org/1999/xhtml">
  <segment xmlns="" title="Mr. Title">
    <h2>Mr. Title</h2>
    <p>This is one paragraph.
    </p>
    <p>Another paragraph.
    </p>

      <ol>
        <li>
          <p>An item paragraph.</p>

        </li>
        <li>
          <p>Another item paragraph</p>
        </li>
      </ol>

  </segment>    
</newdoc>

Бонус: я также хотел бы избавиться от пустых строк и исправить странное форматирование, вызванное удалением узла списка с помощью

 <xsl:template match="foo:list">
  <xsl:apply-templates/>
 </xsl:template>

, поэтому, если кто-нибудь знает лучший способудалить узел, я хотел бы услышать его.

Большое спасибо!

Answer 1

Эта таблица стилей:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:foo="http://www.foo.org"
 xmlns="http://www/w3.org/1999/xhtml"
 exclude-result-prefixes="foo">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
    <xsl:strip-space elements="*"/>
    <xsl:preserve-space elements="foo:paragraph"/>
    <xsl:template match="foo:doc">
        <newdoc>
            <xsl:apply-templates/>
        </newdoc>
    </xsl:template>
    <xsl:template match="foo:div">
        <segment title="{foo:title}">
            <xsl:apply-templates/>
        </segment>
    </xsl:template>
    <xsl:template match="foo:title">
        <h2>
            <xsl:apply-templates/>
        </h2>
    </xsl:template>
    <xsl:template match="foo:paragraph">
        <p>
            <xsl:apply-templates/>
        </p>
    </xsl:template>
    <xsl:template match="foo:orderedlist">
        <ol>
            <xsl:apply-templates/>
        </ol>
    </xsl:template>
    <xsl:template match="foo:item">
        <li>
            <xsl:apply-templates/>
        </li>
    </xsl:template>
    <xsl:template match="foo:item/foo:paragraph">
        <xsl:apply-templates/>
    </xsl:template>
</xsl:stylesheet>

Вывод:

<newdoc xmlns="http://www/w3.org/1999/xhtml">
   <segment title="Mr. Title">
      <h2>Mr. Title</h2>
      <p>This is one paragraph.     </p>
      <p>Another paragraph.     </p>
      <ol>
         <li>An item paragraph.</li>
         <li>Another item paragraph</li>
      </ol>
   </segment>
</newdoc>

Примечание : В настоящее время ваша таблица стилей представляет собой беспорядок в пространствах имен.Используйте @exclude-result-prefixes.Исправьте только пробельные текстовые узлы с помощью объявлений xsl:strip-space и xsl:preserve-space.

Answer 2

Просто добавьте более конкретное правило для абзацев, которые являются потомками списков:

<xsl:template match="foo:item/foo:paragraph">
  <xsl:apply-templates/>
</xsl:template>

То же самое относится к вашему бонусному вопросу, если я правильно понимаю вопрос: не копируйте чисто пробельные текстовые узлы, которые являются потомками элементов списка.

<xsl:template match="foo:item/text()[normalize-space(.)='']" />