SimpleNode дочерний элемент в JJTree - PullRequest
Новая
       13

SimpleNode дочерний элемент в JJTree

1 голос
/ 30 ноября 2011

Я прочитал в учебнике, что когда вы делаете что-то подобное: 

SimpleNode Program() #Program : {} 
{
    (Class_decl())* <EOF>

    { return jjtThis; }
}

он должен создать класс Programm, который наследуется от SimpleNode (после компиляции с jjtree), но в моем случае это нет создать такой как класс.Нужно ли создавать его самому или я что-то упустил?

Спасибо

1 Ответ

3 голосов
/ 30 ноября 2011

Вы впервые используете jjtree в своей грамматике (до javacc)?Он прекрасно работает со мной:

file: Test.jjt 

options {
  MULTI=true;
  NODE_PREFIX="";
}

PARSER_BEGIN(Test)
public class Test {
  public static void main(String[] args) throws Exception {
    Test parser = new Test(new java.io.StringReader("class A; class B;"));
    SimpleNode root = parser.Program();
    root.dump("");
  }
}
PARSER_END(Test)

TOKEN :
{
     < CLASS : "class" >
  |  < SCOL  : ";" >
  |  < ID    : (["a"-"z","A"-"Z"])+ >
}

SKIP :
{
  " " | "\t" | "\r" | "\n"
}

SimpleNode Program() #Program : 
{} 
{
  (Class_decl())* <EOF> {return jjtThis;}
}

void Class_decl() #ClassDecl :
{}
{    
  <CLASS> <ID> <SCOL>
}

И затем команды: 

jjtree Test.jjt
javacc Test.jj

, которая генерирует следующие исходные файлы Java: 

ClassDecl.java
JJTTestState.java
Node.java
Program.java
SimpleNode.java
TestTreeConstants.java

И оба ClassDecl и Program extension SimpleNode: 

/* Generated By:JJTree: Do not edit this line. Program.java Version 4.3 */
/* JavaCCOptions:MULTI=true,NODE_USES_PARSER=false,VISITOR=false,TRACK_TOKENS=false,NODE_PREFIX=,NODE_EXTENDS=,NODE_FACTORY=,SUPPORT_CLASS_VISIBILITY_PUBLIC=true */
public
class Program extends SimpleNode {
  ...
}

/* Generated By:JJTree: Do not edit this line. ClassDecl.java Version 4.3 */
/* JavaCCOptions:MULTI=true,NODE_USES_PARSER=false,VISITOR=false,TRACK_TOKENS=false,NODE_PREFIX=,NODE_EXTENDS=,NODE_FACTORY=,SUPPORT_CLASS_VISIBILITY_PUBLIC=true */
public
class ClassDecl extends SimpleNode {
  ...
}

Компиляция всех исходных файлов и запуск класса Test: 

javac -cp . *.java
java -cp . Test

который напечатает: 

Program
 ClassDecl
 ClassDecl

(то есть Program - это корень с двумя ClassDecl дочерними элементами)

Протестировано с компилятором Java версии 5.0.

...