Список с кнопкой удаления / удаления - PullRequest
Новая
       34

Список с кнопкой удаления / удаления

4 голосов
/ 04 августа 2011

Я разрабатываю приложение WinForms и мне нужен ListBox (или элемент управления, который предоставляет список строк), чтобы при наведении курсора мыши на элемент отображался знак удаления для этого конкретного элемента.1002 * Есть ли какой-нибудь элемент управления, доступный для WinForms, чтобы сделать это?

1 Ответ

0 голосов
/ 04 августа 2011

Установив для ListBox DrawMode значение OwnerDrawFixed (или OwnerDrawVariable), вы можете сами справиться с этим с помощью событий Mouse: 

Public Class Form1

  Private _MouseIndex As Integer = -1

  Private Sub Form1_Load(ByVal sender As Object, ByVal e As EventArgs) Handles MyBase.Load
    ListBox1.Items.Add("String #1")
    ListBox1.Items.Add("String #2")
  End Sub

  Private Sub ListBox1_DrawItem(ByVal sender As Object, ByVal e As DrawItemEventArgs) Handles ListBox1.DrawItem
    e.DrawBackground()

    If e.Index > -1 Then
      Dim brush As Brush = SystemBrushes.WindowText
      If (e.State And DrawItemState.Selected) = DrawItemState.Selected Then
        brush = SystemBrushes.HighlightText
      End If
      e.Graphics.DrawString(ListBox1.Items(e.Index), e.Font, brush, e.Bounds.Left + 20, e.Bounds.Top)

      If e.Index = _MouseIndex Then
        e.Graphics.DrawString("X", e.Font, brush, e.Bounds.Left + 2, e.Bounds.Top)
      End If
    End If

  End Sub

  Private Sub ListBox1_MouseDown(ByVal sender As Object, ByVal e As MouseEventArgs) Handles ListBox1.MouseDown
    If _MouseIndex > -1 AndAlso ListBox1.IndexFromPoint(e.Location) = _MouseIndex AndAlso e.Location.X < 20 Then
      Dim index As Integer = _MouseIndex
      If MessageBox.Show("Do you want to delete this item?", "Confirm", MessageBoxButtons.YesNo, MessageBoxIcon.Question) = DialogResult.Yes Then
        ListBox1.Items.RemoveAt(index)
        ListBox1.Invalidate()
      End If
    End If
  End Sub

  Private Sub ListBox1_MouseLeave(ByVal sender As Object, ByVal e As EventArgs) Handles ListBox1.MouseLeave
    If _MouseIndex <> -1 Then
      _MouseIndex = -1
      ListBox1.Invalidate()
    End If
  End Sub

  Private Sub ListBox1_MouseMove(ByVal sender As Object, ByVal e As MouseEventArgs) Handles ListBox1.MouseMove
    Dim index As Integer = ListBox1.IndexFromPoint(e.Location)

    If index <> _MouseIndex Then
      _MouseIndex = index
      ListBox1.Invalidate()
    End If
  End Sub

End Class

Рефакторинг по необходимости.

...