Странное поведение в комментариях XQuery - PullRequest
Новая
       32

Странное поведение в комментариях XQuery

0 голосов
/ 18 февраля 2011

У меня есть набор преобразований XQuery, которые я выполняю для файлов, хранящихся в базе данных Sedna.Все они имеют примерно следующий формат: 

declare namespace ns0 = "http://www.someuri.com/foo.xsd";
declare namespace ns1 = "http://www.someuri.com/bar.xsd";

(:Declare a few functions like the following:)
declare function local:to-xs-boolean(
    $string as xs:string?
)
as xs:boolean? {
    if (fn:upper-case($string) = 'Y') then
        xs:boolean('true')
    else
        if (fn:upper-case($string) = 'N') then
            xs:boolean('false')
        (:if it isn't Y or N then attempt a normal cast - this will fail if it
        it isn't any of 'true', 'false', 1, or 0 :)
        else
            if ($string != '') then
                xs:boolean($string)
            else
                ()
        (:endif:)
    (:endif:)
};

(:Omitted several other functions:)

(:Start the main program:)

(: { :)
for $formName in /ns0:formName
return
        <ns1:newFormName>
            {
                let $address := $formName/ns0:Address
                return
                    <NewAddress>{
                        (:Omitted code and elements unrelated to this question:)
                    }</NewAddress>
            }
            (:Omitted code and elements unrelated to this question:)
        </ns1:newFormName>

Теперь вот мой вопрос.Вы видите эту строку прямо над 'for', который читает '(: {:)'?Это должен быть комментарий, но по какой-то причине он имеет решающее значение для правильной работы моего запроса.Если я удаляю его полностью (или удаляю '{' из комментария), я получаю 

SEDNA Message: ERROR XPDY0002
It is a dynamic error if evaluation of an expression relies on some part of the dynamic context that has not been assigned a value.

Если я раскомментирую его (поэтому строка просто читает '{'), я получаю 

SEDNA Message: ERROR XPST0003
It is a static error if an expression is not a valid instance of the grammar defined in A.1 EBNF.
Details: at (393:1), syntax error, unexpected {
         at (798:33), syntax error, unexpected end of file, expecting "," or }

Если я удалю комментарий и добавлю соответствующий '}' в конец файла, я получу 

SEDNA Message: ERROR XPST0003
It is a static error if an expression is not a valid instance of the grammar defined in A.1 EBNF.
Details: at (393:1), syntax error, unexpected {

Если я добавлю другой текст к этому комментарию (например, '(: text foo bar baz() бла {:) ') это будет работать до тех пор, пока я оставлю это' {'там.

Кто-нибудь когда-либо видел это раньше или есть идеи, что может быть причиной?Это не очень важный вопрос (я могу просто убедиться, что у меня есть '(: {:)' во всех моих трансформациях), но это действительно вызывает у меня любопытство.Так что спасибо за любую помощь, или даже просто присоединиться ко мне в недоумении.

О, еще одно быстрое замечание - я не знаю, имеет ли это какое-то значение, но я выполняю запрос из Java, используя Sedna Чарльза ФостераAPI (http://www.cfoster.net/sedna/)

Редактировать: Вот другой запрос, который я только что написал, который показывает ту же проблему. Мне кажется, что это воспроизводимо, но если это связано с синтаксической ошибкойэто может быть только я, воспроизводящий синтаксическую ошибку. Я также оставлю старую ошибку, чтобы будущие читатели этого вопроса не запутались. 

declare namespace ns0 = "http://www.someuri.com/InitialSchema.xsd";
declare namespace ns1 = "http://www.someuri.com/FinalSchema.xsd";

declare function local:to-address(
    $recipient as xs:string?,
    $line1 as xs:string?,
    $line2 as xs:string?,
    $line3 as xs:string?,
    $city as xs:string?,
    $provinceOrState as xs:string?,
    $country as xs:string?,
    $postalOrZIP as xs:string?
)
as element() {
    if (fn:upper-case($country) = 'CA' or fn:upper-case($country) = 'US') then
        if (fn:upper-case($country) = 'CA') then
            <CanadianAddress>
                <City>{ $city }</City>
                <Country>{ $country }</Country>
                <PostalCode>{ $postalOrZIP }</PostalCode>
                <Province>{ $provinceOrState }</Province>
                <Recipient>{ fn:normalize-space($recipient) }</Recipient>
                <StreetAddress>{ $line1 }</StreetAddress>
                <StreetAddress>{ $line2 }</StreetAddress>
                <StreetAddress>{ $line3 }</StreetAddress>
                <StreetAddress/>
            </CanadianAddress>
        else
            <USAddress>
                <City>{ $city }</City>
                <Country>{ $country }</Country>
                <ZipCode>{ $postalOrZIP }</ZipCode>
                <State>{ $provinceOrState }</State>
                <Recipient>{ fn:normalize-space($recipient) }</Recipient>
                <StreetAddress>{ $line1 }</StreetAddress>
                <StreetAddress>{ $line2 }</StreetAddress>
                <StreetAddress>{ $line3 }</StreetAddress>
            </USAddress>        
        (:endif:)
    else
        if ($country != '') then        
            <InternationalAddress>
                <City>{ $city }</City>
                <Country>{ $country }</Country>
                <PostalCode>{ $postalOrZIP }</PostalCode>
                <Recipient>{ fn:normalize-space($recipient) }</Recipient>
                <StreetAddress>{ $line1 }</StreetAddress>
                <StreetAddress>{ $line2 }</StreetAddress>
                <StreetAddress>{ $line3 }</StreetAddress>
            </InternationalAddress>
        else
            <CanadianAddress>
                <City>{ $city }</City>
                <Country>{ $country }</Country>
                <PostalCode>{ $postalOrZIP }</PostalCode>
                <Province>{ $provinceOrState }</Province>
                <Recipient>{ fn:normalize-space($recipient) }</Recipient>
                <StreetAddress>{ $line1 }</StreetAddress>
                <StreetAddress>{ $line2 }</StreetAddress>
                <StreetAddress>{ $line3 }</StreetAddress>
                <StreetAddress/>
            </CanadianAddress>
        (:endif:)
    (:endif:)
};


(:{:)
for $addressForm1 in /ns0:AddressForm
let $token := xs:integer(data($addressForm1/ns0:submissionID))
return
        <ns1:NewAddressForm>
            <SubmissionID>{ data($addressForm1/ns0:submissionID) }</SubmissionID>
            {
                let $currentAddress := $addressForm1/ns0:currentAddress
                return
                    <NewAddress>{
                        local:to-address(
                            concat(
                                $addressForm1/ns0:fullName/ns0:firstName,
                                ' ',
                                substring(data($addressForm1/ns0:fullName/ns0:middleName), 1, 1),
                                ' ',
                                $addressForm1/ns0:fullName/ns0:lastName
                            ),
                            data($currentAddress/ns0:line1),
                            data($currentAddress/ns0:line2),
                            data($currentAddress/ns0:line3),
                            data($currentAddress/ns0:city),
                            data($currentAddress/ns0:provinceOrState),
                            data($currentAddress/ns0:country),
                            data($currentAddress/ns0:postalOrZipCode)
                        )
                    }</NewAddress>
            }
        </ns1:NewAddressForm>

А вот некоторые примеры данных для нового запроса 

<?xml version="1.0"?>
<ns0:AddressForm xmlns:ns0="http://www.someuri.com/InitialSchema.xsd">
    <ns0:submissionID>23774</ns0:submissionID>
    <ns0:fullName>
        <ns0:firstName>First</ns0:firstName>
        <ns0:middleName>Middle</ns0:middleName>
        <ns0:lastName>Last</ns0:lastName>
    </ns0:fullName>
    <ns0:currentAddress>
        <ns0:line1>Line 1</ns0:line1>
        <ns0:line2>Line 2</ns0:line2>
        <ns0:line3>Line 3</ns0:line3>
        <ns0:city>City</ns0:city>
        <ns0:provinceOrState>Province</ns0:provinceOrState>
        <ns0:postalOrZipCode>H0H 0H0</ns0:postalOrZipCode>
        <ns0:country>CA</ns0:country>
    </ns0:currentAddress>
</ns0:AddressForm>

Если за этим стоит синтаксическая ошибка, неужели кто-то будет так любезен, чтобы указать мне, в какой строке он находится?

1 Ответ

1 голос
/ 19 февраля 2011

Проблема в следующей строке: 

for $formName in /ns0:formName

В Sedna (помните, Sedna - это база данных, а не процессор XQuery) нет способа определить элемент контекста по умолчанию (см. XQuery 1.0, 2.1.2 Динамический контекст ) до выполнения запроса. Поэтому он не знает, как оценить ./ns0:formName (что эквивалентно простому /ns0:formName) - он просто не знает, что означает . в этом случае.

Вам следует загрузить документ, который вы хотите обработать, в базу данных, а затем получить к нему доступ с помощью функции doc(): 

for $formName in doc('forms')/ns0:formName

Насколько я знаю, вы также можете попробовать XQJ API Чарльза Фостера для Sedna (который должен быть в любом случае лучше, чем XML: DB API), который поддерживает определение элемента контекста.

Кстати, если у вас есть вопросы, касающиеся XML Sedna: DB или XQJ, лучше задать их непосредственно в списке обсуждений sedna. Очень вероятно, что Чарльз ответит вам.

...