AS3 - клонировать объект класса, когда класс имеет параметризованный конструктор - PullRequest
Новая
       8

AS3 - клонировать объект класса, когда класс имеет параметризованный конструктор

1 голос
/ 09 мая 2011

Я хочу клонировать объект класса.Я попытался сделать следующее из здесь : 

package
{
    import flash.net.registerClassAlias;
    import flash.utils.ByteArray;

    public class MyClass
    {
        public var property1:String;
        public var property2:Array;

        public function clone():MyClass
        {
            registerClassAlias("MyClass", MyClass);

            var bytes:ByteArray = new ByteArray();
            bytes.writeObject(this);
            bytes.position = 0;

            return bytes.readObject() as MyClass;
        }
    }
}

НО это работает, только когда у класса есть конструктор по умолчанию, а не когда у него есть параметризованный конструктор:

Любая идея о том, какклонировать объект класса, когда у класса есть параметризованный конструктор?

С уважением

Ответы [ 3 ]

2 голосов
/ 09 мая 2011

Это лучшее, что я могу для вас сделать: 

package
{

    import flash.display.Sprite;


    public class Thing extends Sprite
    {

        // Cloneable properties.
        private var _cloneable:Array = ["x","y","val1","val2"];


        // Properties.
        public var val1:uint = 10;
        public var val2:String = "ten";


        /**
         * Returns a new Thing with the same properties.
         */
        public function clone():Thing
        {
            var t:Thing = new Thing();

            for each(var i:String in _cloneable)
            {
                t[i] = this[i];
            }

            return t;
        }

    }

}

Все, что вам нужно сделать, это добавить свойства, которые вы хотите иметь клонируемые, к _cloneable

Пример использования: 

var thing:Thing = new Thing();

thing.x = 15;
thing.y = 10;
thing.val1 = 25;
thing.val2 = "twentyfive";

// Clone initial Thing.
var thing2:Thing = thing.clone();

trace(thing2.x, thing2.y, thing2.val1, thing2.val2); // 15 10 25 twentyfive
0 голосов
/ 25 июня 2012

Вы можете создать класс с конструктором, который имеет необязательные параметры. Это хорошая практика с точки зрения управляемой тестированием разработки и производительности.

0 голосов
/ 28 июня 2011

Мое предложение состояло бы в том, чтобы не делать это слишком сложным и не обдумывать вещи. На самом деле нет необходимости делать что-то более сложное, чем это. 

 public function clone():Thing {
     var t:Thing = new Thing();

     t.x = this.x;
     t.y = this.y;
     t.val1 = this.val1;
     t.val2 = this.val2;

     return t;
 }

и если у вас есть параметры в конструкторе. 

public function Thing(x:int,y:int) {
    this.x = x;
    this.y = y;
}

public function clone():Thing {
    var t:Thing = new Thing(this.x, this.y);

    t.val1 = this.val1;
    t.val2 = this.val2;

    return t;
}

Мне нравится другой ответ, он умный, но очень утомительный, просто для установки некоторых свойств. Не переоценивайте проблему.

...