Стиль CSS и XSLT? - PullRequest
Новая
       7

Стиль CSS и XSLT?

3 голосов
/ 22 июня 2011

Если я выберу тег DIV в файле XHTML с помощью XSLT, например //*[@id='background'] Как добавить стиль, например, цвет фона или другие стили CSS, например, границы для DIV? И если у меня есть список внутри фона DIV ID =, как я могу оформить список, например, удалить маркеры? :)

1 Ответ

5 голосов
/ 22 июня 2011

Это действительно легко с XSLT. Например, ваш ввод: 

<html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en">
    <head>
        <title></title>
    </head>
    <body>
        <div id="background">
            <ul style="list-style-type: bullet">
                <li>Coffee</li>
                <li>Tea</li>
                <li>Milk</li>
            </ul>       
        </div>
    </body>
</html>

Вы можете использовать преобразование идентичности, чтобы скопировать входной XML как есть и переопределить интересующие узлы: 

<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns="http://www.w3.org/1999/xhtml"
    xmlns:x="http://www.w3.org/1999/xhtml"
    exclude-result-prefixes="x">

    <xsl:output method="xml" indent="yes"/>

    <xsl:strip-space elements="*"/>

    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*" />
        </xsl:copy>
    </xsl:template>

    <xsl:template match="x:div[@id='background']">
        <xsl:copy>
            <xsl:attribute name="style">
                <xsl:text>border-style:solid;border-width:medium</xsl:text>
            </xsl:attribute>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="x:ul[ancestor::*
        [name()='div' and @id='background']]/@style">
        <xsl:attribute name="style">
            <xsl:text>list-style-type: none</xsl:text>
        </xsl:attribute>
    </xsl:template>

</xsl:stylesheet>

Вывод будет: 

<html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en">
   <head>
      <title></title>
   </head>
   <body>
      <div style="border-style:solid;border-width:medium" id="background">
         <ul style="list-style-type: none">
            <li>Coffee</li>
            <li>Tea</li>
            <li>Milk</li>
         </ul>
      </div>
   </body>
</html>
Добро пожаловать на сайт PullRequest, где вы можете задавать вопросы и получать ответы от других членов сообщества.

Нет похожих вопросов

...