Как добавить данные в таблицу существующей книги и не создавать новую книгу

Question

Я пытаюсь выяснить, что мне нужно изменить в следующем коде VBA, чтобы добавить данные в конец данных, которые уже существуют, в книгу с именем " Main " и таблицу с именем " резюме":

Sub MergeAllWorkbooks()
Dim MyPath As String, FilesInPath As String
Dim MyFiles() As String
Dim SourceRcount As Long, FNum As Long
Dim mybook As Workbook, BaseWks As Worksheet
Dim sourceRange As Range, destrange As Range
Dim rnum As Long, CalcMode As Long

' Change this to the path\folder location of your files.
MyPath = "C:\test\"

' Add a slash at the end of the path if needed.
If Right(MyPath, 1) <> "\" Then
    MyPath = MyPath & "\"
End If

' If there are no Excel files in the folder, exit.
FilesInPath = Dir(MyPath & "*.xl*")
If FilesInPath = "" Then
    MsgBox "No files found"
    Exit Sub
End If

' Fill the myFiles array with the list of Excel files
' in the search folder.
FNum = 0
Do While FilesInPath <> ""
    FNum = FNum + 1
    ReDim Preserve MyFiles(1 To FNum)
    MyFiles(FNum) = FilesInPath
    FilesInPath = Dir()
Loop
FNum = FNum - 1

' Set various application properties.
With Application
    CalcMode = .Calculation
    .Calculation = xlCalculationManual
    .ScreenUpdating = False
    .EnableEvents = False
End With

' Add a new workbook with one sheet.
Set BaseWks = Workbooks.Add(xlWBATWorksheet).Worksheets(1)
rnum = 1

' Loop through all files in the myFiles array.
If FNum > 0 Then
    For FNum = LBound(MyFiles) To UBound(MyFiles)
        Set mybook = Nothing
        On Error Resume Next
        Set mybook = Workbooks.Open(MyPath & MyFiles(FNum))
        On Error GoTo 0

        If Not mybook Is Nothing Then
            On Error Resume Next

            ' Change this range to fit your own needs.
          With mybook.Worksheets(1)
                Set sourceRange = .Range("A2:T" & CStr(mybook.Worksheets(1).Range("A2").CurrentRegion.Rows.Count))
            End With

            If Err.Number > 0 Then
                Err.Clear
                Set sourceRange = Nothing
            Else
                ' If source range uses all columns then
                ' skip this file.
                If sourceRange.Columns.Count >= BaseWks.Columns.Count Then
                    Set sourceRange = Nothing
                End If
            End If
            On Error GoTo 0

            If Not sourceRange Is Nothing Then

                SourceRcount = sourceRange.Rows.Count

                If rnum + SourceRcount >= BaseWks.Rows.Count Then
                    MsgBox "There are not enough rows in the target worksheet."
                    BaseWks.Columns.AutoFit
                    mybook.Close savechanges:=False
                    GoTo ExitTheSub
                Else

                    ' Copy the file name in column A.
                    With sourceRange
                        BaseWks.Cells(rnum, "A"). _
                                Resize(.Rows.Count).Value = MyFiles(FNum)
                    End With

                    ' Set the destination range.
                    Set destrange = BaseWks.Range("B" & rnum)

                    ' Copy the values from the source range
                    ' to the destination range.
                    With sourceRange
                        Set destrange = destrange. _
                                        Resize(.Rows.Count, .Columns.Count)
                    End With
                    destrange.Value = sourceRange.Value

                    rnum = rnum + SourceRcount
                End If
            End If
            mybook.Close savechanges:=False
        End If

    Next FNum
    BaseWks.Columns.AutoFit
End If

ExitTheSub:
' Restore the application properties.
With Application
    .ScreenUpdating = True
    .EnableEvents = True
    .Calculation = CalcMode
End With
End Sub

Спасибо

Answer 1

Мне не нравится этот код.Есть много вещей, против которых я возражаю, но я больше всего недоволен использованием обработки ошибок:

• Функциональность обработки ошибок существует для того, чтобы позволить вашей процедуре изящно завершиться неудачей, когда что-то пойдет не так.Он не позволяет вам игнорировать ошибки и продолжать, как если бы они не произошли.

• Обработка ошибок не смогла решить проблему с одной из моих рабочих книг.Я не исследовал, но я подозреваю, что проблема заключается либо в длине отдельной ячейки, либо в общей длине данных, передаваемых destrange.Value = sourceRange.Value.

Однако вы спрашиваете, как сделатьодно изменение, поэтому я ограничусь этим.

Я предлагаю самый простой подход - создать рабочую книгу "Основная" с рабочим листом "Сводка" и включить в нее свой макрос.

Добавитьновые операторы в операторах Dim:

  Dim rnum As Long, CalcMode As Long

  '### Start of new code    
  If Workbooks.Count > 1 Then
    ' It is easy to get into a muddle if there are multiple workbooks
    ' open at the start of a macro like this.  Avoid the problem until
    ' you understand it.
    Call MsgBox("Please close all other workbooks", vbOKOnly)
    Exit Sub
  End If

  Set BaseWks = ActiveWorkBook.Worksheets("Summary")
  With BaseWks
    rnum = .Cells(Rows.Count, "A").End(xlUp).Row + 1
  End With
 '### End of new code  

 ' Change this to the path\folder location of your files.

Первый блок приведенного выше кода гарантирует, что другие рабочие книги не открыты.

Второй блок (1) устанавливает BaseWks вНа листе «Сводка» и (2) rnum устанавливается первая неиспользуемая строка в «Сводке».End(xlUp) является эквивалентом клика VBA Ctrl + Up.Итак, я перешел к нижней части столбца А, поднимался до тех пор, пока не попал в строку со значением, а затем опустился на 1 строку.

Заменить цикл, в котором расположены имена файлов, на:

  Do While FilesInPath <> ""

    If FilesInPath <> ActiveWorkbook.Name Then
      FNum = FNum + 1
      ReDim Preserve MyFiles(1 To FNum)
      MyFiles(FNum) = FilesInPath
    End If
    FilesInPath = Dir()

  Loop

Я предполагаю, что рабочая книга "Основная" будет находиться в той же папке, что и другие рабочие книги.Это изменение гарантирует, что «Main» не будет использоваться в качестве источника.

Откажитесь от этих утверждений:

Set BaseWks = Workbooks.Add(xlWBATWorksheet).Worksheets(1)
rnum = 1

, потому что я уже установил BaseWks и rnum на нужные мне значения,

Если вы хотите автоматически сохранить обновленную рабочую книгу «Основная», добавьте следующую фразу выше ExitTheSub::

ActiveWorkbook.Save