Реализация двойного экспоненциального сглаживания, также известного как двойное экспоненциальное скользящее среднее (DEMA) - PullRequest
Новая
       8

Реализация двойного экспоненциального сглаживания, также известного как двойное экспоненциальное скользящее среднее (DEMA)

6 голосов
/ 04 апреля 2011

Если у меня есть данные временных рядов - список пар {x, y} - и я хочу сгладить их, я могу использовать экспоненциальную скользящую среднюю, например, так: 

EMA[data_, alpha_:.1] := 
  Transpose @ {#1, ExponentialMovingAverage[#2, alpha]}& @@ Transpose@data

Как бы вы реализовали двойное экспоненциальное сглаживание ? 

DEMA[data_, alpha_, gamma_] := (* unstub me! *)

Если бы он вычислял хорошие значения для альфы и гаммы сам по себе, это было бы очень приятно.

Смежный вопрос о том, как обрабатывать случай, когда во временном ряду имеются пропуски, т. Е. Выборки не распределены равномерно по времени:

Экспоненциальная скользящая средняя, ​​отобранная в различные времена

Ответы [ 2 ]

3 голосов
/ 04 апреля 2011

Я не уверен, что это самый быстрый код, который можно получить, но, похоже, это делает следующее: 

DEMA[data_, alpha_, gamma_] := 
 Module[{st = First[data], bt = data[[2]] - data[[1]], btnew, stnew},
  Reap[
    Sow[st];
    Do[
     stnew = alpha y + (1 - alpha) (st + bt);
     btnew = gamma (stnew - st) + (1 - gamma) bt;
     Sow[stnew];
     st = stnew;
     bt = btnew;
     , {y, Rest@data}]][[-1, 1]
   ]]

Это почти прямо со страницы, на которую вы ссылались.Вы можете изменить начальное условие для b в исходном коде.Первоначально установив bt в ноль, вы получите однократное экспоненциальное сглаживание. 

In[81]:= DEMA[{a, b, c, d}, alpha, gamma]

Out[81]= {a, (1 - alpha) b + alpha b, 
 alpha c + (1 - alpha) ((1 - alpha) b + 
     alpha b + (-a + b) (1 - gamma) + (-a + (1 - alpha) b + 
        alpha b) gamma), 
 alpha d + (1 - 
     alpha) (alpha c + (1 - 
        gamma) ((-a + b) (1 - gamma) + (-a + (1 - alpha) b + 
           alpha b) gamma) + (1 - alpha) ((1 - alpha) b + 
        alpha b + (-a + b) (1 - gamma) + (-a + (1 - alpha) b + 
           alpha b) gamma) + 
     gamma (-(1 - alpha) b - alpha b + 
        alpha c + (1 - alpha) ((1 - alpha) b + 
           alpha b + (-a + b) (1 - gamma) + (-a + (1 - alpha) b + 
              alpha b) gamma)))}
1 голос
/ 04 апреля 2011

Вот моя формулировка: 

DEMA[data_, alpha_, gamma_] :=
 FoldList[
   Module[{x, y},
     x = #[[1]] + #[[2]];
     y = #2 - alpha x;
     {y + x, #[[2]] + gamma * y}
     ] &,
   {data[[1]], data[[2]] - data[[1]]},
   alpha * Rest@data
 ][[All, 1]]
...