Изменение поведения модуля в OCaml

Question

У меня есть набор целых, чей ввод я бы хотел ограничить.Я хотел бы, чтобы он вел себя примерно так:

# RestrictedIntSet.add 15 (RestrictedIntSet.make 0 10)
Exception: 15 out of acceptable range [0 .. 10]

Как я могу это реализовать?В Java это может выглядеть примерно так:

Set<Integer> restrictedSet = new HashSet<Integer>() {
    public boolean add(Integer i) {
        if (i < lowerBound || i > upperBound) {
            throw new IllegalArgumentException("out of bounds");
        }
        return super.add(i);
    }

Или, чтобы меньше злоупотреблять наследованием:

public class RestrictedSet {

   private int lowerBound;
   private int upperBound;
   private Set elems = Sets.newHashSet();

   public RestrictedSet(int lowerBound, int upperBound) {
      this.lowerBound = lowerBound;
      this.upperBound = upperBound;
   }

   public boolean add(Integer i) {
      if (i < lowerBound || i > upperBound) {
         throw new IllegalArgumentException("out of bounds");
      }
      return elems.add(i);   
   }

   /* fill in other forwarded Set calls as needed */
}

Какой эквивалентный идиоматический способ сделать это в OCaml?1010 *

Answer 1

Ну, это зависит от того, какую библиотеку set вы используете?

Используя модуль Set стандартной библиотеки, вы можете сделать следующее:

module type RestrictedOrderedType = sig
  type t
  val compare : t -> t -> int
  val lower_bound : t
  val upper_bound : t
end

module RestrictedSet (Elem : RestrictedOrderedType) = struct
  include Set.Make(Elem)

  exception Not_in_range of Elem.t

  let check e =
    if Elem.compare e Elem.lower_bound < 0
     || Elem.compare e Elem.upper_bound > 0
    then raise (Not_in_range e)
    else e

  (* redefine a new 'add' in term of the one in Set.Make(Elem) *)
  let add e s = add (check e) s

  let singleton e = singleton (check e)
end


(* test *)
module MySet = RestrictedSet(struct
  type t = int
  let compare = compare
  let lower_bound = 0
  let upper_bound = 10
end)

let test1 = MySet.singleton 3

let test2 = MySet.add (-3) test1
(* Exception: Not_in_range (-3) *)

Answer 2

Мне нравится ответ @ gasches.

В качестве краткого дополнения: модуль Set в OCaml предназначен для создания экземпляра модулем OrderedType, что означает, что вы не можете напрямую использовать нативные int s OCaml напрямую.

Таким образом, необходимо использовать модуль, который соответствует запрошенной подписи. Определение подписью RestrictedOrderedType, выполненное gasche, делает это и элегантно включает в себя нижнюю и верхнюю граничные поля. Более грубым подходом было бы использование модулей Int32 или Int64 OCaml, которые соответствуют запрошенной сигнатуре OrderedType, и жесткое кодирование границ в модуле MySet.

Ниже приведена небольшая переформулировка примера Гаше, чтобы проиллюстрировать этот момент.

  module MySet = struct
    include Set.Make(Int32)

    exception Not_in_range of Int32.t  

    let lower_bound = Int32.of_int 5

    let upper_bound = Int32.of_int 10

    let add elt set = 
      if (elt < lower_bound)||(elt > upper_bound)
      then raise (Not_in_range elt)
      else add elt set

  end;;