Плагин Grails JMS для сервера WebLogic JMS

Question

Кто-нибудь настраивал подключаемый модуль Grails 2.x JMS для отправки / получения сообщений на удаленный сервер WebLogic JMS?Я попробовал конфигурации resource.groovy, подобные этой, но не повезло:

jmsConnectionFactory(InitialContext, [
 "INITIAL_CONTEXT_FACTORY": "weblogic.jndi.WLInitialContextFactory",
 "PROVIDER_URL": "t3://remote-host:7001",
 "SECURITY_PRINCIPAL": "weblogic",
 "SECURITY_CREDENTIALS": "weblogic"])

Answer 1

В сети не так много ресурсов с полными ответами о отправке / получении JMS в Grails с удаленным сервером Weblogic, поэтому я нашел 2-3 года назад работающее решение, без необходимости какого-либоplugins .

1. Убедитесь, что по крайней мере Weblogic wlthint3client.jar находится в каталоге lib.

2. Настройкаup JMS слушатель :

   • в conf / spring / resources.groovy:

     // Weblogic's JMS setup on Grails
     jndiTemplate(org.springframework.jndi.JndiTemplate) {
         environment = [
                 "java.naming.factory.initial"     : "weblogic.jndi.WLInitialContextFactory",
                 "java.naming.provider.url"        :  "t3://host.name.mustbe.same.as.configured.on.server.side:port_number",
                 "java.naming.security.principal"  : "wlsadmin",
                 "java.naming.security.credentials": "password"
         ]
     }
     
     
     //
     // listener
     //
     jmsListenerConnectionFactory(org.springframework.jndi.JndiObjectFactoryBean) {
         jndiTemplate = ref(jndiTemplate)
         jndiName     = "jms.checkonserver.QueueConnectionFactory"
     }
     
     jmsListenerDestinationResolver(org.springframework.jms.support.destination.JndiDestinationResolver) {
         jndiTemplate = ref(jndiTemplate)
         cache = false
     }
     
     userListenerCredentialsConnectionFactory(org.springframework.jms.connection.UserCredentialsConnectionFactoryAdapter){
         targetConnectionFactory = ref(jmsListenerConnectionFactory)
     }
     
     standardListenerJmsTemplate(org.springframework.jms.core.JmsTemplate) {
         connectionFactory   = ref(userListenerCredentialsConnectionFactory)
         destinationResolver = ref(jmsListenerDestinationResolver)
     }
     
     jmsListenerMessageListener(org.springframework.jms.listener.adapter.MessageListenerAdapter, ref("myListenerService")) { 
         defaultListenerMethod = "onMessage"
     }
     
     standardListenerJmsListenerContainer(org.springframework.jms.listener.DefaultMessageListenerContainer) {
         connectionFactory   = ref(jmsListenerConnectionFactory)
         destinationResolver = ref(jmsListenerDestinationResolver)
         messageListener = jmsListenerMessageListener
         destinationName     = "jms.checkonserver.MessagesQueue"
     }
     

   • в службах / myListenerService.groovy:

     package app
     
     class MyListenerService {
     
           static transactional = false
           static scope = "prototype"
     
      def onMessage(msg) {
           log.info "JMS msg received."
           try {
               String txtmsg = new String(msg as String)
               log.info txtmsg
           } catch (e) {
               log.error e
           }
       }
     }
     

3. Настройка JMS Отправитель :

   • в конф /spring / resources.groovy:

             jmsSenderConnectionFactory( org.springframework.jndi.JndiObjectFactoryBean) {
                 jndiTemplate = ref(jndiTemplate)
                 jndiName     = "jms.checkonseerver.QueueConnectionFactory" 
             }
     
             jmsSenderDestinationResolver(org.springframework.jms.support.destination.JndiDestinationResolver) {
                 jndiTemplate = ref(jndiTemplate)
                 cache = false
             }
     
             userSenderCredentialsConnectionFactory(org.springframework.jms.connection.UserCredentialsConnectionFactoryAdapter){
                 targetConnectionFactory = ref(jmsSenderConnectionFactory)
             }
     
             standardSenderJmsTemplate(org.springframework.jms.core.JmsTemplate) {
                 connectionFactory   = ref(userSenderCredentialsConnectionFactory) //
                 destinationResolver = ref(jmsSenderDestinationResolver)
             }
     

   • в обслуживании / myJmsSenderService.groovy:

     package app
     
     import org.springframework.jms.core.MessageCreator
     
     import javax.jms.JMSException
     import javax.jms.Message
     import javax.jms.Session
     
     class MyJmsSenderService {
     
          static transactional = false
          static scope = "prototype"
     
          def standardSenderJmsTemplate
     
          def sendMessage(txt) { 
               MessageCreator messageCreator = new MessageCreator() {
                public Message createMessage(Session session) throws
                JMSException {
                   return session.createTextMessage(txt)
                }
               }
     
             standardSenderJmsTemplate.send( "jms.checkonserver.SendingQueue", messageCreator)
     
             log.info "JMS message send: ${txt}"
     
          } 
      }