Оценивать выражение XPath во время выполнения или использовать другой подход?

Question

<grid>
<col>Links</col>
<col>Rechts</col>
<row>
    <Links>l1</Links>
    <Rechts>r1</Rechts>
</row>
<row>
    <Links>l2</Links>
    <Rechts>r2</Rechts>
</row>
</grid>

Привет, ребята, учитывая приведенные выше данные XML, я хочу создать таблицу типа:

Links|Rechts
l1|r1
l2|r2

Мой шаблон XSL:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:dyn="http://exslt.org/dynamic"
extension-element-prefixes="dyn">

    <xsl:template match="grid">

        <xsl:for-each select="//row">
            <xsl:variable name="currentrow" select="."/>
            <xsl:for-each select="//col">
                <xsl:variable name="colname" select="text()"/>
                <xsl:value-of select="dyn:evaluate('$currentrow/$colname/text()')"></xsl:value-of>
            </xsl:for-each>
        </xsl:for-each>
    </xsl:template>

</xsl:stylesheet>

Единственный вывод, который я получаю, это "".

Понятия не имею, как решить мою проблему. Я не знаю, правильный ли это способ использования dyn: оценить.

Спасибо за помощь!

Answer 1

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="text"/>
  <xsl:strip-space elements="*" />

  <xsl:template match="grid">
    <xsl:apply-templates select="col" />
    <xsl:apply-templates select="row" />
  </xsl:template>

  <xsl:template match="col|row/*">
    <xsl:value-of select="." />
    <xsl:choose>
      <xsl:when test="position() = last()"><xsl:value-of select="'&#xA;'" /></xsl:when>
      <xsl:otherwise>|</xsl:otherwise>
    </xsl:choose>
  </xsl:template>
</xsl:stylesheet>

Примечания

• для этого не требуется динамическая оценка XPath.
• <xsl:strip-space elements="*"> удаляет текстовые узлы только для пробелов, которые в противном случае появлялись бы в выходных данных
• один и тот же шаблон может соответствовать разным узлам (здесь через оператор объединения |)
• это решение может справиться с любым количеством столбцов
• не имеет значения, как поля данныхназваны, так как я использовал row/*

---

РЕДАКТИРОВАТЬ Более сложная версия, которая не предполагает, что каждый столбец будет там.

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="text"/>
  <xsl:strip-space elements="*" />

  <xsl:template match="grid">
    <xsl:apply-templates select="col" />
    <xsl:apply-templates select="row" />
  </xsl:template>

  <xsl:template match="col">
    <xsl:value-of select="." />
    <xsl:call-template name="separator" />
  </xsl:template>

  <xsl:template match="row">
    <xsl:variable name="this" select="." />
    <xsl:for-each select="/grid/col">
      <xsl:value-of select="$this/*[name() = current()]" />
      <xsl:call-template name="separator" />
    </xsl:for-each>
  </xsl:template>

  <xsl:template name="separator">
    <xsl:choose>
      <xsl:when test="position() = last()"><xsl:value-of select="'&#xA;'" /></xsl:when>
      <xsl:otherwise>|</xsl:otherwise>
    </xsl:choose>
  </xsl:template>
</xsl:stylesheet>

Answer 2

Замените XSLT grid деталь на

<xsl:template match="grid">
    <xsl:for-each select="row">
            <xsl:value-of select="Links"/>|
            <xsl:value-of select="Rechts"/><br>
    </xsl:for-each>
</xsl:template>

Я использовал <br> для новой строки, если это не HTML, используйте соответствующие символы.

Answer 3

Это преобразование (имеющее наименьшее количество шаблонов - всего 3, оно короче всех других текущих решений и устойчиво к порядку элементов или отсутствует col элементов):

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="col[not(position()=last())]">
   <xsl:value-of select="concat(.,'|')"/>
 </xsl:template>

 <xsl:template match="row">
  <xsl:text>&#xA;</xsl:text>
  <xsl:apply-templates select="/*/col"
       mode="buildCell">
   <xsl:with-param name="pRow" select="."/>
  </xsl:apply-templates>
 </xsl:template>

 <xsl:template match="col" mode="buildCell">
   <xsl:param name="pRow"/>

   <xsl:value-of select=
    "concat($pRow/*[name()=current()],
            substring('|', (position()=last())+1)
           )
    "/>
 </xsl:template>
</xsl:stylesheet>

при применении к предоставленному документу XML:

<grid>
    <col>Links</col>
    <col>Rechts</col>
    <row>
        <Links>l1</Links>
        <Rechts>r1</Rechts>
    </row>
    <row>
        <Links>l2</Links>
        <Rechts>r2</Rechts>
    </row>
</grid>

дает требуемый, правильный результат:

Links|Rechts
l1|r1
l2|r2

Answer 4

Эта таблица стилей:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:variable name="vColNames" select="/grid/col"/>
    <xsl:template match="grid">
        <table>
            <xsl:apply-templates/>
        </table>
    </xsl:template>
    <xsl:template match="col"/>
    <xsl:template match="col[1]">
        <tr>
            <xsl:apply-templates select="../col" mode="wrap"/>
        </tr>
    </xsl:template>
    <xsl:template match="col" mode="wrap">
        <th>
            <xsl:apply-templates/>
        </th>
    </xsl:template>
    <xsl:template match="row">
        <xsl:variable name="vCurrent" select="."/>
        <tr>
            <xsl:for-each select="$vColNames">
                <xsl:apply-templates select="$vCurrent/*[name()=current()]"/>
            </xsl:for-each>
        </tr>
    </xsl:template>
    <xsl:template match="row/*">
        <td>
            <xsl:apply-templates/>
        </td>
    </xsl:template>
</xsl:stylesheet>

Выход:

<table>
    <tr>
        <th>Links</th>
        <th>Rechts</th>
    </tr>
    <tr>
        <td>l1</td>
        <td>r1</td>
    </tr>
    <tr>
        <td>l2</td>
        <td>r2</td>
    </tr>
</table>

Примечание : перебирать имена столбцов в контексте row.