Свойства MS Access

Question

Где можно найти собственный список свойств MS Access, доступный через:

 CurrentDb.Properties("Property_Name_Here")

Например, Я знаю;

• AppTitle доступен для доступа к названию приложения
• AppIcon доступен для доступа к пути значка, используемого для приложения

Для разных версий я уверен, что есть разные свойства. Есть ли списки по версии? Так, например, MS Access 2003 имеет эти свойства ... в то время как MS Access 2007 имеет эти свойства ... и т. Д.

Answer 1

Я не верю, что где-нибудь есть список. То есть свойство Properties является коллекцией. Вы можете перебирать их и связывать все. Вы должны будете сделать это во всех версиях MS Access, которые вас интересуют. Для дальнейшего изложения, почти все внутренние объекты, например, таблицы, поля, запросы и т. д. имеют свойства. Свойства поля особенно полезны, так как вы можете назначить, как MS Access связывает и отображает поле для пользователя.

Answer 2

Есть коллекция объектов:

Sub ListProps()
    For i = 0 To CurrentDb.Properties.Count - 1
        Debug.Print CurrentDb.Properties(i).Name
    Next
End Sub

Answer 3

Трудно найти такую ​​информацию.

Я нашел ссылку здесь для свойств доступа DAO

Answer 4

Это было бы хорошо? :)

Option Compare Database
Option Explicit

Private Sub btnShowDbProps_Click()
On Error GoTo Err_btnShowDbProps_Click

  Dim prp As DAO.Property
  Dim dbs As Database
  Dim strProps As String

  Set dbs = CurrentDb

  For Each prp In dbs.Properties
    Dim propval As String
    propval = "<not defined>"

    On Error Resume Next
    propval = CStr(prp.value)

    If propval = vbNullString Then propval = "<empty>"

    strProps = strProps & prp.Name & "=" & propval & " (" & PropertyType(prp.Type) & ")" & vbNewLine
    Debug.Print strProps
  Next

  MsgBox strProps

Exit_btnShowDbProps_Click:
    Exit Sub

Err_btnShowDbProps_Click:
    MsgBox Err.Description
    Resume Exit_btnShowDbProps_Click

End Sub

Function PropertyType(intType As Integer) As String

   Select Case intType
      Case dbBoolean
         PropertyType = "dbBoolean"
      Case dbByte
         PropertyType = "dbByte"
      Case dbInteger
         PropertyType = "dbInteger"
      Case dbLong
         PropertyType = "dbLong"
      Case dbCurrency
         PropertyType = "dbCurrency"
      Case dbSingle
         PropertyType = "dbSingle"
      Case dbDouble
         PropertyType = "dbDouble"
      Case dbDate
         PropertyType = "dbDate"
      Case dbText
         PropertyType = "dbText"
      Case dbLongBinary
         PropertyType = "dbLongBinary"
      Case dbMemo
         PropertyType = "dbMemo"
      Case dbGUID
         PropertyType = "dbGUID"
      Case Else
         PropertyType = "Unknown:" & intType
   End Select

End Function