Groovy, получить имя функции включения?

Question

Я использую Groovy 1.8.4, пытаюсь получить имя включающей функции ...

def myFunction() {
  println functionName??
}

Я пробовал delegate, this, owner, Groovy жалуется, что такие объекты не найдены.

Я также попробовал взломать Java new Exception().getStackTrace()[0].getMethodName(), но он просто печатает newInstance0

Answer 1

Как насчет groovy's StackTraceUtils.sanitize? Вот быстрый пример:

import org.codehaus.groovy.runtime.StackTraceUtils

class A {
  def methodX() {
    methodY()
  }

  def methodY() {
    methodZ()
  }

  def methodZ() {
    def marker = new Throwable()
    StackTraceUtils.sanitize(marker).stackTrace.eachWithIndex { e, i ->
        println "> $i ${e.toString().padRight(30)} ${e.methodName}"
    }
  }

}

new A().methodX()

Вывод вышеперечисленного при вставке в автономный скрипт test.groovy выглядит следующим образом:

$ groovy test.groovy 
> 0 A.methodZ(test.groovy:13)      methodZ
> 1 A.methodY(test.groovy:9)       methodY
> 2 A.methodX(test.groovy:5)       methodX
> 3 A$methodX.call(Unknown Source) call
> 4 test.run(test.groovy:21)       run

метод sanitize отфильтровывает все отличные внутренние mumbo jumbo от трассы, и чистая трасса вместе с ...stackTrace.find { } должна дать вам достойное начало.

Answer 2

import org.codehaus.groovy.runtime.StackTraceUtils

def getCurrentMethodName(){
  def marker = new Throwable()
  return StackTraceUtils.sanitize(marker).stackTrace[1].methodName
}

def helloFun(){
   println( getCurrentMethodName() )
}

helloFun()

вывод:

helloFun

Answer 3

Вы можете добраться до него через трассировку стека, я смог получить его через:

groovy:000> def foo() { println Thread.currentThread().stackTrace[10].methodName }
===> true
groovy:000> foo()
foo
groovy:000> class Foo {                                                             
groovy:001>   def bar() { println Thread.currentThread().stackTrace[10].methodName }
groovy:002> }
===> true
groovy:000> new Foo().bar()
bar

Answer 4

@CompileStatic
class LogUtils {
    // can be called the Groovy or Java way
    public static String getCurrentMethodName(){
        StackTraceElement[] stackTrace = StackTraceUtils.sanitize(new Throwable()).stackTrace
        stackTrace[2].methodName != 'jlrMethodInvoke' ? stackTrace[2].methodName : stackTrace[3].methodName
    }
}