Разрыв строки в XSL

Question

Я пытался использовать XSL для вывода списка клиентов в XML-файле, но между значениями нет разрывных линий

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output 
  method="html"
  encoding="ISO-8859-1"
  doctype-public="-//W3C//DTD HTML 4.01//EN"
  doctype-system="http://www.w3.org/TR/html4/strict.dtd"
  indent="yes" />
    <xsl:template match="/">
        <xsl:apply-templates select="//client"/>
    </xsl:template>

    <xsl:template match="//client">
     <xsl:value-of select="./nom/." />
    </xsl:template>
</xsl:stylesheet>

Выход

DoeNampelluro

Нормально я хочу получить

Doe
Nam
Pelluro

Я позволил отступ = "да", но это не делает работу

Answer 1

Прежде всего, приведенный код XSLT довольно странный :

<xsl:template match="//client">
  <xsl:value-of select="./nom/." />
</xsl:template>

Это намного лучше написано как эквивалент :

<xsl:template match="client">
 <xsl:value-of select="nom" />
</xsl:template>

И способ вывода многострочного текста ... ну, использовать символ новой строки:

<xsl:template match="client">
 <xsl:value-of select="nom" />
 <xsl:if test="not(position()=last())">
   <xsl:text>&#xA;</xsl:text>
 </xsl:if>
</xsl:template>

Вот полное преобразование:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="client">
  <xsl:value-of select="nom" />
  <xsl:if test="not(position()=last())">
    <xsl:text>&#xA;</xsl:text>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

когда это преобразование применяется к следующему документу XML:

<t>
 <client>
   <nom>A</nom>
 </client>
 <client>
   <nom>B</nom>
 </client>
 <client>
   <nom>C</nom>
 </client>
</t>

желаемый, правильный результат получается:

A
B
C

Если вы хотите создать вывод xHtml (не только текст), то вместо символа NL должен быть создан элемент <br> :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="client">
  <xsl:value-of select="nom" />
  <xsl:if test="not(position()=last())">
    <br />
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

Теперь вывод :

A<br/>B<br/>C

и отображается в браузере как :

А
Б
С

Answer 2

просто добавьте: <br/> тег.это работает для меня.

Answer 3

<xsl:for-each select="allowedValueList/allowed">
**<br/>**<xsl:value-of select="." />
</xsl:for-each>

Answer 4

Я узнал, что

<xsl:strip-space elements="*" />

добивается цели.