XSLT: Как я могу получить имена всех узлов?

Question

Я ищу таблицу стилей, которая печатает имя каждого узла, включая его значение.Получить значение легко, но я не знаю, как получить имя каждого узла.Вот основной шаблон:

<?xml version="1.0" encoding="UTF-8"?>
  <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="text" encoding="UTF-8" />   
    <xsl:template match="/">
      <xsl:for-each select="/">
         ???
      </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

Может кто-нибудь дать мне подсказку?

Спасибо, Роберт

Answer 1

Это полное преобразование :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>
 <xsl:variable name="vQ">"</xsl:variable>

 <xsl:template match="*">
     <xsl:value-of select=
       "concat(name(), ' = ', $vQ, ., $vQ, '&#xA;')"/>
    <xsl:apply-templates select="*"/>
 </xsl:template>
</xsl:stylesheet>

при применении к любому документу XML, например, :

<nums>
  <num>01</num>
  <num>02</num>
  <num>03</num>
  <num>04</num>
  <num>05</num>
  <num>06</num>
  <num>07</num>
  <num>08</num>
  <num>09</num>
  <num>10</num>
</nums>

дает в точности нужный, правильный результат:

nums = "01020304050607080910"
num = "01"
num = "02"
num = "03"
num = "04"
num = "05"
num = "06"
num = "07"
num = "08"
num = "09"
num = "10"

Answer 2

Я не знаю, чего вы действительно хотите, но если я восприму ваше требование буквально, оно будет удовлетворено:

<xsl:for-each select="//node()">
  <node name="{name()}" value="{string(.)}"/>
</xsl:for-each>

Answer 3

Попробуйте:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="text" encoding="UTF-8"/>
    <xsl:template match="/">
        <xsl:for-each select="//*">
            <xsl:value-of select="local-name()"/>=<xsl:apply-templates select="current()/text()"/>
            <xsl:text>&#xa;</xsl:text>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

Answer 4

Имя (), "Возвращает имя текущего узла или первого узла в указанном наборе узлов"

    <xsl:value-of select="name()"/> 

Также,

local-name () - "Возвращает имя текущего узла или первого узла в указанном наборе узлов - без префикса пространства имен"

И я думаю, что ты этого хочешь,

 <xsl:value-of select="local-name()"/>