Для начала давайте переопределим ваши предикаты, чтобы они не делали ненужных операций ввода-вывода:
takeout(X,[X|R],R).
takeout(X,[F |R],[F|S]) :- takeout(X,R,S).
perm([X|Y],Z) :- perm(Y,W), takeout(X,Z,W).
perm([],[]).
Теперь у вас есть то, что можно считать «чистой» функцией перестановки:
?- perm([1,2,3], X).
X = [1, 2, 3] ;
X = [2, 1, 3] ;
X = [2, 3, 1] ;
X = [1, 3, 2] ;
X = [3, 1, 2] ;
X = [3, 2, 1] ;
false.
Итак, предположим, что у вас есть функция max_heap, которая принимает список значений и создает дерево. Я позволю вам позаботиться об этом, поэтому давайте просто постулируем, что он существует и называется max_heap/2, и давайте далее постулируем, что у вас есть способ отобразить это привлекательно называемое display_heap/1. Чтобы «взять» перестановку и «отправить» ее в качестве параметра этим функциям, вы действительно говорите в математике: предположим, что P - это перестановка X, давайте создадим с ним max_heap и отобразим его. Или предположим, что P - это перестановка X, H - максимальная куча из X, давайте покажем H:
show_heaps(List) :- perm(List, P), max_heap(P, H), display_heap(H).
Это говорит о том же, что и мое английское предложение: предположим, что P - перестановка списка, затем H - его представление в виде кучи, затем отобразим его. Технически, display_heap/1 все еще является предикатом, который может быть истинным или ложным для данной кучи. На практике это всегда будет верно, и если вы запустите это, вам все равно придется многократно нажимать ;, чтобы сказать: «Дайте мне другое решение, если только вы не используете цикл, управляемый ошибками, или внелогичный предикат, такой как findall/3» вызвать все решения, которые будут найдены.
Редактировать : Давайте обсудим циклы с ошибками и findall/3. Сначала позвольте мне добавить несколько новых предикатов, потому что я точно не знаю, что вы делаете, но это не имеет значения для наших целей.
double([X|Xs], [Y|Ys]) :- Y is X*2, double(Xs, Ys).
double([],[]).
showlist(Xs) :- print(Xs).
Итак, теперь у меня есть предикат double/2, который удваивает значения в списке, и предикат showlist/1, который выводит список на стандартный вывод. Мы можем попробовать это так:
?- perm([1,2,3], X), double(X, Y), showlist(Y).
[2,4,6]
X = [1, 2, 3],
Y = [2, 4, 6] ;
[4,2,6]
X = [2, 1, 3],
Y = [4, 2, 6] ;
[4,6,2]
X = [2, 3, 1],
Y = [4, 6, 2] ;
[2,6,4]
X = [1, 3, 2],
Y = [2, 6, 4] ;
[6,2,4]
X = [3, 1, 2],
Y = [6, 2, 4] ;
[6,4,2]
X = [3, 2, 1],
Y = [6, 4, 2] ;
false.
Когда вы набираете ;, вы говорите "или?" Пролог. Другими словами, вы говорите "что еще?" Вы говорите Прологу, по сути, это не тот ответ, который я хочу, попробуйте найти другой ответ, который мне нравится больше Вы можете формализовать этот процесс с помощью цикла, управляемого ошибками:
?- perm([1,2,3], X), double(X, Y), showlist(Y), fail.
[2,4,6][4,2,6][4,6,2][2,6,4][6,2,4][6,4,2]
false.
Итак, теперь вы видите, что выходные данные каждой перестановки прошли там double/2, а затем Пролог сообщил о ложном. Вот что под этим подразумевается:
show_all_heaps(List) :- perm(List, X), double(X, Y), showlist(Y), nl, fail.
show_all_heaps(_).
Посмотрите, как это работает:
?- show_all_heaps([1,2,3]).
[2,4,6]
[4,2,6]
[4,6,2]
[2,6,4]
[6,2,4]
[6,4,2]
true.
Другой вариант использует findall/3, который выглядит примерно так:
?- findall(Y, (perm([1,2,3], X), double(X, Y)), Ys).
Ys = [[2, 4, 6], [4, 2, 6], [4, 6, 2], [2, 6, 4], [6, 2, 4], [6, 4, 2]].
Использование этого для решения вашей проблемы, вероятно, выходит за рамки домашней работы, над которой вы работаете.