Установка Flash с использованием VB Script

Question

скриптеры,

Я новичок в мире сценариев VB!

Я бы хотел сделать следующее с помощью скриптов, чтобы я мог установить Flash.

Шаги: -

1.  Open Internet Options.
2.  Click on “Connections” tab.
3.  Click on “LAN Settings” button.
4.  Deselect the “Automatically Detect Settings” checkbox.
5.  Check the “Use a proxy server for your LAN (These settings will not apply to dial-up or VPN connections).” checkbox.
6.  Enter the address “172.16.3.150” in the “Address” text field and “80” in the “Port” text field.
7.  Check the “Bypass proxy server for local addresses” check box.
8.  Click “OK”, and “OK” again.
9.  Open “Internet Explorer” and navigate to “http://aihdownload.adobe.com/bin/install_flashplayer11x64ax_gtbd_aih.exe”
and open the file.

Так можно ли заставить все это работать в сценарии? Я хотел бы использовать это в GPO для запуска на всех клиентских компьютерах.

Я ценю любую помощь! Большое спасибо!

Answer 1

Вам не нужен IE и его графический интерфейс для выполнения http-запроса за прокси-сервером.Вы можете загрузить файл, используя объект WinHttpRequest (с информацией о прокси см. SetProxy ). например

Const HTTPREQUEST_PROXYSETTING_PROXY = 2
Const adTypeBinary = 1
Const adSaveCreateOverWrite = 2
Dim oHttp

Set oHTTP = CreateObject("WinHttp.WinHttpRequest.5.1")
With oHttp
    'Make request
    .SetTimeouts 5000,5000,5000,30000
    .SetProxy HTTPREQUEST_PROXYSETTING_PROXY, "172.16.3.150:80"
    .Open "GET", "http://aihdownload.adobe.com/bin/install_flashplayer11x64ax_gtbd_aih.exe", False
    .Send
    If oHttp.Status = 200 Then
        'Save Response
        With CreateObject("ADODB.Stream")
            .Open
            .Type = adTypeBinary
            .Write oHttp.ResponseBody
            .SaveToFile "C:\setup.exe", adSaveCreateOverWrite
            .Close
        End With
        'Run Executable
        CreateObject("WScript.Shell").Run "C:\setup.exe"
        WScript.Echo "Completed!"
    Else
        WScript.Echo "Download Failed"
    End If
End With
Set oHttp = Nothing