AS3 Настройка ширины и высоты контейнера спрайта - PullRequest
Новая
       2

AS3 Настройка ширины и высоты контейнера спрайта

9 голосов
/ 27 февраля 2011

Хорошо, мой разум ошеломлен этой проблемой.Я знаю, что это может показаться таким легким вопросом, и я не могу понять, почему я не могу понять это, но тем не менее я не могу, и я почти сдался.Вот проблема:

У меня есть контейнер спрайтов, который должен содержать кучу миниатюр для видео.Я могу заполнить контейнер всеми видео и всеми работами, но, очевидно, если я добавлю кучу видео, он будет превышать размер флеш-документа, поэтому мне нужно добавить UIScrollBar (что я и сделал), теперь цель полосы прокруткиустановлен на контейнер, но не позволяет мне прокручивать, и если я прав, это потому, что контейнер не имеет установленной высоты.Поэтому я пытаюсь установить высоту этого контейнера, но во-вторых, я пытаюсь установить высоту или даже ширину, все мои эскизы, которые я имел обыкновение видеть, исчезли!Это как если бы размер был установлен в 0, когда его нет, я даже пытался установить его в указанном размере просто для проверки и ничего.В любом случае, вот мой код, если кто-то может помочь, я действительно ценю это!Заранее спасибо! 


import fl.controls.UIScrollBar; 

var videoList:XMLList;
var numVideos:Number;
var current_Video:Number = 0;
var video_position:Number;
var video_paused:Boolean;
var xmlPlaylist:String;

//XML File setup
var playlist_xml:XML;
var myLoader:URLLoader = new URLLoader();

//Playlist setup
var thumb_width:Number;
var thumb_height:Number;
var thumbs_x:Number;
var thumbs_y:Number;
var main_container:Sprite;
var thumbs:Sprite;
var scrollbar:UIScrollBar;

//Loader Data
this.loaderInfo.addEventListener(Event.COMPLETE, loaderComplete);
function loaderComplete(e:Event):void
{
    var myQueryStrings = this.loaderInfo.parameters;
    xmlPlaylist = myQueryStrings.pList;

    myLoader.load(new URLRequest(xmlPlaylist + "?uniq=" + new Date().getTime()));
}

myLoader.addEventListener(Event.COMPLETE, processXML);
function processXML(e:Event):void {
    playlist_xml = new XML(e.target.data);

    numVideos = playlist_xml.video.length();
    videoList = playlist_xml.video;

    thumb_width = playlist_xml.@thumb_width;
    thumb_height = playlist_xml.@thumb_height;
    thumbs_x = playlist_xml.@thumbs_x;
    thumbs_y = playlist_xml.@thumbs_y;

    current_Video = Math.round(Math.random()*(numVideos-1))+1;
    current_Video--;

    startPlayer();
}

function startPlayer()
{
    makeContainers();
    callThumbs();
    setVideo(current_Video);
}

function makeContainers():void
{
    main_container = new Sprite();
    addChild(main_container);

    thumbs = new Sprite();
    thumbs.addEventListener(MouseEvent.CLICK, playVideo);
    thumbs.addEventListener(MouseEvent.MOUSE_OVER, onOver);
    thumbs.addEventListener(MouseEvent.MOUSE_OUT, onOut);
    thumbs.x = thumbs_x;
    thumbs.y = thumbs_y;

Вот в чем проблема: (Если я закомментирую этот код, он отображает эскизы) 


    thumbs.width = thumb_width;
    thumbs.height = (thumb_height + 11) * 3;


    thumbs.buttonMode = true;
    main_container.addChild(thumbs);

    scrollbar = new UIScrollBar();
    scrollbar.x = thumbs_x + thumb_width + 2;
    scrollbar.y = thumbs_y;
    scrollbar.setSize(25, (thumb_height + 11) * 3);
    scrollbar.visible = true;
    scrollbar.scrollTarget = thumbs;
    main_container.addChild(scrollbar);
}

function callThumbs():void
{
    for (var i:Number = 0; i (less than) numVideos; i++) //For some reason Stack Overflow isnt allowing me to put the symbol less than so i just typed it in...
    {
        var thumb_url = videoList[i].@thumb;
        var thumb_loader = new Loader();
        thumb_loader.name = i;
        thumb_loader.load(new URLRequest(thumb_url));

        thumb_loader.contentLoaderInfo.addEventListener(Event.COMPLETE, thumbLoaded);

        thumb_loader.y = (thumb_height + 11) * i;
    }
}

function thumbLoaded(e:Event):void
{
    var my_thumb:Loader = Loader(e.target.loader);
    thumbs.addChild(my_thumb);
}

function playVideo(e:MouseEvent):void
{
    setVideo(e.target.name);
}

function onOver (e:MouseEvent):void
{
    var my_thumb:Loader = Loader(e.target);
    my_thumb.alpha = 0.5;
}

function onOut (e:MouseEvent):void
{
    var my_thumb:Loader = Loader (e.target);
    my_thumb.alpha = 1;
}

function setVideo(current_Video)
{
    var display:String = videoList[current_Video].@title;
    var video:String = videoList[current_Video].@url;

    txt_Display.text = display;
    flvPlayer.source = video;
}

stop();

1 Ответ

11 голосов
/ 27 февраля 2011

Это легко.Вы создаете Sprite, добавляете слушателей, устанавливаете координаты.Спрайт все еще пуст.Затем вы устанавливаете ширину и высоту, которые переводятся в scaleX и scaleY.На пустом спрайте это портит матрицу преобразования, и спрайт никогда не будет отображаться.Устанавливайте ширину, высоту или scaleX / Y только для непустых спрайтов.

...