Groovys XmlParser игнорирует CDATA CR / CL

Question

Я хочу проанализировать сгенерированный log4j XML-журнал.Внутри xml находится узел с бросаемым (если есть).Этот текст (многострочный, с вкладками) инкапсулирован в тег CDATA.

Это фрагмент всего файла:

<log4j:event logger="org.codehaus.groovy.grails.web.errors.GrailsExceptionResolver" timestamp="1330083921521" level="ERROR" thread="http-8080-1">
<log4j:message><![CDATA[Exception occurred when processing request: [GET] /test/log/show
Stacktrace follows:]]></log4j:message>
<log4j:throwable><![CDATA[org.xml.sax.SAXParseException: XML document structures must start and end within the same entity.
    at com.sun.org.apache.xerces.internal.parsers.AbstractSAXParser.parse(AbstractSAXParser.java:1231)
    at com.sun.org.apache.xerces.internal.jaxp.SAXParserImpl$JAXPSAXParser.parse(SAXParserImpl.java:522)
    at test.LogController$_closure2.doCall(LogController.groovy:21)
    at test.LogController$_closure2.doCall(LogController.groovy)
    at java.lang.Thread.run(Thread.java:662)
]]></log4j:throwable>
</log4j:event>

Я анализирую его с помощью groovys XmlParser:

def parser = new XmlParser(false, false).parse(new File("stack.log"))

return parser.'log4j:event'.collect { l ->
    LogEntry entry = new LogEntry()
    entry.with {
        level = l.'@level'
        message = l.'log4j:message'.text()
        thread = l.'@thread'
        logger = l.'@logger'
        timestamp = new Date(l.'@timestamp' as long)
        throwable = l.'log4j:throwable'?.text() ?: ''
    }
    entry
}

Поле «throwable» содержит весь текст, но без CR / LF.

Кто-нибудь знает, как с этим справиться?

Заранее спасибо ...

Answer 1

Ненавижу просто бросать код в вас, но, похоже, он работает так, как ожидалось, и возвращает CRLF

def xml = '''<log>
            |  <log4j:event logger="org.codehaus.groovy.grails.web.errors.GrailsExceptionResolver" timestamp="1330083921521" level="ERROR" thread="http-8080-1">
            |    <log4j:message><![CDATA[Exception occurred when processing request: [GET] /test/log/show
            |Stacktrace follows:]]></log4j:message>
            |    <log4j:throwable><![CDATA[org.xml.sax.SAXParseException: XML document structures must start and end within the same entity.
            |    at com.sun.org.apache.xerces.internal.parsers.AbstractSAXParser.parse(AbstractSAXParser.java:1231)
            |    at com.sun.org.apache.xerces.internal.jaxp.SAXParserImpl$JAXPSAXParser.parse(SAXParserImpl.java:522)
            |    at test.LogController$_closure2.doCall(LogController.groovy:21)
            |    at test.LogController$_closure2.doCall(LogController.groovy)
            |    at java.lang.Thread.run(Thread.java:662)
            |]]></log4j:throwable>
            |  </log4j:event>
            |</log>'''.stripMargin()


class LogEntry {
  def level
  def message
  def thread
  def logger
  def timestamp
  def throwable

  String toString() {
    """EVENT:
      |  level   : $level
      |  message : $message
      |  thread  : $thread
      |  logger  : $logger
      |  ts      : $timestamp
      |  thrown  : $throwable""".stripMargin()
  }
}

def parser = new XmlParser(false, false).parseText( xml )
def entries = parser.'log4j:event'.collect { event ->
  new LogEntry().with {
    level     = event.@level
    message   = event.'log4j:message'.text()
    thread    = event.@thread
    logger    = event.@logger
    timestamp = new Date( event.@timestamp as long )
    throwable = event.'log4j:throwable'?.text() ?: ''
    it
  }
}

entries.each {
  println it
}

, который печатает:

EVENT:
  level   : ERROR
  message : Exception occurred when processing request: [GET] /test/log/show
Stacktrace follows:
  thread  : http-8080-1
  logger  : org.codehaus.groovy.grails.web.errors.GrailsExceptionResolver
  ts      : Fri Feb 24 11:45:21 GMT 2012
  thrown  : org.xml.sax.SAXParseException: XML document structures must start and end within the same entity.
    at com.sun.org.apache.xerces.internal.parsers.AbstractSAXParser.parse(AbstractSAXParser.java:1231)
    at com.sun.org.apache.xerces.internal.jaxp.SAXParserImpl$JAXPSAXParser.parse(SAXParserImpl.java:522)
    at test.LogController$_closure2.doCall(LogController.groovy:21)
    at test.LogController$_closure2.doCall(LogController.groovy)
    at java.lang.Thread.run(Thread.java:662)

В котором есть символы CRLFони должны быть ...

Это с Groovy 1.8.6 кстати ... Какую версию вы используете?Можете ли вы обновить и попробовать еще раз?

Answer 2

Стандарт xml требует нормализации пробела во время синтаксического анализа.

Я не уверен, но синтаксический анализатор может иметь настройку для переопределения этого поведения.В противном случае вы можете предварительно обработать файл, заменив окончания строк внутри секций данных c их эквивалентами сущностей xml, а затем проанализировать его.