xml получает значения параметров childs и выводит их в csv

Question

у меня есть следующая структура XML

<transport titel="vervoer">
  <type titel="car">
    <brand titel="volvo">
      <color titel="kleur">red</color>
    </brand>
  </type>
  <type titel="car">
    <brand titel="volvo">
      <color titel="kleur">green</color>
    </brand>
  </type>
  <type titel="car">
    <brand titel="ford">
      <color titel="kleur">red</color>
    </brand>
  </type>
  <type titel="bike">
    <brand titel="trek">
      <color titel="kleur">blue</color>
    </brand>
  </type>
</transport>

я могу создать CSV со следующим xsl:

<xsl:template match="/">
  <xsl:for-each select="/transport/type/brand/color">
    <xsl:variable name="color" select="@titel" />
    <xsl:variable name="brand" select="../@titel" />
    <xsl:variable name="type" select="../../@titel"/>
    <xsl:value-of select="concat($type,$brand,$color)" />
  </xsl:for-each>
</xsl:template>

это дает вывод с каждым узлом в одной строке:

car,volvo,red  
car,volo.green  
car,ford,red  
bike,trek,blue  

НО есть два вопроса с этим подходом
1. есть ли способ пройтись по дереву сверху и показать все титры, когда они доступны? если есть узел без дочернего цвета, он не будет отображаться.

<type titel="bike">
  <brand titel="trek">
  </brand>
</type>

2.я хочу вывод моего csv так:

car,volvo,red  
   ,     ,green  
   ,ford,red  
bike,trek,blue  

Answer 1

Эта таблица стилей:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:strip-space elements="*"/>
    <xsl:key name="kElementByName" match="*/*" use="name()"/>
    <xsl:variable name="vFields"
         select="//*/*[count(.|key('kElementByName',name())[1])=1]"/>
    <xsl:template match="/*/*">
        <xsl:variable name="vCurrent" select="."/>
        <xsl:for-each select="$vFields">
            <xsl:variable name="vField"
                 select="$vCurrent/descendant-or-self::*[
                             name() = name(current())
                         ]"/>
            <xsl:variable name="vValue"
                 select="($vField/@titel|$vField/text())[last()]"/>
            <xsl:if test="position()!=1">,</xsl:if>
            <xsl:value-of
              select="concat(substring('&#x9;',1 div not($vValue)),$vValue)"/>
        </xsl:for-each>
        <xsl:text>&#xA;</xsl:text>
    </xsl:template>
</xsl:stylesheet>

Вывод:

car,volvo,red
car,volvo,green
car,ford,red
bike,trek,blue

РЕДАКТИРОВАТЬ : Группировка по запросу, эта таблица стилей:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:key name="kTypeByTitel" match="type" use="@titel"/>
    <xsl:key name="kBrandByType-Titel" match="brand"
             use="concat(../@titel,'++',@titel)"/>
    <xsl:template match="/*">
        <xsl:apply-templates
             select="type[count(.|key('kTypeByTitel',@titel)[1])=1]"/>
    </xsl:template>
    <xsl:template match="type">
        <xsl:value-of select="@titel"/>
        <xsl:apply-templates
             select="key('kTypeByTitel',@titel)/brand[
                        count(.|key('kBrandByType-Titel',
                                    concat(../@titel,'++',@titel)
                                )[1]
                        ) = 1
                     ]"/>
    </xsl:template>
    <xsl:template match="brand">
        <xsl:if test="position()!=1">
            <xsl:text>&#x9;</xsl:text>
        </xsl:if>
        <xsl:value-of select="concat(',',@titel)"/>
        <xsl:apply-templates select="key('kBrandByType-Titel',
                                         concat(../@titel,'++',@titel)
                                     )"
                             mode="color"/>
    </xsl:template>
    <xsl:template match="brand" mode="color">
        <xsl:if test="position()!=1">
            <xsl:text>&#x9;,&#x9;</xsl:text>
        </xsl:if>
        <xsl:value-of select="concat(
                                 ',',
                                 (color/@titel|color/text())[last()],
                                 '&#xA;'
                              )"/>
    </xsl:template>
</xsl:stylesheet>

Выход:

car,volvo,red
    ,   ,green
    ,ford,red
bike,trek,blue

Примечание : Нет необходимости в заказном источнике входного сигнала.Исправлены поля, потому что общее решение (вложенная группировка по динамическим клавишам) было бы самой сложной задачей в XSLT 1.0

Answer 2

Ваша проблема в том, что вы выбираете <color> в вашем for-each, поэтому вы пропустите каждый <type>, у которого нет <color> потомка.

Альтернативой обработке с for-each может быть:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text" indent="no" />
    <xsl:strip-space elements="transport" />

    <xsl:template match="/">
        <xsl:apply-templates />
    </xsl:template>

    <xsl:template match="transport">
        <xsl:apply-templates />
    </xsl:template>

    <xsl:template match="type">
        <xsl:choose>
            <xsl:when test="@titel">
                <xsl:value-of select="@titel" />
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="' '" />
            </xsl:otherwise>
        </xsl:choose>

        <xsl:text>,</xsl:text>

        <xsl:choose>
            <xsl:when test="brand[@titel]">
                <xsl:apply-templates select="brand" />
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="' '" />
            </xsl:otherwise>
        </xsl:choose>

        <xsl:text>,</xsl:text>

        <xsl:choose>
            <xsl:when test="brand/color">
                <xsl:apply-templates select="brand/color" />
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="' '" />
            </xsl:otherwise>
        </xsl:choose>
        <xsl:text>&#13;&#10;</xsl:text>
    </xsl:template>

    <xsl:template match="brand">
        <xsl:value-of select="@titel"/>
    </xsl:template>

    <xsl:template match="brand/color">
        <xsl:value-of select="."/>
    </xsl:template>
</xsl:stylesheet>

пример ввода

<?xml version="1.0" encoding="utf-8" ?>
<transport titel="vervoer">
    <type titel="car">
        <brand titel="volvo">
            <color titel="kleur">red</color>
        </brand>
    </type>
    <type titel="car">
        <brand titel="volvo">
            <color titel="kleur">green</color>
        </brand>
    </type>
    <type titel="car">
        <brand titel="ford">
            <color titel="kleur">red</color>
        </brand>
    </type>
    <type titel="bike">
        <brand titel="trek">
            <color titel="kleur">blue</color>
        </brand>
    </type>
    <type titel="trike">
        <brand titel="foo" />
    </type>
    <type>
        <brand titel="porsche">
            <color titel="kleur">black</color>
        </brand>
    </type>
    <type>
        <brand>
            <color titel="kleur">black</color>
        </brand>
    </type>

образец вывода

car,volvo,red
car,volvo,green
car,ford,red
bike,trek,blue
trike,trek, 
 ,porsche,black
 , ,black

Чтобы исключить ненужные элементы из вашего вывода, просто добавьте пустой шаблон:

    ...
    <xsl:template match="sometext" />
</xsl:stylesheet>