«Выполнение функции document () было запрещено».где EnableDocumentFunction установлен в true? - PullRequest
Новая
       0

«Выполнение функции document () было запрещено».где EnableDocumentFunction установлен в true?

3 голосов
/ 23 ноября 2011

Я получаю прерывистое исключение System.Xml.Xsl.XslTransformException в нашей производственной среде при попытке преобразования xslt, к сожалению, я не могу повторить это в среде разработки.

Исключение выкладывается дополнительная информация:

Выполнение функции document () было запрещено. Использовать Свойство XsltSettings.EnableDocumentFunction, чтобы включить его. Ошибка произошло в C: \ path \ to \ file \ CDS.xsl (16,3).

Однако свойство EnableDocumentFunction имеет значение true в коде обработки: 

private void Transform()
{
    var keepTrying = true;
    var tryCount = 0;
    const int maxRetrys = 3;

    while (keepTrying)
    {
        try
        {
            var xmlResolver = new XmlUrlResolver();

            using (var xmlFile = new XmlNodeReader(_xDoc))
            {
                var settings = new XmlReaderSettings
                                   {
                                       XmlResolver = xmlResolver,
                                       ProhibitDtd = false,
                                       DtdProcessing = DtdProcessing.Ignore
                                   };

                using (var xsl = XmlReader.Create(_xslPath, settings))
                {
                    var xslt = new XslCompiledTransform(true);
                    xslt.Load(xsl, new XsltSettings { EnableDocumentFunction = true }, xmlResolver);

                    var sb = new StringBuilder();
                    using (var writer = XmlWriter.Create(sb, xslt.OutputSettings))
                    {
                        xslt.Transform(xmlFile, null, writer, xmlResolver); // errors out here.
                    }

                    var xhtml = sb.ToString();
                    _transformedXml = xhtml;
                    _isTransformed = true;

                    xsl.Close();
                }
            }

            keepTrying = false;
        }
        catch (System.Xml.Xsl.XsltException ex)
        {
            ExceptionPolicy.HandleException(ex, "ExceptionLogging");

            tryCount++;
            if (tryCount > maxRetrys)
            {
                keepTrying = false;
                throw;
            }
        }
    }
}

Файл xslt предоставляется третьей стороной и автоматически обновляется, поэтому перезапись его не возможна. Вот вершина, слегка измененная по соображениям конфиденциальности: 

<?xml version="1.0"?>

<!--
     Interaction_550.xsl : 20110916
-->
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:example="http://www.example.com" version="1.0">
  <xsl:param name="D2DSeverityFilter"></xsl:param>
  <xsl:param name="D2HSeverityFilter"></xsl:param>
  <xsl:param name="DocumentationFilter"></xsl:param>
  <xsl:output method="html"/>
  <xsl:key name="d2d_sev_level-lookup" match="example:d2d_sev_level" use="@name"/>
  <xsl:key name="d2h_sev_level-lookup" match="example:d2h_sev_level" use="@name"/>
      <xsl:key name="d2l_sev_level-lookup" match="example:d2l_sev_level" use="@name"/>
      <xsl:key name="preg_cat-lookup" match="example:preg_cat" use="@cat"/>
  <xsl:key name="doc_level-lookup" match="example:doc_level" use="@name"/>
  <xsl:variable name="d2d_sev_level-top" select="document('')/*/example:d2d_sev_levels"/>
  <xsl:variable name="d2h_sev_level-top" select="document('')/*/example:d2h_sev_levels"/>
      <xsl:variable name="d2l_sev_level-top" select="document('')/*/example:d2l_sev_levels"/>

  <xsl:variable name="doc_level-top" select="document('')/*/example:doc_levels"/>
      <xsl:variable name="preg_cat-top" select="document('')/*/example:preg_cats"/>
  <xsl:template match="/">
    <head>
      <style type="text/css">
body {
font-family : arial,sans serif,helvetica;
}
...

Как я могу:

  • исправить это, чтобы оно вообще не происходило?
  • если это не удастся, как я смогу воспроизвести это в dev?

Ответы [ 2 ]

6 голосов
/ 12 декабря 2012

В качестве альтернативы с классом MS XslCompiledTransform вы можете использовать класс XsltSettings, чтобы избежать этой ошибки, как это описано самой ошибкой. от MSDN

2 голосов
/ 23 ноября 2011

