XSLT не может группировать / сортировать узлы по значению - PullRequest
Новая
       21

XSLT не может группировать / сортировать узлы по значению

1 голос
/ 17 марта 2011

Я пытаюсь преобразовать этот XML. Однако у меня проблемы с форматированием. Может кто-нибудь, пожалуйста, направьте меня, чтобы решить эту проблему. Заранее спасибо 

<?xml version="1.0" encoding="windows-1252"?>
<XML>
    <Attributes>
        <Attribute>
            <id>5</id>
            <Name>Buyer ID</Name>
            <Type>common</Type>
            <Value>Lee</Value>
        </Attribute>
        <Attribute>
            <id>331</id>
            <Name>Enviornment</Name>
            <Type>common</Type>
            <Value>Development</Value>
        </Attribute>
        <Attribute>
            <id>79</id>
            <Name>Retail</Name>
            <Type>common</Type>
            <Value></Value>
        </Attribute>
        <Attribute>
            <id>402</id>
            <Name>Gender</Name>
            <Type>category</Type>
            <Value>Men</Value>
        </Attribute>
        <Attribute>
            <id>433</id>
            <Name>HeelHeight</Name>
            <Type>category</Type>
            <Value></Value>
        </Attribute>
        <Attribute>
            <id>41</id>
            <Name>PlusShip</Name>
            <Type>common</Type>
            <Value>False</Value>
            <Path></Path>
        </Attribute>
    </Attributes>
</XML>

В следующий XML. Может кто-нибудь дать мне несколько советов о том, как преобразовать этот xml на основе значения Атрибуты / Атрибут / Тип 

<?xml version="1.0" encoding="utf-8" ?>
<Data Schema="XML A">
  <Attributes type="Common">
    <Attr id="" name="Buyer ID" value="Lee" />
    <Attr id="" name="Enviornment" value="Development" />
    <Attr id="" name="Retail" value="" />
    <Attr id="" name="PlusShip" value="False" />
 </Attributes>
 <Attributes type="Category">
   <Attr id="" name="Gender" value="Men" />
   <Attr id="" name="HeelHeight" value="" />
 </Attributes>

1 Ответ

0 голосов
/ 18 марта 2011

Следующая таблица стилей дает желаемый результат: 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="/">
        <Data Schema="XML A">
            <xsl:apply-templates/>
        </Data>
    </xsl:template>
    <xsl:template match="Attribute[not(Type=following::Type)]">
        <Attributes type="{Type}">
            <xsl:for-each select="../Attribute[Type=current()/Type]">
               <Attr id="{id}" name="{Name}" value="{Value}"/>
            </xsl:for-each>
        </Attributes>
    </xsl:template>
    <xsl:template match="Attribute"/>
</xsl:stylesheet>

Вывод в исходном документе: 

<Data Schema="XML A">
    <Attributes type="category">
        <Attr id="402" name="Gender" value="Men"/>
        <Attr id="433" name="HeelHeight" value=""/>
    </Attributes>
    <Attributes type="common">
        <Attr id="5" name="Buyer ID" value="Lee"/>
        <Attr id="331" name="Enviornment" value="Development"/>
        <Attr id="79" name="Retail" value=""/>
        <Attr id="41" name="PlusShip" value="False"/>
    </Attributes>
</Data>

Редактировать: Хорошо, давайте избавимся от этого уродливого for-each: 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="/">
        <Data Schema="XML A">
            <xsl:apply-templates/>
        </Data>
    </xsl:template>
    <xsl:template match="Attribute[not(Type=following::Type)]">
        <Attributes type="{Type}">
            <xsl:apply-templates 
                 select="../Attribute[Type=current()/Type]" mode="out"/>
        </Attributes>
    </xsl:template>
    <xsl:template match="Attribute" mode="out">
        <Attr id="{id}" name="{Name}" value="{Value}"/>
    </xsl:template>
    <xsl:template match="Attribute"/>
</xsl:stylesheet>

Я чувствую себя намного лучше.

Редактирование # 2: Использование метода Мюнхена (с сортировкой): 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:key name="type" match="Attribute" use="Type"/>
    <xsl:template match="/">
        <Data Schema="XML A">
            <xsl:apply-templates select="XML/Attributes/Attribute">
                 <xsl:sort select="Type" order="descending"/>
            </xsl:apply-templates>
        </Data>
    </xsl:template>
    <xsl:template 
            match="Attribute[generate-id()=generate-id(key('type', Type)[1])]">
        <Attributes type="{Type}">
            <xsl:apply-templates 
                    select="../Attribute[Type=current()/Type]" mode="out"/>
        </Attributes>
    </xsl:template>
    <xsl:template match="Attribute" mode="out">
         <Attr id="{id}" name="{Name}" value="{Value}"/>
    </xsl:template>
    <xsl:template match="Attribute"/>
</xsl:stylesheet>

Создает следующий (упорядоченный) вывод: 

<Data Schema="XML A">
    <Attributes type="common">
        <Attr id="5" name="Buyer ID" value="Lee"/>
        <Attr id="331" name="Enviornment" value="Development"/>
        <Attr id="79" name="Retail" value=""/>
        <Attr id="41" name="PlusShip" value="False"/>
    </Attributes>
    <Attributes type="category">
        <Attr id="402" name="Gender" value="Men"/>
        <Attr id="433" name="HeelHeight" value=""/>
   </Attributes>
</Data>
...