Записать символ в видеобуфер MASM - PullRequest
Новая
       43

Записать символ в видеобуфер MASM

1 голос
/ 01 декабря 2011

Я пытаюсь написать букву «D» синим цветом на белом фоне, перемещая ее в видеобуфер. Что не так с этим кодом? 

INCLUDE Irvine16.inc

.code
main PROC

mov ax,@data
mov ds,ax

mov si, 0b800h
mov word ptr [si], 44h
mov word ptr [si+2] 0701h

mov ah, 08h
int 21h

exit

main ENDP

Внесены изменения, указанные выше. Теперь он собирается, но ничего не отображается.

Ответы [ 3 ]

2 голосов
/ 22 декабря 2015

1) 0b800h является адресом сегмента видеобуфера.mov word ptr [si], 44h адресует только смещение (здесь: 0b800h) адреса сегмента в DS - и DS не указывает на видеобуфер.Я предлагаю загрузить сегмент видео в ES и использовать переопределение сегмента (ES:).

2) Буква плюс цвет образуют слово.В буфере видео сначала идет буква, затем цвет.Цвет фона и переднего плана использует каждый кусочек (4 бита).Из-за "немного порядкового номера" (Google для него) слово должно иметь формат цвет / буква, например, белый / синий / 'D' = 7144h

Это пример, совместимый с Irvine16: 

INCLUDE Irvine16.inc
INCLUDELIB Irvine16.lib

.CODE
main PROC
;   mov ax,@data                ; No .DATA in this example
;   mov ds,ax

    mov si, 0b800h              ; Initialize ES with video buffer
    mov es, si

    xor si, si                  ; Position 0 is top left
    mov word ptr es:[si], 7144h ; White background ('7'), blue foreground (1), letter 'D' (44)

    mov ah, 08h                 ; Wait for key - http://www.ctyme.com/intr/rb-2561.htm
    int 21h

    exit                        ; Irvine16: end of program
main ENDP

END main
2 голосов
/ 01 декабря 2011

Пример примера: 

name "hello-world"
org 100h

; set video mode     
mov ax, 3     ; text mode 80x25, 16 colors, 8 pages (ah=0, al=3) 
int 10h       ; do it! 

; cancel blinking and enable all 16 colors: 
mov ax, 1003h
mov bx, 0
int 10h


; set segment register: 
mov     ax, 0b800h
mov     ds, ax

; print "hello world" 
; first byte is ascii code, second byte is color code. 

mov [02h], 'h'

mov [04h], 'e'

mov [06h], 'l'

mov [08h], 'l'

mov [0ah], 'o'

mov [0ch], ','

mov [0eh], 'w'

mov [10h], 'o'

mov [12h], 'r'

mov [14h], 'l'

mov [16h], 'd'

mov [18h], '!'




; color all characters: 
mov cx, 12  ; number of characters. 
mov di, 03h ; start from byte after 'h' 

c:  mov [di], 11101100b   ; light red(1100) on yellow(1110) 
    add di, 2 ; skip over next ascii code in vga memory. 
    loop c

; wait for any key press: 
mov ah, 0
int 16h

ret

Надеюсь, этот образец поможет вам

0 голосов
/ 01 декабря 2011

Взгляните на листинг 15 здесь:

http://stuff.pypt.lt/ggt80x86a/asm8.htm

...