Определение массива анонимных объектов в CoffeeScript

Question

Как определить массив анонимных объектов в CoffeeScript? Возможно ли это вообще, используя синтаксис YAML?

Я знаю, что иметь массив именованных объектов довольно просто:

items:[
   item1:
      name1:value1
   item2:
      name:value2
]

Однако было бы немного хитрее, если бы эти два объекта не имели имен

Answer 1

Простой - поместите запятую в столбец ниже, чем тот, в котором вы определяете свои объекты.

a = [
     nameA1: valueA1
     nameA2: valueA2
     nameA3: valueA3
  ,
     nameB1: valueB1
     nameB2: valueB2
     nameB3: valueB3
]

Будет:

var a;

a = [
  {
    nameA1: valueA1,
    nameA2: valueA2,
    nameA3: valueA3
  }, {
    nameB1: valueB1,
    nameB2: valueB2,
    nameB3: valueB3
  }
];

Answer 2

Вы также можете добавить кому между каждым объектом:

items:[
    item1:
        name1:value1
  ,
    item2:
        name:value2
]

Answer 3

вы не можете:

это несколько хитростей:

items:[
    (name:"value1")
    (name:"value2")
]

другой

items:[
    true && name:"value1"
    true && name:"value2"
]

это лучшее:

items:[
    {name:"value1"}
    {name:"value2"}
]

Answer 4

Я думаю, что решение с запятой лучше, но я решил добавить это для полноты:

a = [
  {
    nameA1: valueA1
    nameA2: valueA2
    nameA3: valueA3
  }
  {
    nameB1: valueB1
    nameB2: valueB2
    nameB3: valueB3
  }
]

Answer 5

Вы можете определить переменную при определении массива, поэтому уродливый ответ будет:

a = 
  items: [
    item1 = 
      name: 'value1'
    item2 = 
      name: 'value2'
  ]

Это сработает, но вы можете получить предупреждения об «определенных, но не используемых переменных (item1, item2)». Лучше было бы использовать подчеркивание, переменную, используемую для пропуска неиспользуемых переменных:

a = 
  items: [
    _ = 
      name: 'value1'
    _ = 
      name: 'value2'
  ]

console.log JSON.stringify(a) будет производить это:

  {
    "items":[
      {
        "name":"value1"
      },{
        "name":"value2"
      }
    ]
  }

Answer 6

Я очень рад сообщить, что после небольшого переворота я могу заставить его правильно скомпилировать:

items: [
  nameA: subA
  nameB: subB
,
  nameX: subX
  nameY: subY
]

В результате получается то, что вы ожидаете: список двух анонимных объектов.

Answer 7

Не ответ на вопрос ОП, но на всякий случай, если вы здесь по той же причине, по которой я был ... Если у вас мало Маунтин Дью и вы используете '=' вместо ':', то Coffeescript превратить ваш массив объектов в плоский массив без ошибки компиляции:

data = [
    one='one'
    two='two'
  ,
    one='1'
    two='2'
]

Производит

['one', 'two', '1', '2']

Вставьте еще Mountain Dew и замените '=' на ':'.

Answer 8

Почему бы и нет:

list = []
list.push
  prop1: val
  prop2: val
list.push
  prop1: val
  prop2: val

Это все еще огромное улучшение по сравнению с js, очень легко читаемое, минимальное и довольно безопасное для написания.

Answer 9

Я столкнулся с связанной проблемой и нашел это решение. Если вам нужен массив из множества одиночных k / v-объектов без фигурных скобок, просто сделайте отступ для некоторых из них. Кажется, чтобы сделать трюк.

data = [                                     
  "2013-09-25T16:46:52.636Z":3,              
    "2013-09-25T16:47:52.636Z":6,            
      "2013-09-25T16:48:52.636Z":2,          
        "2013-09-25T16:49:52.636Z":7,        
  "2013-09-25T16:50:52.636Z":5,              
    "2013-09-25T16:51:52.636Z":2,            
      "2013-09-25T16:52:52.636Z":1,          
        "2013-09-25T16:53:52.636Z":3,        
  "2013-09-25T16:54:52.636Z":8,              
    "2013-09-25T16:55:52.636Z":9,            
      "2013-09-25T16:56:52.636Z":2,          
        "2013-09-25T16:57:52.636Z":5,        
          "2013-09-25T16:58:52.636Z":7       
]                                            

Производит:

coffee> data
[ { '2013-09-25T16:46:52.636Z': 3 },
  { '2013-09-25T16:47:52.636Z': 6 },
  { '2013-09-25T16:48:52.636Z': 2 },
  { '2013-09-25T16:49:52.636Z': 7 },
  { '2013-09-25T16:50:52.636Z': 5 },
  { '2013-09-25T16:51:52.636Z': 2 },
  { '2013-09-25T16:52:52.636Z': 1 },
  { '2013-09-25T16:53:52.636Z': 3 },
  { '2013-09-25T16:54:52.636Z': 8 },
  { '2013-09-25T16:55:52.636Z': 9 },
  { '2013-09-25T16:56:52.636Z': 2 },
  { '2013-09-25T16:57:52.636Z': 5 },
  { '2013-09-25T16:58:52.636Z': 7 } ]

Это нелогично для меня; можно подумать, что это приведет к созданию подобъектов, но я думаю, что запятая в конце строки говорит ей прекратить создавать свойства для этого объекта.