XSLT Преобразование нескольких файлов из подкаталога

Question

Я создал XSLT-файл, который может преобразовывать один XML-файл. Тем не менее, у меня есть несколько сотен каталогов с несколькими файлами XML. Есть ли способ в XSLT преобразовать все эти файлы. Я использую функцию сбора, чтобы получить список всех файлов. Но не знаю, как применить преобразование сейчас.

Вот мой пример XSLT-файла. По сути, я хочу просмотреть все файлы xml и применить таблицу шаблонов к отдельному файлу. Вывод всех этих преобразований должен быть в одном текстовом файле.

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:foo="http://whatever">

<xsl:output method="text" encoding="ISO-8859-1"/>
    <xsl:template name="process">
        <xsl:variable name="files" select="collection('file:///C:/files/testResults?select=*.xml;recurse=yes')"/>
        <xsl:for-each select="$files">
            <xsl:if test="(not(contains(document-uri(.), 'SuiteSetUp'))) and (not(contains(document-uri(.), 'SuiteTearDown')))">
                <xsl:value-of select="tokenize(document-uri(.), '/')[last()]"></xsl:value-of>
                <xsl:apply-templates select="/testResults/result/tables/table[14]">
                    <xsl:with-param name="title" select="/testResults/rootPath"></xsl:with-param>
                </xsl:apply-templates>
                <xsl:apply-templates select="/testResults/result/tables/table[15]"/>
            </xsl:if>
        </xsl:for-each>
    </xsl:template>

    <xsl:template match="table">
    <xsl:param name="testName"></xsl:param>
        <xsl:for-each select="row">
            <xsl:if test="position() > 2">
                <xsl:variable name="choices" select="col[2]"></xsl:variable>
                <xsl:if test="contains($choices, 'fail')">
                    <xsl:value-of  select="$testName"></xsl:value-of>
                    <xsl:text>|</xsl:text>
                    <xsl:value-of select="col[1]"></xsl:value-of>
                    <xsl:text>|</xsl:text>
                    <xsl:value-of select="foo:getCorrectChoices(col[2])"></xsl:value-of>
                    <xsl:text>|</xsl:text>
                    <xsl:value-of select="foo:getExpectedChoices(col[2])"></xsl:value-of>
                    <xsl:text>|</xsl:text>
                    <xsl:call-template name="NewLine"/>
                </xsl:if>
            </xsl:if>
        </xsl:for-each>
    </xsl:template>

    <xsl:template name="NewLine">
        <xsl:text>&#xA;</xsl:text>
    </xsl:template>

    <xsl:function name="foo:getCorrectChoices">
        <xsl:param name="content"></xsl:param>
        <xsl:analyze-string select="$content" regex="\[(\[.+?\])\] fail">
            <xsl:matching-substring>
                <xsl:value-of select="regex-group(1)"></xsl:value-of>
            </xsl:matching-substring>
        </xsl:analyze-string>
    </xsl:function>
    <xsl:function name="foo:getExpectedChoices">
        <xsl:param name="content"></xsl:param>
        <xsl:analyze-string select="$content" regex="fail\(expected \[(\[.+?\])\]">
            <xsl:matching-substring>
                <xsl:value-of select="regex-group(1)"></xsl:value-of>
            </xsl:matching-substring>
        </xsl:analyze-string>
    </xsl:function>
</xsl:stylesheet>

Answer 1

Вот, пожалуй, самый простой пример того, как обрабатывать все xml-файлы в поддереве файловой системы (используя функцию collection(), реализованную в Saxon):

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="node()|@*" mode="inFile">
     <xsl:copy>
       <xsl:apply-templates mode="inFile" select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="/">
   <xsl:apply-templates mode="inFile" select=
   "collection('file:///C:/temp?select=*.xml;recurse=yes')"/>
 </xsl:template>
</xsl:stylesheet>

При применении к любому документу XML (не используется, игнорируется), это преобразование применяет правило идентификации к каждому документу XML, содержащемуся в любом из *.xml файлов в поддереве C:/Temp файловой системы.

Для выполнениядля более тщательной обработки необходимо переопределить шаблон идентификации - в режиме inFile.

Я полагаю, что в вашем конкретном случае вы можете просто заменить :

            <xsl:apply-templates select="/testResults/result/tables/table[14]">     

с

            <xsl:apply-templates select="./testResults/result/tables/table[14]">    

, и это применяет требуемые шаблоны к узлам, выбранным из текущего (документа) узла.

Answer 2

Я просто хотел добавить облегченную версию превосходного ответа Димитра. Если у вас есть <foo> документы (корневой узел), находящиеся в каталоге, и работающая программа XSLT для <foo>, просто сделайте ваш шаблон верхнего уровня следующим образом:

<xsl:template match="/">
    <xsl:apply-templates select="collection($my_url)/foo"/>
</xsl:template>

Предполагается, что вы хотите указать URL-адрес в качестве параметра <xsl:param name="my_url"/>, указанного в командной строке.