XSLT + Создание структуры таблицы - PullRequest
Новая
       0

XSLT + Создание структуры таблицы

2 голосов
/ 12 января 2012

Я хотел бы создать структуру таблицы, которая разделяет строку заголовка на THEAD и строки данных на TBODY :

Входной XML: 

<Rowsets>
  <Rowset>
    <Columns>
      <Column Description="Date"/>
      <Column Description="Time"/>
    </Columns>
    <Row>
      <Date>DATA1</Date>
      <Time>DATA2</Time>
    </Row>
    <Row>
      <Date>DATA1</Date>
      <Time>DATA2</Time>
  </Rowset>
</Rowsets>

Следующий XSLT разделяет заголовок и тело, но я не могу понять, как обернуть теги между строками данных: 

<xsl:strip-space elements="*"/>
<xsl:template match="/">
  <HTML>
    <BODY>
      <TABLE>
        <XSL:apply-templates/>
      </TABLE>
    </BODY>
  </HTML>
</xsl:template>

<xsl:template match="Columns|Row">
  <tr><xsl:apply-templates/></tr>
</xsl:template>

<xsl:template match="Columns">
  <thead><xsl:apply-templates/></thead>
</xsl:template>

<xsl:template match="Columns/*">
  <th><xsl:apply-templates select="@Description"/></th>
</xsl:template>

<xsl:template match="Row/*">
  <td><xsl:apply-templates/></td>
</xsl:template>

Текущий вывод HTML: 

  <THEAD>
    <TR>
      <TH>Date</TH><TH>Time</TH>
    </TR>
  </THEAD>
    <TR>
      <TD>DATA1</TD><TD>DATA2</TD>
    </TR>
    <TR>
      <TD>DATA1</TD><TD>DATA2</TD>
    </TR>

Как обернуть строки данных с помощью TBODY ? Спасибо!

Ответы [ 2 ]

3 голосов
/ 12 января 2012

Самое простое решение - добавить следующий шаблон в таблицу стилей: 

<xsl:template match="Rowset">
    <xsl:apply-templates select="Columns"/>
    <tbody>
        <xsl:apply-templates select="Row"/>
    </tbody>
</xsl:template>

Полная таблица стилей (с парой других незначительных изменений): 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:strip-space elements="*"/>
    <xsl:template match="/">
        <HTML>
            <BODY>
                <TABLE>
                    <xsl:apply-templates/>
                </TABLE>
            </BODY>
        </HTML>
    </xsl:template>
    <xsl:template match="Rowset">
        <xsl:apply-templates select="Columns"/>
        <tbody>
            <xsl:apply-templates select="Row"/>
        </tbody>
    </xsl:template>
    <xsl:template match="Columns">
        <thead><tr><xsl:apply-templates/></tr></thead>
    </xsl:template>
    <xsl:template match="Columns/*">
        <th><xsl:apply-templates select="@Description"/></th>
    </xsl:template>
    <xsl:template match="Row">
        <tr><xsl:apply-templates/></tr>
    </xsl:template>
    <xsl:template match="Row/*">
        <td><xsl:apply-templates/></td>
    </xsl:template>
</xsl:stylesheet>
3 голосов
/ 12 января 2012

Вы можете ограничить (выбрать), какие узлы должны применяться apply-templates. Я бы использовал что-то вроде этого: 

<xsl:strip-space elements="*"/>
<xsl:template match="/">
  <HTML>
    <BODY>
      <TABLE>
        <THEAD>
          <xsl:apply-templates select="Columns"/>
        </THEAD>
        <TBODY>
          <xsl:apply-templates select="Row"/>
        </TBODY>
      </TABLE>
    </BODY>
  </HTML>
</xsl:template>

<xsl:template match="Columns|Row">
  <TR><xsl:apply-templates/></TR>
</xsl:template>

<xsl:template match="Columns/*">
  <TH><xsl:value-of select="@Description"/></TH>
</xsl:template>

<xsl:template match="Row/*">
  <TD><xsl:apply-templates/></TD>
</xsl:template>
Добро пожаловать на сайт PullRequest, где вы можете задавать вопросы и получать ответы от других членов сообщества.

Нет похожих вопросов

...