Несколько каталогов приложений с Dancer Perl - PullRequest
Новая
       7

Несколько каталогов приложений с Dancer Perl

5 голосов
/ 07 сентября 2011

Есть ли способ иметь одно приложение в Dancer, но с несколькими приложениями.

Или я мог бы сделать что-то вроде этого:

Мой проект в директории 'foo'. И скажем, у меня есть каталог 'bar' (не внутри 'foo'), в котором есть каталог с именем public. Какое мое приложение 'foo' использует эту общедоступную как свою публичную, и если оно ищет, скажем, '/css/style.css', а его нет в / bar / public / ', оно должно искать' / foo / общественности /». Как я могу это сделать?

Ответы [ 3 ]

7 голосов
/ 14 октября 2011

ОК, вот хороший способ сделать это.Конечно, это может быть плагин.

Вы никогда не должны делать подобные вещи, взламывая ядро ​​Dancer, вам лучше всегда подумать о реализации обработчика маршрута для выполнения этой работы: 

#!/usr/bin/env perl
use Dancer;
use File::Spec;
use Dancer::FileUtils 'read_file_content';
use Dancer::MIME;
use HTTP::Date;

# your routes here

# then the catchall route for 
# serving static files

# better in config
my @public_dirs = qw(/tmp/test/foo /tmp/test/bar /tmp/test/baz);

get '/**' => sub {
    my $path = request->path;
    my $mime = Dancer::MIME->instance;

    # security checks
    return send_error("unauthrorized request", 403) if $path =~ /\0/;
    return send_error("unauthrorized request", 403) if $path =~ /\.\./;

    # decompose the path_info into a file path
    my @path = split '/', $path;

    for my $location (@public_dirs) {
        my $file_path = File::Spec->catfile($location, @path);

        next if ! -f $file_path;

        my $content = read_file_content($file_path);
        my $content_type = $mime->for_file($file_path);
        my @stat = stat $file_path;

        header 'Content-Type', $content_type;
        header 'Content-Length', $stat[7];
        header 'Last-Modified', HTTP::Date::time2str($stat[9]);
        return $content;
    }

    pass;
};

start;

Пример запуска этого приложения: 

$ mkdir -p /tmp/test/foo /tmp/test/bar /tmp/test/baz
$ echo 1 > /tmp/test/foo/foo.txt
$ echo 2 > /tmp/test/bar/bar.txt
$ echo 3 > /tmp/test/baz/baz.txt
$ ./bin/app.pl
$ curl -I http://0:3000/baz.txt
HTTP/1.0 200 OK
Content-Length: 2
Content-Type: text/plain
Last-Modified: Fri, 14 Oct 2011 11:28:03 GMT
X-Powered-By: Perl Dancer 1.3051
2 голосов
/ 07 сентября 2011

Один из способов, если написать плагин, который отображает статический (и заменяет некоторые функции).Вы можете использовать Dancer :: Plugin :: Thumbnail в качестве примера.

Другой способ, который я вижу, - это обезьяна-патч get_file_response() в Dancer :: Renderer , котораяне очень хорошая идея.

Следующий код ищет статические файлы в каждом каталоге из массива @dirs.Это грязно, некрасиво и небезопасно.Это может быть сломано в будущей версии и может вызвать проблемы с другими частями среды Dancer, с которыми я не знаком.Вы предупреждены. 

#!/usr/bin/env perl
use Dancer;
use Dancer::Renderer;
use MyWeb::App;

my $get_file_response_original = \&Dancer::Renderer::get_file_response;
my @dirs = ('foo');

*Dancer::Renderer::get_file_response = sub {
    my $app = Dancer::App->current;

    my $result;

    # Try to find static in default dir
    if ($result = $get_file_response_original->(@_)) {
        return $result;
    }

    # Save current settings
    my $path_backup = $app->setting('public');

    # Go through additional dirs
    foreach my $dir (@dirs) {
        $app->setting(public => $dir);
        if ($result = $get_file_response_original->(@_)) {
            last;
        }
    }

    # Restore public
    $app->setting('public' => $path_backup);

    return $result
};

dance;

Третий способ - позволить nginx просто выполнить эту работу за вас, написав надлежащий конфиг nginx для вашего приложения.

0 голосов
/ 17 октября 2011

Может быть этот модуль тебе поможет? https://github.com/Perlover/Dancer-Plugin-Hosts Вы можете настроить виртуальные сайты в Dancer с собственным appdir и другими настройками каталога Я загрузил этот модуль сегодня на github Скоро будет в CPAN

...