Что такое функция vimrc, чтобы определить, был ли изменен буфер?

Question

У меня есть функция табулирования, которую я украл / изменил откуда-то, но я бы хотел, чтобы перед именем файла было звездочка, если оно было изменено с момента последней записи на диск (т. Е. Если: up выполнитдействие).

Например, это моя таблица, когда я открываю файл vim -p * .txt

file1.txt file2.txt file3.txt

Затем, после того как я изменил file1.txt и не сохранил его:

*file1.txt file2.txt file3.txt

Моя функция табуляции:

if exists("+showtabline")
   function MyTabLine()
      let s = ''
      let t = tabpagenr()
      let i = 1
      while i <= tabpagenr('$')
         let buflist = tabpagebuflist(i)
         let winnr = tabpagewinnr(i)
         let s .= ' %*'
         let s .= (i == t ? '%#TabLineSel#' : '%#TabLine#')
         let file = bufname(buflist[winnr - 1])
         let file = fnamemodify(file, ':p:t')
         if file == ''
            let file = '[No Name]'
         endif
         let s .= file
         let i = i + 1
      endwhile
      let s .= '%T%#TabLineFill#%='
      let s .= (tabpagenr('$') > 1 ? '%999XX' : 'X')
      return s
   endfunction
   set stal=2
   set tabline=%!MyTabLine()
endif

Answer 1

Я просто искал то же самое и обнаружил, что %m и %M не очень подходят, так как он говорит вам, был ли изменен открытый в данный момент буфер. Таким образом, вы не можете видеть, изменены ли другие буферы (особенно для вкладок, это важно).

Решением является функция getbufvar. Примерно из справки:

let s .= (getbufvar(buflist[winnr - 1], "&mod")?'*':'').file

вместо

let s .= file

должен сделать трюк. Это может быть удобно использовано для отображения всех буферов, открытых на одной вкладке (в случае нескольких разделений).

Answer 2

tabline использует флаги, аналогичные statusline (см. :h statusline).Так что %m - это то, что вам нужно, и изменение строк непосредственно перед endwhile, так как

let s .= file
let s .= (i == t ? '%m' : '')
let i = i + 1

автоматически установит значение по умолчанию [+] после имени файла в текущей вкладке, если есть несохраненные изменения.