XSLT сумма предшествующих братьев и сестер по атрибутам - PullRequest
Новая
       0

XSLT сумма предшествующих братьев и сестер по атрибутам

2 голосов
/ 02 марта 2012

Я пытаюсь суммировать все предыдущие значения для определенного атрибута.Я полагал, что использование суммы и предшествующего родного брата добились бы цели.Я получаю все нули вместо этого.Вот XSL: 

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema">
<xsl:template match="/xs:schema/xs:complexType/xs:sequence">
  <html>  <body>  <table border="1">
    <tr bgcolor="#9acd32">
      <th>Field</th>
      <th>Width</th>
      <th>Position</th>
    </tr>
    <xsl:variable name="position" select="1"  />
    <xsl:for-each select="xs:element">
    <tr>
      <td><xsl:value-of select="@name"/></td>
      <td><xsl:value-of select="xs:simpleType/xs:restriction/xs:maxLength/@value"/></td>
      <td><xsl:value-of select="sum(preceding-sibling::xs:simpleType/xs:restriction/xs:maxLength/@value)"/></td>
      </tr>
    </xsl:for-each>
  </table>  </body>  </html>
</xsl:template>  </xsl:stylesheet>

XML выглядит следующим образом: 

<?xml version="1.0" encoding="UTF-8"?>
<?xml-stylesheet type="text/xsl" href="fw.xsl"?>
<xs:schema xmlns:xs="http://www.w3.org/2001/XMLSchema">
  <xs:complexType name="xxxxxxxxxxxxx">
    <xs:sequence>
      <xs:element default="" name="TransactionCode" nillable="true">
        <xs:simpleType>
          <xs:restriction base="xs:string">
            <xs:maxLength value="2"/>
          </xs:restriction>
        </xs:simpleType>
      </xs:element>
      <xs:element default="" minOccurs="0" name="ZipCodeSendingProgram" nillable="true">
        <xs:simpleType>
          <xs:restriction base="xs:string">
            <xs:maxLength value="6"/>
          </xs:restriction>
        </xs:simpleType>
      </xs:element>
      <xs:element default="" minOccurs="0" name="ZipCodeSendingProgramEOJ" nillable="true">
        <xs:simpleType>
          <xs:restriction base="xs:string">
            <xs:maxLength value="3"/>
          </xs:restriction>
        </xs:simpleType>
      </xs:element>
      <xs:element default="" minOccurs="0" name="ZipCodeError" nillable="true">
        <xs:simpleType>
          <xs:restriction base="xs:string">
            <xs:maxLength value="2"/>
          </xs:restriction>
        </xs:simpleType>
      </xs:element>

Ожидаемый результат: 

Field                     Width Position
TransactionCode           2 0
ZipCodeSendingProgram     6 2
ZipCodeSendingProgramEOJ  3 8
ZipCodeError              2 11

Фактический результат: 

Field                     Width Position
TransactionCode           2 0
ZipCodeSendingProgram     6 0
ZipCodeSendingProgramEOJ  3 0
ZipCodeError              2 0

Я, вероятно, упускаю что-то действительно очевидное ... но я не могу это понять.Заранее спасибо ...

1 Ответ

2 голосов
/ 02 марта 2012

Просто изменить : 

<td><xsl:value-of select="sum(preceding-sibling::xs:simpleType/xs:restriction/xs:maxLength/@value)"/></td>

до 

<td>
  <xsl:value-of select="sum(preceding-sibling::xs:element/xs:simpleType/xs:restriction/xs:maxLength/@value)"/>
</td>

Вот полный исправленный код : 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema">
    <xsl:template match="/xs:schema/xs:complexType/xs:sequence">
        <html>
            <body>
                <table border="1">
                    <tr bgcolor="#9acd32">
                        <th>Field</th>
                        <th>Width</th>
                        <th>Position</th>
                    </tr>
                    <xsl:variable name="position" select="1"  />
                    <xsl:for-each select="xs:element">
                        <tr>
                            <td>
                                <xsl:value-of select="@name"/>
                            </td>
                            <td>
                                <xsl:value-of select="xs:simpleType/xs:restriction/xs:maxLength/@value"/>
                            </td>
                            <td>
                                <xsl:value-of select="sum(preceding-sibling::xs:element/xs:simpleType/xs:restriction/xs:maxLength/@value)"/>
                            </td>
                        </tr>
                    </xsl:for-each>
                </table>
            </body>
        </html>
    </xsl:template>
</xsl:stylesheet>

Теперь, когда это преобразование применяется к предоставленному документу XML (исправлено, чтобы оно было правильно сформировано): 

<xs:schema xmlns:xs="http://www.w3.org/2001/XMLSchema">
    <xs:complexType name="xxxxxxxxxxxxx">
        <xs:sequence>
            <xs:element default="" name="TransactionCode" nillable="true">
                <xs:simpleType>
                    <xs:restriction base="xs:string">
                        <xs:maxLength value="2"/>
                    </xs:restriction>
                </xs:simpleType>
            </xs:element>
            <xs:element default="" minOccurs="0" name="ZipCodeSendingProgram" nillable="true">
                <xs:simpleType>
                    <xs:restriction base="xs:string">
                        <xs:maxLength value="6"/>
                    </xs:restriction>
                </xs:simpleType>
            </xs:element>
            <xs:element default="" minOccurs="0" name="ZipCodeSendingProgramEOJ" nillable="true">
                <xs:simpleType>
                    <xs:restriction base="xs:string">
                        <xs:maxLength value="3"/>
                    </xs:restriction>
                </xs:simpleType>
            </xs:element>
            <xs:element default="" minOccurs="0" name="ZipCodeError" nillable="true">
                <xs:simpleType>
                    <xs:restriction base="xs:string">
                        <xs:maxLength value="2"/>
                    </xs:restriction>
                </xs:simpleType>
            </xs:element>
        </xs:sequence>
    </xs:complexType>
</xs:schema>

желаемый, правильный результат выдается : 

        <html xmlns:xs="http://www.w3.org/2001/XMLSchema">
   <body>
      <table border="1">
         <tr bgcolor="#9acd32">
            <th>Field</th>
            <th>Width</th>
            <th>Position</th>
         </tr>
         <tr>
            <td>TransactionCode</td>
            <td>2</td>
            <td>0</td>
         </tr>
         <tr>
            <td>ZipCodeSendingProgram</td>
            <td>6</td>
            <td>2</td>
         </tr>
         <tr>
            <td>ZipCodeSendingProgramEOJ</td>
            <td>3</td>
            <td>8</td>
         </tr>
         <tr>
            <td>ZipCodeError</td>
            <td>2</td>
            <td>11</td>
         </tr>
      </table>
   </body>
</html>
Добро пожаловать на сайт PullRequest, где вы можете задавать вопросы и получать ответы от других членов сообщества.

Нет похожих вопросов

...