Вот общий способ избавиться от выражений document('')/*/someName :

Исходное преобразование обрабатывается специальным преобразованием, которое генерирует эквивалентное преобразование, которое не содержит вызова функции document('').

Тогда вам просто нужно использовать сгенерированное преобразование.

Пример :

Это преобразование (назовем его tA), содержащее document(''): 

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:my="my:my" >
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <my:paramDoc1>
  <x>123</x>
  <y>37</y>
 </my:paramDoc1>

 <my:paramDoc2>
  <x>456</x>
  <y>79</y>
 </my:paramDoc2>

 <xsl:variable name="vpDoc1" select="document('')/*/my:paramDoc1"/>
 <xsl:variable name="vpDoc2" select="document('')/*/my:paramDoc2"/>

 <xsl:template match="/*">
     <xsl:value-of select="$vpDoc1/x"/>
     <xsl:text>|</xsl:text>
     <xsl:value-of select="$vpDoc2/y"/>
 </xsl:template>
</xsl:stylesheet>

при применении к любому документу создает : 

123|79

Теперь мы обрабатываем приведенное выше преобразование с этим (tGen) : 

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:x="a:a" exclude-result-prefixes="x">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:namespace-alias stylesheet-prefix="x"
      result-prefix="xsl"/>

 <xsl:variable name="vApos">'</xsl:variable>

 <xsl:variable name="vSelectPrefix" select=
  "concat('document(', $vApos,$vApos, ')/*/')"/>

 <xsl:template match="node()|@*" name="identity">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="xsl:stylesheet">
  <x:stylesheet xmlns:ext="http://exslt.org/common">
    <xsl:copy-of select="@*"/>
    <xsl:apply-templates/>
  </x:stylesheet>
 </xsl:template>

 <xsl:template match="xsl:variable">
  <xsl:variable name="vSelattr" select="@select"/>
  <xsl:choose>
      <xsl:when test="not(starts-with(@select, $vSelectPrefix))">
        <xsl:call-template name="identity"/>
      </xsl:when>
      <xsl:otherwise>
      <x:variable name="vrtf{@name}">
        <xsl:copy-of select=
        "/*/*[name()
             = substring-after($vSelattr, $vSelectPrefix)
             ]"/>
      </x:variable>

      <x:variable name="{@name}" select=
           "ext:node-set($vrtf{@name})/*"/>
      </xsl:otherwise>
  </xsl:choose>
 </xsl:template>

</xsl:stylesheet>

Результатом является новое преобразование (tRes), которое не содержит выражений типа document(''): 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
     xmlns:ext="http://exslt.org/common">
    <xsl:output omit-xml-declaration="yes" 
         indent="yes" xmlns:my="my:my" />
    <xsl:strip-space elements="*" xmlns:my="my:my" />
    <my:paramDoc1 xmlns:my="my:my">
        <x>123</x>
        <y>37</y>
    </my:paramDoc1>
    <my:paramDoc2 xmlns:my="my:my">
        <x>456</x>
        <y>79</y>
    </my:paramDoc2>
    <xsl:variable name="vrtfvpDoc1">
        <my:paramDoc1 xmlns:my="my:my">
            <x>123</x>
            <y>37</y>
        </my:paramDoc1>
    </xsl:variable>
    <xsl:variable name="vpDoc1" select="ext:node-set($vrtfvpDoc1)/*" />
    <xsl:variable name="vrtfvpDoc2">
        <my:paramDoc2 xmlns:my="my:my">
            <x>456</x>
            <y>79</y>
        </my:paramDoc2>
    </xsl:variable>
    <xsl:variable name="vpDoc2" select="ext:node-set($vrtfvpDoc2)/*" />
    <xsl:template match="/*" xmlns:my="my:my">
        <xsl:value-of select="$vpDoc1/x" />
        <xsl:text>|</xsl:text>
        <xsl:value-of select="$vpDoc2/y" />
    </xsl:template>
</xsl:stylesheet>

Если мы теперь применим это динамически сгенерированное преобразование (tRes) к любому документу XML, результат будет точно таким же , что и при применении исходного преобразования (tA) к этому документу: 

123|79

Следовательно, мы можем использовать tGen для преобразования преобразования, содержащего выражения document(''), в эквивалентное преобразование, которое не содержит таких выражений .

Добро пожаловать на сайт PullRequest, где вы можете задавать вопросы и получать ответы от других членов сообщества.

Нет похожих вопросов

...