Примечание: Получите готовую палитру с этой функциональностью здесь .
Решение от Arnoud взволновало меня и привело к нетерпению, так что вот улучшениеЭто.Я не мог бы сделать это без изучения его кода.Эта версия кажется несколько более надежной и менее подверженной ошибкам тайм-аута, но, если честно, я вообще не знаю Java, поэтому любые улучшения приветствуются.
Самое главное: эта версия загружается непосредственно в stack.imgur.comтак что здесь безопасно использовать StackOverflow, не беспокоясь о том, что загруженные изображения исчезнут через некоторое время.
Я предоставляю три функции:
stackImage загружает выражение,экспортируется как PNG и возвращает URL stackMarkdown возвращает уценку, готовую к копированию stackCopyMarkdown копирует уценку в буфер обмена
Далеешаг: создайте кнопку палитры, которая делает это автоматически для выбранной графики в блокноте.Улучшения кода очень приветствуются.
Needs["JLink`"]
stackImage::httperr = "Server returned respose code: `1`";
stackImage::err = "Server returner error: `1`";
stackImage[g_] :=
Module[
{getVal, url, client, method, data, partSource, part, entity, code,
response, error, result},
(* this function attempts to parse the response fro the SO server *)
getVal[res_, key_String] :=
With[{k = "var " <> key <> " = "},
StringTrim[
First@StringCases[First@Select[res, StringMatchQ[#, k ~~ ___] &],
k ~~ v___ ~~ ";" :> v],
"'"]
];
data = ExportString[g, "PNG"];
JavaBlock[
url = "https://stackoverflow.com/upload/image";
client = JavaNew["org.apache.commons.httpclient.HttpClient"];
method = JavaNew["org.apache.commons.httpclient.methods.PostMethod", url];
partSource = JavaNew["org.apache.commons.httpclient.methods.multipart.ByteArrayPartSource", "mmagraphics.png", MakeJavaObject[data]@toCharArray[]];
part = JavaNew["org.apache.commons.httpclient.methods.multipart.FilePart", "name", partSource];
part@setContentType["image/png"];
entity = JavaNew["org.apache.commons.httpclient.methods.multipart.MultipartRequestEntity", {part}, method@getParams[]];
method@setRequestEntity[entity];
code = client@executeMethod[method];
response = method@getResponseBodyAsString[];
]
If[code =!= 200, Message[stackImage::httperr, code]; Return[$Failed]];
response = StringTrim /@ StringSplit[response, "\n"];
error = getVal[response, "error"];
result = getVal[response, "result"];
If[StringMatchQ[result, "http*"],
result,
Message[stackImage::err, error]; $Failed]
]
stackMarkdown[g_] := "![Mathematica graphics](" <> stackImage[g] <> ")"
stackCopyMarkdown[g_] := Module[{nb, markdown},
markdown = Check[stackMarkdown[g], $Failed];
If[markdown =!= $Failed,
nb = NotebookCreate[Visible -> False];
NotebookWrite[nb, Cell[markdown, "Text"]];
SelectionMove[nb, All, Notebook];
FrontEndTokenExecute[nb, "Copy"];
NotebookClose[nb];
]
]
Обновление:
Вот кнопка, которая покажет предварительный просмотр выбора и предложит выгрузку (или отмена).Требуется определить предыдущие функции.
Button["Upload to SO",
Module[{cell = NotebookRead@InputNotebook[], img},
If[cell =!= {}, img = Rasterize[cell];
MessageDialog[
Column[{"Upload image to StackExchange sites?",
img}], {"Upload and copy MarkDown" :> stackCopyMarkdown[img],
"Cancel" :> Null}, WindowTitle -> "Upload to StackExchange"]]]]
К сожалению, я не могу поместить кнопку в палитру (CreatePalette), потому что размеры палитры будут влиять на растеризацию.Решения этой проблемы приветствуются.
Обновление 2:
Основываясь на ответе на этот вопрос , вот рабочая кнопка палитры только для Windows:
button = Button["Upload to SO",
Module[{sel},
FrontEndExecute[
FrontEndToken[FrontEnd`SelectedNotebook[], "CopySpecial", "MGF"]];
sel = Cases[NotebookGet@ClipboardNotebook[],
RasterBox[data_, ___] :>
Image[data, "Byte", ColorSpace -> "RGB", Magnification -> 1],
Infinity];
If[sel =!= {},
With[{img = First[sel]},
MessageDialog[
Column[{"Upload image to StackExchange sites?",
img}], {"Upload and copy MarkDown" :> stackCopyMarkdown[img],
"Cancel" :> Null}, WindowTitle -> "Upload to StackExchange"]
]
]
]
]
CreatePalette[button]
Предупреждение: уничтожает содержимое буфера обмена, даже если нажать кнопку «Отмена» в окне предварительного просмотра.