ANTLR грамматика для квази-цитат Схемы - PullRequest
Новая
       42

ANTLR грамматика для квази-цитат Схемы

1 голос
/ 13 июня 2011

Учитывая следующую грамматику в EBNF:
http://pauillac.inria.fr/cdrom_a_graver/www/bigloo/manual/r5rs-8.html

Заданная там грамматика квазиквотирования не является контекстно-свободной: 

<quasiquotation> --> <quasiquotation 1>
<qq template 0> --> <expression>
<quasiquotation D> --> `<qq template D>
       | (quasiquote <qq template D>)
<qq template D> --> <simple datum>
       | <list qq template D>
       | <vector qq template D>
       | <unquotation D>
<list qq template D> --> (<qq template or splice D>*)
       | (<qq template or splice D>+ .  <qq template D>)
       | '<qq template D>
       | <quasiquotation D+1>
<vector qq template D> --> #(<qq template or splice D>*)
<unquotation D> --> ,<qq template D-1>
       | (unquote <qq template D-1>)
<qq template or splice D> --> <qq template D>
       | <splicing unquotation D>
<splicing unquotation D> --> ,@<qq template D-1>
       | (unquote-splicing <qq template D-1>)

Возможно ли определить грамматику для этого в ANTLR, хотя она разработана для контекстно-свободных грамматик?

1 Ответ

1 голос
/ 14 июня 2011

Вы можете добавить параметры к правилам как лексера, так и парсера, добавив после него [int d], например: foo[int d] : ... ;.Передать параметр 1 в правило foo так же просто, как parse : foo[1];:

Конечно, это не обязательно должен быть int, но может быть любой тип.

Так, в вашем случае, сделайте что-то вроде этого: 

quasiquotation
  :  quasiquotationD[1]
  ;

quasiquotationD[int d]
  :  '`' qqTemplate[d]
  |  '(' QUASIQUOTE qqTemplate[d] ')'
  ;

qqTemplate[int d]
  :  (expression)=>  expression
  |  ('(' UNQUOTE)=> unquotation[d]
  |                  simpleDatum
  |                  vectorQQTemplate[d]
  |                  listQQTemplate[d]
  ;

vectorQQTemplate[int d]
  :  '#(' qqTemplateOrSplice[d]* ')'
  ;

listQQTemplate[int d]
  :                     '\'' qqTemplate[d]
  |  ('(' QUASIQUOTE)=> quasiquotationD[d+1]
  |                     '(' (qqTemplateOrSplice[d]+ ('.' qqTemplate[d])?)? ')'
  ;

unquotation[int d]
  :  ',' qqTemplate[d-1]
  |  '(' UNQUOTE qqTemplate[d-1] ')'
  ;

qqTemplateOrSplice[int d]
  :  ('(' UNQUOTE_SPLICING)=> splicingUnquotation[d]
  |                           qqTemplate[d]
  ;

splicingUnquotation[int d]
  :  ',@' qqTemplate[d-1]
  |  '(' UNQUOTE_SPLICING qqTemplate[d-1] ')'
  ;

Обратите внимание, что есть также некоторые синтаксические предикаты, ( ... )=>, для объяснения некоторых неясностей в грамматике.

Для полноговерсия спецификации R5RS в ANTLR, см. этот ответ .

...