Как заменить последовательности пробелов одним пробелом, но не обрезать в XSLT? - PullRequest
Новая
       9

Как заменить последовательности пробелов одним пробелом, но не обрезать в XSLT?

5 голосов
/ 18 февраля 2011

Функция normalize-space удаляет начальные и конечные пробелы и заменяет последовательности пробельных символов одним пробелом. Как я могу только заменить последовательности пробельных символов одним пробелом в XSLT 1.0? Например, "..x.y...\n\t..z." (пробелы заменяются точкой для удобства чтения) должно стать ".x.y.z.".

Ответы [ 2 ]

7 голосов
/ 18 февраля 2011

Используйте это выражение XPath 1.0 : 

concat(substring(' ', 1 + not(substring(.,1,1)=' ')), 
       normalize-space(), 
       substring(' ', 1 + not(substring(., string-length(.)) = ' '))
      )

Для проверки необходимо следующее преобразование: 

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="text()">
  <xsl:value-of select=
  "concat(substring(' ', 1 + not(substring(.,1,1)=' ')),
          normalize-space(),
          substring(' ', 1 + not(substring(., string-length(.)) = ' '))
          )
  "/>
 </xsl:template>
</xsl:stylesheet>

при применении к этому документу XML: 

<t>
 <t1>   xxx   yyy   zzz   </t1>
 <t2>xxx   yyy   zzz</t2>
 <t3>  xxx   yyy   zzz</t3>
 <t4>xxx   yyy   zzz  </t4>
</t>

дает желаемый, правильный результат: 

<t>
   <t1> xxx yyy zzz </t1>
   <t2>xxx yyy zzz</t2>
   <t3> xxx yyy zzz</t3>
   <t4>xxx yyy zzz </t4>
</t>
2 голосов
/ 18 февраля 2011

Без метода Беккера вы могли бы использовать какой-либо обескураженный символ в качестве знака: 

translate(normalize-space(concat('&#x7F;',.,'&#x7F;')),'&#x7F;','')

Примечание : три вызова функций ...

Или с любым символом, но с повторением некоторого выражения: 

substring(
   normalize-space(concat('.',.,'.')),
   2,
   string-length(normalize-space(concat('.',.,'.'))) - 2
)

В XSLT вы можете легко объявить переменную: 

<xsl:variable name="vNormalize" select="normalize-space(concat('.',.,'.'))"/>
<xsl:value-of select="susbtring($vNormalize,2,string-length($vNormalize)-2)"/>
...