Путь к значку приложения в MS Access

Question

Как получить доступ к пути значков приложений в MS Access 2003 программно?

Answer 1

Это пользовательское свойство ("AppIcon") объекта базы данных.

Set dbs = CurrentDb
sAppIconPath = dbs.Properties("AppIcon")

Примечание - вы получите ошибку, если свойство не существует.

Этот код из справки Access показывает, как создать свойство:

Пример

В следующем примере показано, как изменить свойства AppIcon и AppTitle в базе данных Microsoft Access (.mdb). Если свойства еще не были установлены или созданы, их необходимо создать и добавить в коллекцию Properties с помощью метода CreateProperty.

Sub cmdAddProp_Click()
    Dim intX As Integer
    Const DB_Text As Long = 10
    intX = AddAppProperty("AppTitle", DB_Text, "My Custom Application")
    intX = AddAppProperty("AppIcon", DB_Text, "C:\Windows\Cars.bmp")
    CurrentDb.Properties("UseAppIconForFrmRpt") = 1
    Application.RefreshTitleBar
End Sub

Function AddAppProperty(strName As String, _
        varType As Variant, varValue As Variant) As Integer
    Dim dbs As Object, prp As Variant
    Const conPropNotFoundError = 3270

    Set dbs = CurrentDb
    On Error GoTo AddProp_Err
    dbs.Properties(strName) = varValue
    AddAppProperty = True

AddProp_Bye:
    Exit Function

AddProp_Err:
    If Err = conPropNotFoundError Then
        Set prp = dbs.CreateProperty(strName, varType, varValue)
        dbs.Properties.Append prp
        Resume
    Else
        AddAppProperty = False
        Resume AddProp_Bye
    End If
End Function